mehrere Excel-Dateien zusammenfügen

Forumthread: mehrere Excel-Dateien zusammenfügen

12.07.2017 10:01:28

Tobi

Ich bräuchte dringend eure Hilfe, da ich mich mit Makros in Excel überhaupt nicht auskenne.
Und zwar habe ich folgendes Problem:
Ich habe 1200 Excel-Dokumente in einem Ordner mit jeweils einem Arbeitsblatt und dem gleichen Aufbau/Form.
Aus diesen Dokumenten möchte ich in einem neuen Dokument jeweils die Zelle D5 und D13 der 1200 Tabellen in eine Gesamttabelle automatisiert kopieren-sodass der Wert der Zelle D5 in A1 bis Ax und D13 in B1 bis Bx kopiert wird.
Ich danke im Voraus für eure Hilfe !!!

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: mehrere Excel-Dateien zusammenfügen

12.07.2017 11:06:53

Tino

Hallo,
kannst mal so testen.
Tabellenname der in den externen Dateien verwendet wird anpassen
Pfad wo diese liegen anpassen
Ausgabe Tabelle anpassen

Sub Test()
Dim ArFiles(), ArAusgabe(), sPath$, sDir$, n&
Dim ExTabellenName$

'Name der Tabelle in der externen Datei 
ExTabellenName = "Tabelle1"

'Pfad zum Ordner 
sPath = "C:\Ordner\Ordner\"
ChDrive sPath
ChDir sPath

sDir = Dir(sPath & "*.xls?", vbNormal)
Do While sDir <> ""
    n = n + 1
    Redim Preserve ArFiles(1 To n)
    ArFiles(n) = sDir
    sDir = Dir$()
Loop

If n > 0 Then
    Redim ArAusgabe(1 To Ubound(ArFiles), 1 To 3)
    For n = Lbound(ArFiles) To Ubound(ArFiles)
        'Datei-Name 
        ArAusgabe(n, 1) = ArFiles(n)
        'Zelle D5 
        ArAusgabe(n, 2) = "='" & sPath & "[" & ArAusgabe(n, 1) & "]" & ExTabellenName & "'!R5C4"
'        Zelle D13 
        ArAusgabe(n, 3) = "='" & sPath & "[" & ArAusgabe(n, 1) & "]" & ExTabellenName & "'!R13C4"
    Next n
    
    With Tabelle1 'Ausgabe Tabelle 
        'alte Daten löschen ab A2 
        .Range("A2", .Cells(.Rows.Count, 1)).EntireRow.Delete
        'Ausgabe ab A2 
        With .Range("A2").Resize(Ubound(ArAusgabe), Ubound(ArAusgabe, 2))
            .FormulaR1C1 = ArAusgabe 'Formel einfügen 
            .Value = .Value 'nur Werte 
            .EntireColumn.AutoFit 'Spaltenbreite einstellen 
        End With
    End With
End If
End Sub

Gruß Tino

AW: mehrere Excel-Dateien zusammenfügen

12.07.2017 11:27:01

Tobi

Vielen Dank für die schnelle Antwort
Eine Frage habe ich jedoch noch...Was meinst du mit "Tabellenname der in den externen Dateien verwendet wird anpassen" - es sind 1200 verschiedene Tabellennamen

AW: mehrere Excel-Dateien zusammenfügen

12.07.2017 11:36:05

Tino

Hallo,
es gibt diese 1200 Excel-Files und in dieser ist ja eine Tabelle und diese hat einen Namen.
Wenn alle Dateien gleich aufgebaut sind,
müsste in jeder dieser eine Tabelle mit dem Namen Tabelle1, Tabelle2 oder Tabelle3 enthalten sein.
Gruß Tino

AW: mehrere Excel-Dateien zusammenfügen

12.07.2017 12:03:23

Tobi

ok also sozusagen der Name des Arbeitsblattes
Zum Testen muss ich die Zeile...
5 - mit dem Namen des Arbeitsblattes
7 - Pfad meiner Daten
10 - Ausgabedatei
...ändern.
Oder noch weitere Zeilen ?
Bitte zusätzlich um eine einfache Kurzanleitung, wie ich es in Excel einbringe.
Danke !!!

genau so sollte es gehen...

12.07.2017 12:12:17

Tino

Hallo,
zumindest in meinen Test-Aufbau geht es so der nach deiner Beschreibung aufgebaut war.
Gruß Tino

AW: mehrere Excel-Dateien zusammenfügen

12.07.2017 12:58:05

Tobi

Bitte noch um eine Beschreibung wie ich das Makro in Excel erstelle
Danke

AW: mehrere Excel-Dateien zusammenfügen

12.07.2017 14:19:33

Tino

Hallo,

Öffne Excel

Drücke Alt+F11

Gehe ins VBAProject dieser Exceldatei

Rechte Maus Einfügen Modul

Code in diesem Modul einfügen

Gehe auf die Tabelle, Zeichne einen Button und weise dem dieses Makro zu.

Gruß Tino

Beliebteste Forumthreads (12 Monate)

mehrere Excel-Dateien zusammenfügen

Forumthread: mehrere Excel-Dateien zusammenfügen

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

mehrere Excel-Dateien zusammenfügen

Forumthread: mehrere Excel-Dateien zusammenfügen

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread