Textdatei mit Trennzeichen | | HERBERS Excel Forum

Forumthread: Textdatei mit Trennzeichen |

Textdatei mit Trennzeichen |

19.05.2013 09:51:08

Andre´

Hallo alle zusammen,
ich möchte gern mit einem Makro bestimmte Werte aus einer Textdatei in Excel schreiben.
hier eine TXT-Bsp.Datei: https://www.herber.de/bbs/user/85398.txt
und nachfolgend die Exceldatei mit den Werten die ausgelesen werden sollen
https://www.herber.de/bbs/user/85399.xls
Ich hoffe mir kann jemand helfen.
Vielen Dank im Voraus!
MFG Andre

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Textdatei mit Trennzeichen |

19.05.2013 10:31:56

Erich
AW: Textdatei mit Trennzeichen |

19.05.2013 10:56:22

Andre´
AW: Textdatei mit Trennzeichen |

19.05.2013 10:51:55

Tino
AW: Textdatei mit Trennzeichen |

19.05.2013 11:50:07

Andre´

AW: Textdatei mit Trennzeichen |

19.05.2013 10:31:56

Erich

Hi André,
hast du das nicht schon mit der Makroaufzeichnung versucht?
Bei mir erzeugt die im Prinzip das hier (Filename anpassen):


Sub OeffneTxt()
Workbooks.OpenText Filename:="F:\exc\www\tmp\85398.txt", Origin:=xlMSDOS, _
StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
ConsecutiveDelimiter:=False, Tab:=False, Semicolon:=False, Comma:=False, _
Space:=False, Other:=True, OtherChar:="|", FieldInfo:=Array( _
Array(1, 1), Array(2, 9), Array(3, 9), Array(4, 9), Array(5, 9), _
Array(6, 9), Array(7, 9), Array(8, 9), Array(9, 1), Array(10, 9), _
Array(11, 1)), TrailingMinusNumbers:=True
End Sub

Schöne Pfingsten!
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

AW: Textdatei mit Trennzeichen |

19.05.2013 10:56:22

Andre´

Hallo Erich,
erstmal Danke für die Meldung.
Ich möchte erreichen, dass die Daten in der geöffneten Datei geschrieben werden und keine neue Datei geöffnet wird.
Problem ist auch, dass die Orginaldatei eine CSV-Datei ist deshalb wollte ich diese öffnen mit:
...
Open Buchung For Input As #1
sText = Input(LOF(1), 1)
Close 1
arrText = Split(sText, vbLf)
...
das funktioniert aber nicht.
Kann man das anders splitten?
MFG Andre

AW: Textdatei mit Trennzeichen |

19.05.2013 10:51:55

Tino

Hallo,
sollte hiermit funktionieren.

Sub Lese_TxT()
Dim sInhalt$, sFilename$
Dim n&, F%
Dim ArInhalt, varTXTRow, varTeil
Dim ArAusgabe()
sFilename = Application.GetOpenFilename("Text Files (*.txt), *.txt")
If sFilename = CStr(False) Then Exit Sub

F = FreeFile
Open sFilename For Binary As #F
sInhalt = Space$(LOF(F))
Get #F, , sInhalt
Close

With Application.WorksheetFunction
    ArInhalt = Split(sInhalt, vbCr)
    For Each varTXTRow In ArInhalt
        varTeil = Split(.Clean(Replace(varTXTRow, Chr(34), "")), "|")
        If Ubound(varTeil) > 9 Then
            n = n + 1
            Redim Preserve ArAusgabe(1 To 3, 1 To n)
            ArAusgabe(1, n) = varTeil(0) 'pos 1 in TxT Zeile 
            ArAusgabe(2, n) = varTeil(8) 'pos 9 in TxT Zeile 
            ArAusgabe(3, n) = varTeil(10) 'pos 11 in TxT Zeile 
        End If
    Next varTXTRow
End With

'Ausgabe*************************** 
With Tabelle1
    .Range("A:C").ClearContents 'alte Daten löschen 
    If n > 0 Then
        ArAusgabe = Application.Transpose(ArAusgabe)
        .Range("A1").Resize(Ubound(ArAusgabe), Ubound(ArAusgabe, 2)) = ArAusgabe
    End If
End With
End Sub

Gruß Tino

AW: Textdatei mit Trennzeichen |

19.05.2013 11:50:07

Andre´

Hallo Tino,
vielen Dank für die Lösung, dies funktioniert auch für die csv Datei.
MFG Andre

Beliebteste Forumthreads (12 Monate)

Textdatei mit Trennzeichen |

Forumthread: Textdatei mit Trennzeichen |

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread