xlsx in xls umwandeln

Forumthread: xlsx in xls umwandeln

19.12.2015 10:14:22

parza

Hallo zusammen,
es wäre schön, wenn ihr für Folgendes eine Lösung hätten.
Ich erhalte regelmäßig für Auswertungen eine Menge Excel-Dateien, die allerdings einmal in xls und einige in xlsx vorliegen. Zur besseren Auswertung sollten alle Dateien in xls vorliegen, d.h. sie müssten von xlsx in xls umgewandelt werden und vor dem Umwandeln sollte ausgewählt werden können, in welchem Ordner/Verzeichnis sich die Dateien befinden.
Noch ein Hinweis: alle Dateien enthalten bereits Makros - bin mir nicht sicher, ob dies wichtig ist.
Danke, parza

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: xlsx in xls umwandeln

19.12.2015 10:30:56

mumpel
AW: xlsx in xls umwandeln

19.12.2015 10:52:09

parza
AW: xlsx in xls umwandeln

19.12.2015 11:37:14

mumpel
AW: xlsx in xls umwandeln

19.12.2015 11:55:55

parza
AW: xlsx in xls umwandeln

19.12.2015 16:43:00

Nepumuk
AW: xlsx in xls umwandeln

20.12.2015 11:48:15

parza

AW: xlsx in xls umwandeln

19.12.2015 10:30:56

mumpel

Hallo!

Zitat:
Noch ein Hinweis: alle Dateien enthalten bereits Makros
____________________________
Quelle: Herber-Forum

Aber nicht die XLSX-Dateien. Diese können technisch bedingt keine Makros enthalten. Bist Du sicher dass Du XLSX meinst und nicht etwas XLSM?
Gruß, René

AW: xlsx in xls umwandeln

19.12.2015 10:52:09

parza

Es sind auf alle Fälle xlsx-Dateien und wenn ich "tradionell" mit "speichern unter" in xls ändere, kommt die Abfrage, ob ich Makros aktivieren will. Könnte dies eine Standardabfrage sein?
Danke, parza

AW: xlsx in xls umwandeln

19.12.2015 11:37:14

mumpel

Wenn man xlsx-Dateien speichert dann dürfte keine Abfrage kommen, da xlsx-Dateien keine Makros enthalten können. Da läuft eventuell etwas schief.

AW: xlsx in xls umwandeln

19.12.2015 11:55:55

parza

Ich bin jetzt nicht auf Arbeit; aber könnte es sein, dass die Ursache hierfür ist, dass ich einmal eine xla-Datei eingebunden habe und nun gerade etwas durcheinander bringe.
Unabhängigdessen wäre mir geholfen, wenn ich eine Lösung für die Umwandlung von xlsx in xls habe. Wie gesagt, vielleicht bringe ich auch gerade was durcheinander.
parza

AW: xlsx in xls umwandeln

19.12.2015 16:43:00

Nepumuk

Hallo,
teste mal (die .xlsx-Dateien werden im Anschluss gelöscht):

Option Explicit

Public Sub Dateiformat()
    Dim objFileDialog As FileDialog
    Dim objWorkbook As Workbook
    Dim strFolder As String, strFilename As String
    Set objFileDialog = Application.FileDialog(msoFileDialogFolderPicker)
    With objFileDialog
        .AllowMultiSelect = False
        .InitialFileName = "D:\" 'Vorauswahl anpassen !!!
        If .Show = -1 Then
            strFolder = .SelectedItems(1)
            If Right$(strFolder, 1) <> "\" Then strFolder = strFolder & "\"
            strFilename = Dir$(strFolder & "*.xlsx")
            With Application
                .DisplayAlerts = False
                .ScreenUpdating = False
            End With
            Do Until strFilename = vbNullString
                Set objWorkbook = Workbooks.Open(Filename:=strFolder & strFilename)
                Call objWorkbook.SaveAs(strFolder & Left$(strFilename, _
                    Len(strFilename) - 1), FileFormat:=xlWorkbookNormal)
                Call objWorkbook.Close(SaveChanges:=False)
                Set objWorkbook = Nothing
                strFilename = Dir$
            Loop
            Call Kill(PathName:=strFolder & "*.xlsx")
            With Application
                .DisplayAlerts = True
                .ScreenUpdating = True
            End With
        End If
    End With
    Set objFileDialog = Nothing
End Sub

Gruß
Nepumuk

AW: xlsx in xls umwandeln

20.12.2015 11:48:15

parza

Hallo Nepumuk,
perfekt!
Ich habe zwar keine Ahnung, wie es funktioniert, aber es ist super.
Danke, parza

Beliebteste Forumthreads (12 Monate)

Forumthread: xlsx in xls umwandeln

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread