Formel kürzen

Forumthread: Formel kürzen

Formel kürzen

05.01.2016 21:29:20

Fabian

Hallo,
gibt es eine Möglichkeit, nachfolgende Formel so einzukürzen das ich die Zelle "Einteilung!E8" nur einmal schreiben kann? Ich muss die Formel ein paar mal eingeben und wenn ich dann jedesmal 9x die Zelle ändern muss.... VIEL ARBEIT
=WENN(Einteilung!E8="U";"U";WENN(Einteilung!E8="F";"F";WENN(Einteilung!E8="F2";"F2"; WENN(Einteilung!E8="AF";"AF";WENN(Einteilung!E8="K";"K";WENN(Einteilung!E8="S";"S"; WENN(Einteilung!E8="Ua";"Ua";WENN(Einteilung!E8="§8";"§8";WENN(Einteilung!E8="Brücke";"B";"")))))))))
Vielen DANK im vorraus
Gruss
Fabian

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Formel kürzen

05.01.2016 21:31:40

Sepp

Hallo Fabian,

=WENN(Einteilung!E8="Brücke";"B";Einteilung!E8)

Gruß Sepp

AW: Formel kürzen

05.01.2016 22:30:14

Daniel

Hi
kann in der Zelle auch noch anderer Text stehen (dh ausser "U", "F", "F2", "AF", "K", "S", "Ua", "§8", "Brücke") und wenn ja, was soll dann erscheinen?
bei deiner Formel erscheint bei anderen Texten der Leerstring
bei Sepps Formel werden auch andere Texte angezeigt.
was möchstest du denn haben?
die kürzteste Formel bekommst du, wenn du eine kleine Hilfstabelle erstellst, in welcher du in der ersten Spalte den zulässigen Text in Einteilung!E8 auflistest und in der zweiten Spalte dann den Text, den die Formel anzeigen soll.
Dann könntest du mit dem SVerweis arbeiten.
dh in Tabelle1, Spalte A und B steht:
U | U
F | F
F2 | F2
AF | AF
K | K
S | S
Ua | Ua
Brücke | B
und die Formel wäre dann:

=WennFehler(SVerweis(Einteilung!E8;Tabelle1!$A:$B;2;falsch);"")

bei Änderung an den Begriffen brauchst du dann nur die Hilfsstabelle anpassen und das wirkt sich dann in allen Formeln aus.
Gruss Daniel

AW: Formel kürzen

05.01.2016 23:20:08

Fabian

Hi,
https://www.herber.de/bbs/user/102599.xlsx
hier ist die Datei.
In dem Reiter "Einteilung" Stehen viele Sachen (Arbeitsplätze, Urlaub usw.) drin. Für jeden Mitarbeiter pro Schicht ein Pulldown. Ich möchten aber im Kalender Januar bis Dezember immer nur die Sachen angezeigt bekommen die den Kalender betreffen. Also NICHT die Arbeitsplätze.

AW: Formel kürzen

05.01.2016 23:44:13

Sepp

Hallo Fabian,
nicht so intelligent, eine Kennwortgeschützte Datei hochzuladen;-))

Gruß Sepp

AW: Formel kürzen

05.01.2016 23:45:10

Fabian

ohhh
SORRY :-)
PW ist frodo

Denke, nur die angegebenen Kürzel sind ...

06.01.2016 03:13:34

Luc:-?

…kalender-relevant, Fabian;
da das ein relativ triviales Problem ist, das man auch so lösen könnte …
=WENNFEHLER(INDEX({"U";"F";"F2";"AF";"K";"S";"Ua";"§8";"B"};VERGLEICH(Einteilung!E6;{"U";"F";"F2"; "AF";"K";"S";"Ua";"§8";"Brücke"};0));"")
…habe ich mir erlaubt, eine längere, 1zellige MatrixFml zu entwickeln, die in jede Kalenderzelle jeden Monatsblattes ohne Änderung einkopiert wdn könnte:
D5[:AH27]: {=WENNFEHLER(INDEX({"U";"F";"F2";"AF";"K";"S";"Ua";"§8";"B"};VERGLEICH(INDEX(Einteilung!$E$6:$AA$188;VERGLEICH(DATWERT(D$2&"."&$B$2&" "&$B$3);Einteilung!$C$6:$C$188*(Einteilung!$B$6:$B$188=$B$2);0);VERGLEICH($C5;Einteilung!$E$4:$AA$4;0));{"U";"F";"F2";"AF";"K";"S";"Ua";"§8";"Brücke"};0));"")}
Einzige Voraussetzung ihrer Funktionalität wäre eine relativ kleine Änderung im Blatt Einteilung → die VerbundZellen in Spalte B müssen den Monatsnamen in jeder ihrer TeilZellen enthalten! Man kann das zwar auch anders lösen, das würde aber die EinheitsFml nur unnötig verlängern. Also im Nutzungsfall dieser Anleitung folgen:
1. Format der VerbundZelle mit dem FormatPinsel auf einen beliebigen, freien und gleichgroßen Bereich übertragen!
2. Originale VerbundZelle auflösen und die den Monatsnamen tragende 1.Zelle des aufgelösten ZellVerbunds auf alle weiteren, ursprünglich dazugehörigen Zellen kopieren!
3. Das Format der VerbundZellenKopie mit dem FormatPinsel auf die Zellen des ursprünglichen Originals rückübertragen!
Nun ist das alte Erscheinungsbild wiederhergestellt, mit dem Unterschied, dass der Monatsname nunmehr nicht nur in einer, der 1., sondern in allen Zellen des Verbunds steht, obwohl natürlich weiterhin nur der Inhalt der 1.Zelle angezeigt wird.
Ich habe das und die MatrixFml für den ganzen Januar und Teile des Februar getestet, wobei mir auffiel, dass das B bei Siegfried falsch steht. Stattdessen haben sich B und U bei Reiser, genau wie schon bei Eicher, ergeben.
Gruß, Luc :-?

Ergänzung: Statt die MatrixKonstanten {"..."} ...

06.01.2016 03:27:06

Luc:-?

…in die Fml zu schreiben, Fabian,
könntest du auch 2 Namen definieren und je eine benannte Fml mit diesen Konstanten anlegen, was allemal rationeller als das Anlegen einer Hilfsspalte lt Daniel wäre, aber (fast) genauso pflegeleicht:
kalRelQVglW ={"U";"F";"F2"; "AF";"K";"S";"Ua";"§8";"Brücke"}
kalRelZVglW ={"U";"F";"F2";"AF";"K";"S";"Ua";"§8";"B"}
In der einheitlichen MatrixFml müssen dann nur noch die Namen anstelle der MatrixKonstanten-Ausdrücke verwendet wdn.
Luc :-?

AW: Denke, nur die angegebenen Kürzel sind ...

09.01.2016 20:13:29

Fabian

Hallo,
sorry für das späte Feedback, war kurz im Urlaub.
Ich hab das nun so gemacht wie beschrieben. VerbundZelle aufgelöst usw. Hab die MatrixFml jetzt nur mal beim Kollegen Eicher im Januar in jede spalte eingefügt. Eigentlich sollte nun am 1.1. ein B und am 4.1. ein U stehen. Leider macht er es aus einem Grund nicht so.
https://www.herber.de/bbs/user/102693.xlsx
Desweiteren wollte ich dann D5:AH5 einfach zum Kollegen Schumm kopieren. Das macht er auch nicht einfach so. Er ändert immer ein paar Zeilen. Gibt es da nicht eine Kopierfunktion die das einfach Stock und Steif kopiert ohne irgend etwas zu verändern?
DANKE
Gruss
Fabian Schumm

AW: Formel kürzen

09.01.2016 20:32:54

Fabian

Klappt doch alles hervorragend, ...

10.01.2016 13:01:23

Luc:-?

…Fabian,
wenn du noch 2 Dinge tust:
1. Berechnungsmodus (Menü Formeln - Berechnungsoptionen) von manuell auf automatisch stellen;
2. Die Fml auch als MatrixFml eingeben, d.h., die Eingabe nicht nur mit Tasten [Enter] bzw [Return] abschließen, sondern dabei auch noch [Ctrl]+[Shift] ([Strg]+[Umsch]) gedrückt halten. Die so abgeschlossene Fml in D5 kann dann erst in die anderen Zellen der Zeile oder Spalte, anschließend die Fmln der ganzen Zeile bzw Spalte in die anderen Zeilen bzw Spalten kopiert wdn.
Die kompletten KalenderFmln von Januar können dann für die jeweilige TagesSpaltenZahl auch auf die anderen Blätter kopiert wdn.
Gruß, Luc :-?

AW: Klappt doch alles hervorragend, ...

12.01.2016 09:43:44

Faian

Hat geklappt. DANKE
an die Strg+Umsch Taste habe ich nicht gedacht :-(
DANKE DANKE DANKE

Beliebteste Forumthreads (12 Monate)

Forumthread: Formel kürzen

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread