Zahlenreihen vergleichen

hindenberger@gmx.de

Hallo,
ich habe zwei Spalten, die beinahe die gleichen Zahlen enthalten, aber nicht alle.
Wie kann ich am besten über Excel rausfiltern, welche Zahlen in Spalte A sind, aber nicht in B?
Danke.
Gruß,
Patric

AW: Zahlenreihen vergleichen

06.07.2009 16:34:25

David

Hallo Patric,
zum beispiel so:
Tabelle1

	A	B	C	D
1	Spalte A	Spalte B		Diff.
2	1	1
3	2	2
4	3	3
5	4	4
6	5	7		5
7	6	6

verwendete Formeln
Zelle	Formel
D2	{=WENN(NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)=0;"";INDEX($A$1:A7;NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)))}
D3	{=WENN(NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)=0;"";INDEX($A$1:A7;NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)))}
D4	{=WENN(NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)=0;"";INDEX($A$1:A7;NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)))}
D5	{=WENN(NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)=0;"";INDEX($A$1:A7;NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)))}
D6	{=WENN(NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)=0;"";INDEX($A$1:A7;NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)))}
D7	{=WENN(NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)=0;"";INDEX($A$1:A7;NICHT(IDENTISCH(A2:A7;B2:B7))ZEILE(A2:A7)))}

{} Matrixformel mit Strg+Umschalt+Enter abschließen

Tabellendarstellung in Foren Version 1.8

Gruß
David

AW: Zahlenreihen vergleichen

06.07.2009 16:37:57

hindenberger@gmx.de

Hallo,
danke, das hilft schonmal.
Ich kann aber leider nicht immer davon ausgehen, dass die gleichen Zahlen in der gleichen Zeile stehen, da die Spalten ggf. ungleich in der Menge der Zahlen sein könnten.
Bspw
1 1
2 3
3 4
4 5
5 6
6

AW: Zahlenreihen vergleichen

06.07.2009 16:48:25

ransi

HAllo
Versuch mal so:
Tabelle1

	A	B	C	D
1	1	1		2
2	2	3		7
3	3	4		#ZAHL!
4	4	5		#ZAHL!
5	5	6		#ZAHL!
6	7			#ZAHL!

Formeln der Tabelle

Zelle	Formel
D1	{=INDEX($A$1:$A$6;KKLEINSTE(WENN(ZÄHLENWENN($B$1:$B$5;$A$1:$A$6)=0;ZEILE($A$1:$A$6)); ZEILE(A1)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Aber irgendwie beschleicht mich das ungute Gefühl das ich da viel zu ümstänlich unterwegs bin....
ransi

AW: Zahlenreihen vergleichen

06.07.2009 16:51:28

David

Aber irgendwie beschleicht mich das ungute Gefühl das ich da viel zu ümstänlich unterwegs bin....
nein, das passt schon. Deine Lösung basiert auf dem gleichen Prinzip wie meine zweite.
Weniger umständlich geht es nur mit einer Hilfsspalte.
Gruß
David

AW: Zahlenreihen vergleichen

06.07.2009 16:49:24

David

Hallo Patric,
so sollte auch das klappen:
Tabelle1

	A	B	C	D
1	Spalte A	Spalte B		Diff.
2	1	1		5
3	2	2		7
4	3	3		9
5	4	4		#ZAHL!
6	5	6
7	6	8
8	7	10
9	8
10	9
11	10

verwendete Formeln
Zelle	Formel
D2	{=KKLEINSTE(WENN(ISTNV(VERGLEICH($A$2:$A$11;$B$2:$B$8;0));$A$2:$A$11;"");ZEILE(D1))}
D3	{=KKLEINSTE(WENN(ISTNV(VERGLEICH($A$2:$A$11;$B$2:$B$8;0));$A$2:$A$11;"");ZEILE(D2))}
D4	{=KKLEINSTE(WENN(ISTNV(VERGLEICH($A$2:$A$11;$B$2:$B$8;0));$A$2:$A$11;"");ZEILE(D3))}
D5	{=KKLEINSTE(WENN(ISTNV(VERGLEICH($A$2:$A$11;$B$2:$B$8;0));$A$2:$A$11;"");ZEILE(D4))}

{} Matrixformel mit Strg+Umschalt+Enter abschließen

Schriftformate
Zelle	Rot	Grün	Blau	Color	Stil	Unterstreichung	Effekte	Durchgestrichen
A1					Fett
B1					Fett
C1					Fett
D1					Fett

Zellen mit Schriftformatierung automatisch werden nicht dargestellt

Tabellendarstellung in Foren Version 1.8

Wenn kein Treffer mehr gefunden wird, gibt es einen #Zahl-Fehler.
Gruß
David

in Spalte A aber nicht in Spalte B

06.07.2009 16:59:09

WF

Hi Patric,
folgende Arrayformel bringt die richtige Reihenfolge und funktioniert auch bei Texten:
{=INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(B$2:B$20;A$2:A$20)=0;ZEILE($2:$20));ZEILE(A1)))}
und runterkopieren
ARRAY-Formel {=geschweifte Klammern} nicht eingeben;
Abschluß der Formel mit gleichzeitig Strg / Shift / Enter (statt Enter allein); - das erzeugt sie.
Salut WF

AW: Zahlenreihen vergleichen

06.07.2009 17:00:47

hindenberger@gmx.de

Hallo
vielen Dank euch allen.
Perfekt!
Gruß,
Patric

Zahlenreihen vergleichen

Forumthread: Zahlenreihen vergleichen

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Zahlenreihen vergleichen

Forumthread: Zahlenreihen vergleichen

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread