Access Datensätze

Forumthread: Access Datensätze

Access Datensätze

Markus

Hallo Zusammen,
Ich weis ich bin hier in einem Excel Forum aber vielleicht weis ja einer eine Lösung meines Problemes.
Ich habe in Access eine Tabelle die Datensätze enthällt. in der Spalte [Anzahl] ist eine zahl angegeben.
ich möchte nun ein Bericht erstellen der mir den entsprechenden Datensatz so oft wie in der Spalte [anzahl] angegeben ausgibt.
Ist dies überhaubt möglich?
Um hilfe wäre ich sehr Dankbar.
Mit freundlichen Grüßen
M.Schückler

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Access Datensätze

fcs
AW: Access Datensätze

Markus

AW: Access Datensätze

06.04.2012 23:11:54

fcs

Hallo Markus,
grundsätzlich kann man so etwas in ACCESS umsetzen. Es erfordert aber schon gute Kenntnisse in MS-ACCESS.
Dazu muss in ACCESS auch entsprechendes vorbereitet werden.
1. Eine zusätzliche Tabelle, die über ein Schlüsselfeld mit der Datentabelle über eine 1:n Beziehung verknüpft ist.
2. Eine Abfrage, die aus den beiden Daten-Tabellen die Datensätze für den Bericht generiert.
3. Ein VBA-Modul mit den Prozeduren, die die zusätzliche Tabelle bei Bedarf aktualisieren.
4. Makros, die die VBA-Prozeduren von der Bedienoberfläche starten können.
Hier eine Grafik, mit der Objekt-Struktur einer Beispiel-Datenbank.
Userbild

Wenn du mit Office 2007 oder 2010 arbeitest, dann kann ich dir die Beispiel-Datei auch per E-Mail schicken. Kontakt-E-Mail-Adresse findest du hier unter Forums-Seiten--Profile--Profilliste.
Gruß
Franz
Code in einem VBA-Modul der Beispieldatei

'Erstellt unter MS-ACCESS 2010
'Ersteller: fcs
'Datum: 2012-04-06
'Prozeduren zur Aktualisierung der Verknüpfungsdaten zwischen den Tabellen "Liste Namen" und " _
Liste Bericht"
Option Compare Database
Option Explicit
Function UpDate_Tabelle()
'Tabelle "Liste Bericht" aktualisieren
Dim lngAnz As Long
Dim rstZiel As Recordset, rstQuelle As Recordset
'Alle Datensätze in Zieltabelle löschen
Call DatensaetzeLoeschen(strTabellenName:="Liste Bericht")
Set rstQuelle = Application.CurrentDb.TableDefs("Liste Namen").OpenRecordset ' _
Quelldatentabelle
Set rstZiel = Application.CurrentDb.TableDefs("Liste Bericht").OpenRecordset(Options:= _
dbOpenDynaset)
'ID-Nummern der Datensätze in "Liste Namen" gemäß Wert in Feld "Anzahl" in "Liste Bericht"  _
einfügen
With rstQuelle
If .RecordCount > 0 Then
.MoveFirst
Do Until .EOF
With rstZiel
If rstQuelle.Fields("Anzahl").Value > 0 Then
For lngAnz = 1 To rstQuelle.Fields("Anzahl").Value
.AddNew
.Fields("ID").Value = rstQuelle.Fields("ID").Value
.Update
Next
End If
End With
.MoveNext
Loop
End If
End With
Set rstZiel = Nothing: Set rstQuelle = Nothing
End Function
Public Function DatensaetzeLoeschen(ByVal strTabellenName As String, Optional objDatabase As  _
Database)
'Alle Datensätze in Tabelle löschen
If objDatabase Is Nothing Then Set objDatabase = Application.CurrentDb
With objDatabase.TableDefs(strTabellenName)
With .OpenRecordset(Options:=dbOpenDynaset)
If .RecordCount > 0 Then
.MoveLast
Do Until .BOF
.Delete
.MovePrevious
Loop
End If
End With
End With
End Function

AW: Access Datensätze

10.04.2012 13:36:39

Markus

Hallo Franz,
ich bin zu größtem Dank verpflichtet.
angepasst -- gestartet -- begeistert =)
Mfg Markus

Beliebteste Forumthreads (12 Monate)

Forumthread: Access Datensätze

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread