neue Zeile rahmen mit Formular

Forumthread: neue Zeile rahmen mit Formular

10.12.2014 04:13:56

Andrej

Hallo Freunde, ich habe in meiner Excel Tabelle folgendes Formular erstellt:

Private Sub cmdAbbruch_Click()
'Schließt das Formular frmBachelorarbeit
Unload frmBachelorarbeit
End Sub

Private Sub cmdÜbernehmen_Click()
'Fügt die eingetragenen in das Tabellenblatt und schließt das Formular frmBachelorarbeit
Dim intErsteLeereZeile As Long
intErsteLeereZeile = ActiveSheet.Cells(Rows.Count, 2).End(xlUp).Row + 1
ActiveSheet.Cells(intErsteLeereZeile, 2).Value = Me.txtBranche.Value
ActiveSheet.Cells(intErsteLeereZeile, 3).Value = Me.txtUnternehmen.Value
ActiveSheet.Cells(intErsteLeereZeile, 4).Value = Me.txtNachname.Value
ActiveSheet.Cells(intErsteLeereZeile, 5).Value = Me.txtVorname.Value
ActiveSheet.Cells(intErsteLeereZeile, 6).Value = Me.txtThema.Value
ActiveSheet.Cells(intErsteLeereZeile, 7).Value = Me.txtTitel.Value
ActiveSheet.Cells(intErsteLeereZeile, 8).Value = Me.txtSemester.Value
Unload frmBachelorarbeit
End Sub

Damit werden Werte direkt in die nächste leere Zeile eingetragen. Ich möchte das irgendwie hinbekommen, dass die nächste Zeile mit den neuen Werten direkt schwarz eingerahmt wird. Wie macht man das ? Kann ich den Code in das Formular schreiben ? Muss man den Code in das Tabellenblatt schreiben ? Bei Verständnisfragen verweise ich nochmal auf meinen Wissensstand. Vielen Dank für eure Zeit !!

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

AW: neue Zeile rahmen mit Formular

10.12.2014 11:27:52

fcs

AW: neue Zeile rahmen mit Formular

10.12.2014 11:27:52

fcs

Hallo Andrej,
die Anweisungen zum Formatieren kannst du in den Code des Formulars integrieren.
Es ist aber meistens sinnvoll, die eigentlichen Formatieranweisungen und in einer separaten Sub zu machen, die den zu formatierenden Bereich als Parameter übergeben bekommt. So kann man die Sub beliebig oft aufrufen, ohne jeweils den Code wiederholen zu müssen und bei einem neuen Projekt kann man diese Sub einfach per Copy&Paste übernehmen.
Gruß
Franz

Private Sub cmdÜbernehmen_Click()
'Fügt die eingetragenen in das Tabellenblatt und schließt das Formular frmBachelorarbeit
Dim intErsteLeereZeile As Long
intErsteLeereZeile = ActiveSheet.Cells(Rows.Count, 2).End(xlUp).Row + 1
ActiveSheet.Cells(intErsteLeereZeile, 2).Value = Me.txtBranche.Value
ActiveSheet.Cells(intErsteLeereZeile, 3).Value = Me.txtUnternehmen.Value
ActiveSheet.Cells(intErsteLeereZeile, 4).Value = Me.txtNachname.Value
ActiveSheet.Cells(intErsteLeereZeile, 5).Value = Me.txtVorname.Value
ActiveSheet.Cells(intErsteLeereZeile, 6).Value = Me.txtThema.Value
ActiveSheet.Cells(intErsteLeereZeile, 7).Value = Me.txtTitel.Value
ActiveSheet.Cells(intErsteLeereZeile, 8).Value = Me.txtSemester.Value
With ActiveSheet
'      Call prcRahmen(.Range(Cells(intErsteLeereZeile, 2), .Cells(intErsteLeereZeile, 8)))
Call prcRahmenRundum(.Range(Cells(intErsteLeereZeile, 2), .Cells(intErsteLeereZeile, 8)))
End With
Unload frmBachelorarbeit
End Sub
'Die folgenden beiden Makros am besten in einem allgemeinen Modul der Datei anlegen
Public Sub prcRahmen(Bereich As Range)
'Rahmen um und zwischen den Zellen des Bereiches
With Bereich
With .Borders
.LineStyle = xlSolid
.Weight = xlThin
End With
End With
End Sub
Public Sub prcRahmenRundum(Bereich As Range)
'Rahmen um Zellen des Bereiches
With Bereich
.BorderAround LineStyle:=xlSolid, Weight:=xlThin
End With
End Sub

Forumthread: neue Zeile rahmen mit Formular

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread