Viele Spalten untereinander

Forumthread: Viele Spalten untereinander

09.01.2015 16:47:23

Karl

Hallo,
Ich kenne mich leider nicht so gut mit Excel aus ...
habe 728 Spalten , die ich in eine einzige Spalte (ABA) untereinander zusammenführen möchte. Mittels kopieren/Einfügen wird es mir zu lang und nach langem Recherchieren habe ich noch keine lösung gefunden.
Wer kennt eine passende Lösung ?
Danke im Voraus

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Transponieren

09.01.2015 16:57:02

ChrisL
AW: Viele Spalten untereinander

09.01.2015 17:31:49

Karl
AW: Viele Spalten untereinander

09.01.2015 19:14:56

Ralf
AW: Viele Spalten untereinander

09.01.2015 20:45:46

Karl
AW: Viele Spalten untereinander

09.01.2015 19:18:28

fcs

Transponieren

09.01.2015 16:57:02

ChrisL

Hi Karl Heinz
Falls ich richtig verstehe. Bereich kopieren, rechte Maustaste, Inhalte einfügen, Option: Transponieren
cu
Chris

AW: Viele Spalten untereinander

09.01.2015 17:31:49

Karl

Hi Chris,
mit transponieren habe ich es schon versucht dadurch wurden die Spalten lediglich zu Zeilen,
ich hingegen möchte alle spalten untereinader zu einer einzigen langen Spalte machen.
trotzdem danke für den Vorschlag

AW: Viele Spalten untereinander

09.01.2015 19:14:56

Ralf

Hallo,
genau das tut transponieren.
denn beschreibe bitte, was genau getan werden soll oder mache eine Beispieldatei und lade die hier hoch.
Ralf

AW: Viele Spalten untereinander

09.01.2015 20:45:46

Karl

Hallo Franz,
mit dem Makro hat es geklappt die Spalten sind jetzt ordentlich untereinander.
Vielen Dank an alle die mir geholfen haben

AW: Viele Spalten untereinander

09.01.2015 19:18:28

fcs

Hallo Karl Heinz,
Makro-Lösung, die ein neues Blatt anlegt und die Spalten des Quellblatts einzeln kopiert und im Zielblatt in Spalte A untereinander einfügt.
Gruß
Franz

Sub AlleSpalten_untereinander()
Dim wks As Worksheet, wksZ As Worksheet
Dim Spalte As Long, Spalte_L As Long, rngCopy As Range, Zeile_Z As Long
Dim bolNurWerteFormate As Boolean
Dim StatusCalc As Long
Set wks = ActiveSheet
bolNurWerteFormate = True 'ggf. ändern in False
'neues Blatt anlegen für Daten in einer Spalte
ActiveWorkbook.Worksheets.Add after:=wks
Set wksZ = ActiveSheet
With Application
.ScreenUpdating = False
.EnableEvents = False
StatusCalc = .Calculation
.Calculation = xlCalculationManual
End With
With wks
Spalte_L = .UsedRange.Column + .UsedRange.Columns.Count - 1 ' 729
Zeile_Z = 1
For Spalte = 1 To Spalte_L
Application.StatusBar = "Kopiere Spalte: " & Spalte
Set rngCopy = .Range(.Cells(1, Spalte), .Cells(.Rows.Count, Spalte).End(xlUp))
If bolNurWerteFormate = True Then
rngCopy.Copy
With wksZ.Cells(Zeile_Z, 1)
.PasteSpecial Paste:=xlPasteFormats
.PasteSpecial Paste:=xlPasteValues
End With
Else
rngCopy.Copy Destination:=wksZ.Cells(Zeile_Z, 1)
End If
'nächste Einfügezeile
Zeile_Z = Zeile_Z + rngCopy.Rows.Count
Next Spalte
End With
With Application
.CutCopyMode = False
.StatusBar = False
.ScreenUpdating = True
.EnableEvents = True
.Calculation = StatusCalc
End With
End Sub

Forumthread: Viele Spalten untereinander

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread