Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1068to1072
1068to1072
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

In Spalte leere Zelle erkennen /farblich markieren

Forumthread: In Spalte leere Zelle erkennen /farblich markieren

In Spalte leere Zelle erkennen /farblich markieren
21.04.2009 08:56:19
Joachim
Hi,
ich mal wieder: ich lese Daten in mein Tabellenblatt "DATEN" ein. Dann möchte ich überprüfen, ob es in der Spalte B irgendwo eine Zelle gibt , die leer ist. Den Range des Datenbereichs ermittle ich so:
lngRow = Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
Range("B10:B" & lngRow)
Wie kann ich nun innerhalb meines ermittelten Range die Spalte B durchlaufen und nach leeren Zellen suchen. Wenn eine leere Zelle gefunden wurde, soll die entsprechende Zeile GELB und die betroffene Zelle ROT markiert werden. Dann weiter bis zur nächsten Zelle , bis ans Ende meines Ranges.
Hat da jemand eine Idee ?
Danke mal
Gruss
Joachim
Anzeige

16
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
Habe aber ein dynamischen Range ...
21.04.2009 09:42:23
Joachim
Hi Jan,
Danke. Mein Problem ist aber, da ich immer wieder neue Daten einlese und mein Range immer unterschiedlich ist, möchte ich auch nur den eingelesenen Range überprüfen und markieren.
Darum würde ich das am liebsten per VBA machen.
Gruss
Joachim
Anzeige
AW: Habe aber ein dynamischen Range ...
21.04.2009 10:01:38
Tino
Hallo,
versuche und teste es mal hiermit.
Sub Beispiel()
Dim lngRow As Long, lngCol As Long
Dim Bereich As Range
Dim objTab As Worksheet

'eventuell Namen anpassen 
Set objTab = ActiveSheet

With objTab
    .UsedRange.Interior.ColorIndex = xlColorIndexNone
    lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
    lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
    Set Bereich = .Range("B10:B" & lngRow)


For Each Bereich In Bereich.SpecialCells(xlCellTypeBlanks)
 .Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
 Bereich.Interior.ColorIndex = 3
Next Bereich

End With

End Sub


Gruß Tino

Anzeige
sieht fast gut aus...
21.04.2009 10:14:42
Joachim
Hi Tino,
Vielen Dank. Sieht fest gut aus. Nur eine Bitte: wenn ich den Code ausführe, verschwinden innerhalb der Zeilen 1 - 9 , also den Teil, den ich eigentlich ausschliessen will, die Farbhintergründe der Zellen (Überschrift)
Geht der Code nicht erst ab B10 los ?
Gruss
Joachim
Anzeige
machen wir es gut ;-)
21.04.2009 10:27:47
Tino
Hallo,
wollte den einfachen Weg gehen, dachte die Tabelle hätte noch keine Formatierung.
Ist aber schnell erledigt.
Sub Beispiel()
Dim lngRow As Long, lngCol As Long
Dim Bereich As Range
Dim objTab As Worksheet

'eventuell Namen anpassen 
Set objTab = ActiveSheet

With objTab
    
    lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
    lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
    Set Bereich = .Range("B10:B" & lngRow)
    Bereich.Interior.ColorIndex = xlColorIndexNone

For Each Bereich In Bereich.SpecialCells(xlCellTypeBlanks)
 .Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
 Bereich.Interior.ColorIndex = 3
Next Bereich

End With

End Sub


Gruß Tino

Anzeige
Perfekt, Vielen Dank owT
21.04.2009 10:36:41
Joachim
wo wird denn nach "leer" gesucht...
21.04.2009 11:00:29
Joachim
.. Hi Tino,
ist das die Spalte, wo nach leeren Zellen gesucht wird:
lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
(dieses "*") ?
Wie sieht denn die Zeile aus , wenn nicht nicht nach Leeren, sondern zB Abfrage IST NICHT "TEST"
Danke und Gruss
Joachim
Anzeige
nein so nicht.
21.04.2009 11:26:37
Tino
Hallo,
wenn Du nach einem bestimmten Begriff suchen möchtest,
geht dies am schnellsten mit einer Hilfsspalte die am Schluss wieder gelöscht wird.
Man könnte es noch schneller machen wenn man den Bereich zuvor noch Sortiert und danach wieder zurücksortiert, aber so sollte es erst mal reichen.
Noch schneller würde es nur noch gehen, wenn man die Bedingte Formatierung dafür nutzt.
Wenn ich noch Lust habe werte ich ein Beispiel aufbauen.
Kommentare stehen im Code.
Option Explicit

Sub Beispiel()
Dim lngRow As Long, lngCol As Long, lngCol1 As Long
Dim Bereich As Range
Dim objTab As Worksheet
Dim SuchBegriff As String

'Suchbegriff************* 
SuchBegriff = "Test"

'eventuell Namen anpassen 
Set objTab = ActiveSheet

'Bildschirmaktualisierung aus 
Application.ScreenUpdating = False
 
    With objTab
        'Suche letzte Zeile 
        lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
        'Suche letzte Spalte 
        lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
        'Bereich in B eingrenzen 
        Set Bereich = .Range("B10:B" & lngRow)
        'Merke Spalte aus Bereich 
        lngCol1 = Bereich.Column
        'Farben zurücksetzen in Spalte B 
        Bereich.Interior.ColorIndex = xlColorIndexNone
        'letzte Spalte bestimmen 
        Set Bereich = Bereich.Offset(0, .Columns.Count - lngCol1)
        'Formel einfügen 
        Bereich.FormulaR1C1 = "=IF(RC" & lngCol1 & "=""" & SuchBegriff & """,0,"""")"
        'prüfen ob der Wert 0 in der letzten Spalte vorkommt 
        If Application.WorksheetFunction.CountIf(Bereich, 0) > 0 Then
         'Schleife über alle Zellen mit dem Wert 0 
            For Each Bereich In Bereich.SpecialCells(xlCellTypeFormulas, 1)
             'Zeile gelb färben 
             .Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
             'Zelle rot färben 
             Cells(Bereich.Row, lngCol1).Interior.ColorIndex = 3
            Next Bereich
        End If
       'Hilfsspalte löschen 
       .Columns(Columns.Count).Delete
    
    End With
'Bildschirmaktualisierung ein 
Application.ScreenUpdating = True
End Sub


Gruß Tino

Anzeige
AW: wo wird denn nach "leer" gesucht...
21.04.2009 12:05:35
Tino
Hallo,
hier mal eine Version mit der Bedingten Formatierung.
Unter xl2007 ist es einfacher, aber so geht’s auch.
Option Explicit

Sub Beispiel2()
Dim lngRow As Long, lngCol As Long
Dim Bereich1 As Range, Bereich2 As Range
Dim SuchBegriff As String
Dim objTab As Worksheet

'Suchbegriff************* 
SuchBegriff = "Test"

Application.ScreenUpdating = False

    'eventuell Namen anpassen 
    Set objTab = ActiveSheet

 
    With objTab
        'Suche letzte Zeile 
        lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
        'Suche letzte Spalte 
        lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
        
        Set Bereich1 = Range("A10", Cells(lngRow, 1))
        Set Bereich2 = Range("B10", Cells(lngRow, 2))
        
        Bereich2.FormatConditions.Delete
        Bereich2.FormatConditions.Add Type:=xlExpression, Formula1:="=$B10=""" & SuchBegriff & """"
        Bereich2.FormatConditions(1).Interior.ColorIndex = 3
        
        Bereich1.FormatConditions.Delete
        Bereich1.FormatConditions.Add Type:=xlExpression, Formula1:="=$B10=""" & SuchBegriff & """"
        Bereich1.FormatConditions(1).Interior.ColorIndex = 6
        
        Set Bereich1 = Range("C10", Cells(lngRow, lngCol))
        Bereich1.FormatConditions.Delete
        Bereich1.FormatConditions.Add Type:=xlExpression, Formula1:="=$B10=""" & SuchBegriff & """"
        Bereich1.FormatConditions(1).Interior.ColorIndex = 6
    End With

Application.ScreenUpdating = True
End Sub


Gruß Tino

Anzeige
AW: wo wird denn nach "leer" gesucht...
22.04.2009 08:54:16
Joachim
Hallo Tino,
weiss jetzt garnicht, welchen Code ich nehmen soll, welcher der Beste ist für mich, funktionieren tun sie ja alle :-) Im Moment nutze ich noch den:
With objTab
lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
Set Bereich = .Range("B10:B" & lngRow)
'Bereich.Interior.ColorIndex = xlColorIndexNone
If Application.WorksheetFunction.CountBlank(Bereich) > 0 Then
For Each Bereich In Bereich.SpecialCells(xlCellTypeBlanks)
.Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
Bereich.Interior.ColorIndex = 3
Next Bereich
End If
End With
Geht der auch unter 2007 ?.
Was muss ich denn ändern, wenn ich noch eine zweite Abfrage machen will:
Wenn Spalte C = "TEST" UND Spalte H = "", Dann diese Markierungen (wie seither)
Danke Tino und Gruss
Anzeige
AW: wo wird denn nach "leer" gesucht...
22.04.2009 15:30:21
Tino
Hallo,
Du brauchst nur die Formel die erstellt wird entsprechend anpassen.

"=IF(RC" & lngCol1 & "=""" & SuchBegriff & """,0,"""")"


Bei mir funktionieren beide Versionen unter xl2003 und 2007.

Sub Beispiel()
Dim lngRow As Long, lngCol As Long, lngCol1 As Long
Dim Bereich As Range
Dim objTab As Worksheet
Dim SuchBegriff As String

'Suchbegriff************* 
SuchBegriff = "Test"

'eventuell Namen anpassen 
Set objTab = ActiveSheet

'Bildschirmaktualisierung aus 
Application.ScreenUpdating = False
 
    With objTab
        'Suche letzte Zeile 
        lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
        'Suche letzte Spalte 
        lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
        'Bereich in B eingrenzen 
        Set Bereich = .Range("B10:B" & lngRow)
        'Merke Spalte aus Bereich 
        lngCol1 = Bereich.Column
        'Farben zurücksetzen in Spalte B 
        Bereich.Interior.ColorIndex = xlColorIndexNone
        'letzte Spalte bestimmen 
        Set Bereich = Bereich.Offset(0, .Columns.Count - lngCol1)
        'Formel einfügen 
        Bereich.FormulaR1C1 = "=IF(AND(RC" & lngCol1 & "=""" & SuchBegriff & """,RC8=""""),0,"""")"
        'prüfen ob der Wert 0 in der letzten Spalte vorkommt 
        If Application.WorksheetFunction.CountIf(Bereich, 0) > 0 Then
         'Schleife über alle Zellen mit dem Wert 0 
            For Each Bereich In Bereich.SpecialCells(xlCellTypeFormulas, 1)
             'Zeile gelb färben 
             .Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
             'Zelle rot färben 
             .Cells(Bereich.Row, lngCol1).Interior.ColorIndex = 3
            Next Bereich
        End If
       'Hilfsspalte löschen 
       .Columns(.Columns.Count).Delete
    
    End With
'Bildschirmaktualisierung ein 
Application.ScreenUpdating = True
End Sub


Gruß Tino

Anzeige
Hallo Tino,
22.04.2009 15:57:55
Joachim
Ich denke das passt soweit: habe nur noch versucht, der BEREICH anders zu definieren, also dass nicht die Spalte C (seitherB) gefärbt wird, (wo seither "Test" stand, sondern meine leere Zelle in der Spalte M.
Habe den Bereich herumgedreht, scheint aber nicht zu klappen, kannst Du sehen warum.
Also wenn C = "TEST" und M = "", dann M färben:
Dim lngRow As Long, lngCol As Long, lngCol1 As Long
Dim Bereich As Range
Dim objTab As Worksheet
Dim SuchBegriff As String
'Suchbegriff*************
'SuchBegriff = "Text"
'eventuell Namen anpassen
Set objTab = ActiveSheet
'Bildschirmaktualisierung aus
Application.ScreenUpdating = False
With objTab
'Suche letzte Zeile
lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
'Suche letzte Spalte
lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
'Bereich in B eingrenzen
Set Bereich = .Range("M10:M" & lngRow)
'Merke Spalte aus Bereich
lngCol1 = Bereich.Column
'Farben zurücksetzen in Spalte B
Bereich.Interior.ColorIndex = xlColorIndexNone
'letzte Spalte bestimmen
Set Bereich = Bereich.Offset(0, .Columns.Count - lngCol1)
'Formel einfügen
Bereich.FormulaR1C1 = "=IF(AND(RC13="""",RC" & lngCol1 & "=""" & "Text" & """),0,"""")"
'prüfen ob der Wert 0 in der letzten Spalte vorkommt
If Application.WorksheetFunction.CountIf(Bereich, 0) > 0 Then
'Schleife über alle Zellen mit dem Wert 0
For Each Bereich In Bereich.SpecialCells(xlCellTypeFormulas, 1)
'Zeile gelb färben
.Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
'Zelle rot färben
.Cells(Bereich.Row, lngCol1).Interior.ColorIndex = 3
Next Bereich
End If
'Hilfsspalte löschen
.Columns(.Columns.Count).Delete
End With
'Bildschirmaktualisierung ein
Application.ScreenUpdating = True
Sorry für das blöde Nachfragen :-(
Sonst Super, danke
Anzeige
AW: Hallo Tino,
22.04.2009 16:15:33
Tino
Hallo,
wenn ich Dich jetzt richtig verstanden habe, müsste dies so angepasst werden.
Sub Beispiel()
Dim lngRow As Long, lngCol As Long, lngCol1 As Long
Dim Bereich As Range
Dim objTab As Worksheet
Dim SuchBegriff As String

'Suchbegriff************* 
SuchBegriff = "Test"

'eventuell Namen anpassen 
Set objTab = ActiveSheet

'Bildschirmaktualisierung aus 
Application.ScreenUpdating = False
 
    With objTab
        'Suche letzte Zeile 
        lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
        'Suche letzte Spalte 
        lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
        'Bereich in B eingrenzen 
        Set Bereich = .Range("C10:C" & lngRow)
        'Merke Spalte aus Bereich 
        lngCol1 = Bereich.Column
        'Farben zurücksetzen in Spalte B 
        Bereich.Interior.ColorIndex = xlColorIndexNone
        'letzte Spalte bestimmen 
        Set Bereich = Bereich.Offset(0, .Columns.Count - lngCol1)
        'Formel einfügen 
        Bereich.FormulaR1C1 = "=IF(AND(RC" & lngCol1 & "=""" & SuchBegriff & """,RC13=""""),0,"""")"
        'prüfen ob der Wert 0 in der letzten Spalte vorkommt 
        If Application.WorksheetFunction.CountIf(Bereich, 0) > 0 Then
         'Schleife über alle Zellen mit dem Wert 0 
            For Each Bereich In Bereich.SpecialCells(xlCellTypeFormulas, 1)
             'Zeile gelb färben 
             .Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
             'Zelle rot färben 
             .Cells(Bereich.Row, 13).Interior.ColorIndex = 3
            Next Bereich
        End If
       'Hilfsspalte löschen 
       .Columns(.Columns.Count).Delete
    
    End With
'Bildschirmaktualisierung ein 
Application.ScreenUpdating = True
End Sub


Also es wird geprüft ob in C = "Text" steht und in M nichts, ist dies gegeben wird M rot.
Gruß Tino

Anzeige
JA, hast Du, Perfekt, Vielen Dank owT :-))
22.04.2009 16:49:29
Joachim
AW: Hallo Tino,
23.04.2009 09:06:19
Joachim
Hallo Tino,
wenn ich nicht nach leerern zellen suchen will, ist doch diese Zeile zuständig, oder
If Application.WorksheetFunction.CountBlank(Bereich) > 0 Then ...
Was ändere ich in der Zeile , wenn ich nicht nach leeren, sondern nach <>"BBS" suche will
Code war dieser :
Dim lngRow As Long, lngCol As Long
Dim Bereich As Range
Dim objTab As Worksheet
'eventuell Namen anpassen
Set objTab = ActiveSheet
'Spalte C
With objTab
'Suche letzte Zeile
lngRow = .Cells.Find("*", , xlValues, 2, 1, 2, False, False).Row
lngCol = .UsedRange(, .UsedRange.Columns.Count).Column
Set Bereich = .Range("C10:C" & lngRow)
Bereich.Interior.ColorIndex = xlColorIndexNone
If Application.WorksheetFunction.CountBlank(Bereich) > 0 Then
For Each Bereich In Bereich.SpecialCells(xlCellTypeBlanks)
.Range(.Cells(Bereich.Row, 1), .Cells(Bereich.Row, lngCol)).Interior.ColorIndex = 6
Bereich.Interior.ColorIndex = 3
Next Bereich
End If
End With
Danke Gruss
Joachim
Anzeige
Habs gefunden, danke owT
23.04.2009 12:48:22
Joachim

Forumthreads zu verwandten Themen

Zellen farbig markieren
chrisss

Hallo,
ist es eigentlich bei Excel 2007 nun möglich, dass bei einer Wenn-Funktion eine Zelle farbig ausgefüllt wird. Beispiel: Wenn in Tabelle 1 in A1 ein U steht, soll die Zelle A1 in Tabelle 2 rot ausgefüllt werden.
Ich hatte die Frage schonmal gepostet und die Antwort erhalten, dass...
21.08.2008 13:20:00
Thread-ID: 1003455
8 Beiträge
Zellen farblich Markieren
Hans

Hallo Leute,
Mit den beiden Codes markiere ich bestimmte Zellen farbig (hellgelb, bzw. hellgrau), was auch funktioniert. Allerdings muss ich die Farben im Code festlegen, was ich eigentlich nicht möchte. Ist es möglich die Farbe aus bestimmten Zellen auszulesen und diese per Code einzutrag...
12.10.2008 12:08:00
Thread-ID: 1015830
7 Beiträge
Text in Zelle suchen und markieren
Heiko

Hi, Excelianer,
kenne mich mit der Suche nach Strings nicht gut aus...
Ich habe mit Excel einen Kalender (händisch) erstellt mit dem Datum jeweils eines Monats in Spalte A (Text in Zelle: "01.10.2008", durch Formatierung angezeigt: "Mittwoch, 01. Oktober 2008"). Die Tabellenblätter heiß...
30.10.2008 08:21:00
Thread-ID: 1020459
5 Beiträge
trotz INDIREKT verknüpfte zellen farbig markieren
merlin

Hallo,
gibt es eine Möglichkeit trotz der Verwendung von INDIREKT die verknüpften Zellen markieren zu lassen?
https://www.herber.de/bbs/user/60118.xls
Viele Grüße, vielen Dank.
09.03.2009 11:14:37
Thread-ID: 1058088
3 Beiträge
Mehrere Zellen gleichzeitig farblich markieren
KLAUS

Hallo!
Ich habe eine Tabelle in der von B9 bis V45 in jeder Zelle ein Namenskürzel steht, insgesamt 21 verschiedene.
Jetzt möchte ich alle Kürzel von einer Person, die aber an unterschiedlichen,d.h. nicht zusammenhängenden, Zellen stehen mit wenig Aufwand und Suchaktionen mit einem Arbe...
11.03.2009 12:29:52
Thread-ID: 1059068
7 Beiträge
Datum suchen und markieren
edie

Hallo zusammen,
das recherchieren im Archiv hat mich nicht weiter gebracht, wäre schön, wenn mir jemand helfen könnte.
Im Bereich B6:B50 wird immer wieder ein Datum geschrieben und die Zelle markiert.
Nun soll das markierte Datum in der Spalte AA1:AA200 gesucht und die Zelle markie...
03.06.2009 21:54:16
Thread-ID: 1079017
2 Beiträge
Zellen farblich markieren
Uwe.Siebers

Guten Morgen,
in einem Arbeitsblatt "Zeitdaten" befinden sich in den Zellen "B6:B36" die Angaben zu den Tagen eines Monats (01 bis z.B. 31) In den Zellen "C6:C36" stehen dazu die Wochentage (z.B. Sa, So)
Wie bekomme ich`s nun hin, das die Zellen im Bereich "B6:Z36" immer dann farblich h...
10.09.2009 10:09:17
Thread-ID: 1101686
3 Beiträge
farbliche Nummern suchen und markieren
Bernie

Hallo Spezialisten,
Aus einem Programm bekomme ich eine Excel-Tabelle aufbereitet, in welcher 2 Spalten mit Material-Nummern vorhanden sind.
Jetzt möchte ich gerne die Spalten so farblich markieren, daß dort Nummern, welche ich zuvor als Legende gekennzeichnet und farblich markiert ha...
10.12.2009 20:00:24
Thread-ID: 1123042
8 Beiträge
Zellen automatisch farblich markieren | Herbers Excel-Forum
Olaf Schade
Hallo alle zusammen,
ich möchte gerne Zellen in Abhängigkeit von einem Zahlenwert farblich markieren.
Beispiel: in Zelle A1 steht eine 3, dann sollen die Zellen A1, B1, und C1 grün markiert werden. In Zelle A2 steht eine 5, dann sollen die Zellen A2, B2, C2, D2 und E2 grün markiert werden...
11.01.2010 13:42:31
Thread-ID: 1128861
2 Beiträge
Wert suchen und markieren
Einzel

Hallo,
habe eine Datei wo ich nach Stäben suche. Nun möchte ich, wenn ich z.B. 2 Eingabe alle
Zellen die hinter der 2 liegen makieren.
Im Beispiel wäre das bei Eingabe von 2:
C9:C15 und E9:J15
habe schon mal ein VBA angefangen nur leider markiert er mir nur E9:E15
Hat je...
15.03.2010 18:47:56
Thread-ID: 1146005
6 Beiträge
Anzeige
Suchen und markieren
Einzel

Hallo,
ich such per VBA in Tabelle1 ein Wert zb 2. Nun möchte ich das wenn das Makro die 2 gefunden hat, A bis J markiert. In diesen Fall für Wert2 wäre das der Bereich A1 bis J8.
Habe mal ein altes Makro von mir benutz das ich mit der Forum Hilfe erstellt bekommen habe, da markiert er...
20.03.2010 14:42:21
Thread-ID: 1147257
4 Beiträge
Alle Zellen mit Kommentaren farblich markieren
Ralph P.

Hallo.
Ich möchte in einer Excel-Tabelle alle Zellen farblich markieren, die einen Komentar enthalten. Mein Ansatzt ist dieser:Sub mark()laRow = Cells(Rows.Count, 1).End(xlUp).Row
laCol = Cells(Columns.Count).End(xlToLeft).Column
For col = 1 To laCol For Row = 1 To laRow
Cell...
29.04.2002 11:46:36
Thread-ID: 117105
4 Beiträge
Anzeige

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige