Wortsuche im Userform (Listbox)

Matthias · 2015-11-14T17:19:12+00:00

Hallo Forumgemeinde, in meinem aktuellen Projekt habe ich eine "Produktsuche" eingefügt, Diese gibt, wenn ich textbox1 enter drücke in einer Listbox die ergebnisse wieder, Soweit so gut, dies Funktioniert auch. Mein Problem was ich habe, ist das nur 10 spalten wiedergegeben werden. ich benötige aber 42 spalten. BSP.: Die Datei https://www.herber.de/bbs/user/101512.xlsm wurde aus Datenschutzgründen gelöscht kann mir jemand helfen dieses Problem zu beheben? Liebe grüße und vielen Dank im Vorraus Matthias Dietz

Hallo,
teste mal:

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Dim s As String
        Dim Found As Range
        Dim FirstAddress As String
        Dim lngRow As Long, lngColumn As Long, lngFoundRow As Long
        Dim avntValues()
        ' On Error Resume Next

        s = Trim(TextBox1.Text) 'Sucheingabe über Textbox1 steuern
        If s = "" Then Exit Sub
        ListBox1.Clear
        With Tabelle4
            Set Found = Tabelle4.Cells.Find(what:=s, LookIn:=xlValues, LookAt:=xlPart, MatchCase:=False)

            If Not Found Is Nothing Then
                FirstAddress = Found.Address
                ListBox1.ColumnCount = 40 'Gibt die Werte der gefundenen Treffer an (Spaltenbezogen)
                Do

                    lngFoundRow = Found.Row

                    Redim Preserve avntValues(1 To 40, 0 To lngRow)

                    For lngColumn = 1 To 40
                        avntValues(lngColumn, lngRow) = Tabelle4.Cells(lngFoundRow, lngColumn).Value
                    Next

                    Set Found = Tabelle4.Cells.FindNext(after:=Found)
                    If Found.Address = FirstAddress Then Exit Do
                    lngRow = lngRow + 1
                Loop

                ListBox1.Column = avntValues

            End If
        End With
    End If
End Sub

Gruß
Nepumuk

Hallo Matthias,

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
Dim s As String
Dim Found As Range
Dim FirstAddress As String
Dim varItem As Variant, varList() As Variant, lngI As Long

If KeyCode = 13 Then
  s = Trim(TextBox1.Text) 'Sucheingabe über Textbox1 steuern
  If s = "" Then Exit Sub
  ListBox1.Clear
  ListBox1.ColumnCount = 42
  With Tabelle4
    Set Found = .Cells.Find(what:=s, LookAt:=xlPart)
    If Not Found Is Nothing Then
      FirstAddress = Found.Address
      Do
        varItem = .Range(.Cells(Found.Row, 1), .Cells(Found.Row, 42))
        Redim Preserve varList(lngI)
        varList(lngI) = varItem
        lngI = lngI + 1
        Set Found = .Cells.FindNext(after:=Found)
      Loop While Not Found Is Nothing And Found.Address <> FirstAddress
    End If
  End With
  If lngI > 0 Then ListBox1.List = Application.Transpose(Application.Transpose(varList))
End If
End Sub

Gruß Sepp

Forumthread: Wortsuche im Userform (Listbox)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Wortsuche im Userform (Listbox)

Forumthread: Wortsuche im Userform (Listbox)

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread