Word Dokument erstellen aus Excel Datei

Forumthread: Word Dokument erstellen aus Excel Datei

06.02.2019 22:44:55

Bongobob

Hallo zusammen,
ich habe eine Exceltabelle erstellt, mit welcher verschiedene Textbausteine ausgewählt werden können, um so einen Text zu generieren. Dieser Text wird dann per Makro Überarbeitet (Zeit, Geschlecht etc. anpassen) und dann zusammengefasst in einer Zelle abgespeichert.
Nun möchte ich diesen Text, der in einer Zelle steht, per Knopfdruck in ein Word Dokument überführen. Bestenfalls soll ein Bestimmtes Word Dokument geöffnet werden, welches Kopf und Fußzeile enthält und der generierte Text in eine bestimmte Zeil (oder Textmarken eignen sich hierfür habe ich gelesen?!) geschrieben werden.
Die Excel Seite habe ich soweit fertig. Nun bräuchte ich noch den Code um die Word Datei zu öffnen und den Text an eine bestimmte Zelle einzusetzen.
Wäre klasse, wenn mir hier jemand weiter helfen könnte.
Danke und Grüße,
Bongobob

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

AW: Word Dokument erstellen aus Excel Datei

07.02.2019 00:03:28

fcs

AW: Word Dokument erstellen aus Excel Datei

07.02.2019 00:03:28

fcs

Hallo Bongobob,
dieses Forum hat auch einen Bereich "RECHERCHE" hier kann man dann z.B. die Themen des Forums im Archiv nach dem Begriff Word durchsuchen.
Dann hast du zumendest die Möglichkeit dir die notwendige Inspiration zum Lösungsweg zu holen.
Fürs grobe sollte folgendes funktionieren, dass du an deine ANforderungen anpassen muss.
LG
Franz


Sub datenausexcel_Wordvorlage()
Dim appWord As Object 'Word.Application
Dim wrdDocument As Object 'Word.Document
Dim wks As Worksheet
Dim strVorlage As String
On Error GoTo Fehler
Set wks = ActiveWorkbook.Worksheets("Tabelle1") 'Tabellenblatt mit den _
zu übertragenden Daten
strVorlage = "C:\Users\Public\Test\TestVorlage.dotx"
If Dir(strVorlage, vbNormal) = "" Then
MsgBox "Vorlage-Dokument """ & strVorlage & """ ist nicht vorhanden"
Exit Sub
End If
Set appWord = GetObject(, "word.application")
appWord.Visible = True
'Word-Vorlage als neues Dokument öffnen
Set wrdDocument = appWord.Documents.Add(Template:=strVorlage)
'Zellinhalt an Textmarke einfügen
wrdDocument.Bookmarks("Text_aus_Excel").Range.Text = wks.Cells(1, 1)
appWord.Activate
Fehler:
With Err
Select Case .Number
Case 0 'alles OK
Case 429 'Word ist noch nicht geöffnet
Set appWord = CreateObject("word.application")
Resume Next
Case 91 'objekt-Fehler -  z.B. Textmarke in Word fehlt
Resume Next
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description
End Select
End With
End Sub
Sub datenausexcel_Worddokument()
Dim appWord As Object 'Word.Application
Dim wrdDocument As Object 'Word.Document
Dim wks As Worksheet
Dim strVorlage As String
On Error GoTo Fehler
Set wks = ActiveWorkbook.Worksheets("Tabelle1") 'Tabellenblatt mit den _
zu übertragenden Daten
strVorlage = "C:\Users\Public\Test\TestVorlage.docx"
If Dir(strVorlage, vbNormal) = "" Then
MsgBox "Vorlage-Dokument """ & strVorlage & """ ist nicht vorhanden"
Exit Sub
End If
Set appWord = GetObject(, "word.application")
appWord.Visible = True
'Word-Dokument schreibgeschützt öffnen
Set wrdDocument = appWord.Documents.Open(Filename:=strVorlage, ReadOnly:=True)
'Zellinhalt an Textmarke einfügen
wrdDocument.Bookmarks("Text_aus_Excel").Range.Text = wks.Cells(1, 1)
appWord.Activate
Fehler:
With Err
Select Case .Number
Case 0 'alles OK
Case 429 'Word ist noch nicht geöffnet
Set appWord = CreateObject("word.application")
Resume Next
Case 91 'objekt-Fehler -  z.B. Textmarke in Word fehlt
Resume Next
Case Else
MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description
End Select
End With
End Sub

Infobox / Tutorial

Schritt-für-Schritt-Anleitung

Um ein Word-Dokument aus einer Excel-Datei zu erstellen, kannst du ein Excel-Makro verwenden. Folge diesen Schritten:

Vorbereitung der Excel-Datei: Stelle sicher, dass deine Excel-Datei die benötigten Daten enthält. In diesem Beispiel gehen wir davon aus, dass die Daten auf "Tabelle1" gespeichert sind.
Erstellen des Makros:
- Öffne Excel und drücke ALT + F11, um den VBA-Editor zu öffnen.
- Füge ein neues Modul hinzu, indem du mit der rechten Maustaste auf "VBAProject (DeinWorkbookName)" klickst und "Einfügen" > "Modul" auswählst.
- Kopiere den folgenden VBA-Code in das Modul:

Sub datenausexcel_Wordvorlage()
    Dim appWord As Object 'Word.Application
    Dim wrdDocument As Object 'Word.Document
    Dim wks As Worksheet
    Dim strVorlage As String
    On Error GoTo Fehler
    Set wks = ActiveWorkbook.Worksheets("Tabelle1") 'Tabellenblatt mit den zu übertragenden Daten
    strVorlage = "C:\Users\Public\Test\TestVorlage.dotx"
    If Dir(strVorlage, vbNormal) = "" Then
        MsgBox "Vorlage-Dokument """ & strVorlage & """ ist nicht vorhanden"
        Exit Sub
    End If
    Set appWord = GetObject(, "word.application")
    appWord.Visible = True
    'Word-Vorlage als neues Dokument öffnen
    Set wrdDocument = appWord.Documents.Add(Template:=strVorlage)
    'Zellinhalt an Textmarke einfügen
    wrdDocument.Bookmarks("Text_aus_Excel").Range.Text = wks.Cells(1, 1)
    appWord.Activate
Fehler:
    With Err
        Select Case .Number
            Case 0 'alles OK
            Case 429 'Word ist noch nicht geöffnet
                Set appWord = CreateObject("word.application")
                Resume Next
            Case 91 'objekt-Fehler -  z.B. Textmarke in Word fehlt
                Resume Next
            Case Else
                MsgBox "Fehler-Nr.: " & .Number & vbLf & .Description
        End Select
    End With
End Sub

Makro ausführen: Schließe den VBA-Editor und gehe zurück zu Excel. Du kannst das Makro jetzt über ALT + F8 ausführen und das entsprechende Makro auswählen.

Häufige Fehler und Lösungen

Fehler: Vorlagen-Dokument nicht gefunden: Überprüfe den Pfad zu deiner Word-Vorlage. Stelle sicher, dass die Datei existiert.
Fehler: Word ist nicht geöffnet: Das Makro versucht, Word zu verwenden, aber es ist nicht geöffnet. Das Makro sollte Word automatisch starten, wenn es nicht läuft.
Fehler: Textmarke fehlt: Stelle sicher, dass die Textmarke "Text_aus_Excel" in deinem Word-Dokument vorhanden ist.

Alternative Methoden

Wenn du nicht mit VBA arbeiten möchtest, gibt es auch andere Methoden:

Serienbrief in Word: Du kannst eine Excel-Datei als Datenquelle für einen Serienbrief in Word verwenden. Dies ist besonders nützlich, wenn du mehrere Dokumente auf einmal erstellen möchtest.
Copy & Paste: Du kannst den gewünschten Text manuell aus Excel kopieren und in ein Word-Dokument einfügen, was jedoch weniger automatisiert und zeitraubend ist.

Praktische Beispiele

Einfacher Texttransfer: Wenn du nur einen einfachen Text von Excel nach Word übertragen möchtest, kannst du die vorherige Methode verwenden. Du kannst den Text direkt in eine Zelle eingeben und das Makro ausführen.
Erstellen von Berichten: Du kannst das Makro anpassen, um mehrere Zellen zu lesen und diese in verschiedene Textmarken eines Word-Dokuments einzufügen. So kannst du ein vollständiges Dokument mit verschiedenen Abschnitten erstellen.

Tipps für Profis

Makros optimieren: Du kannst Fehlerbehandlungsroutinen in dein Makro einfügen, um die Nutzererfahrung zu verbessern.
Dynamische Pfade: Verwende Variablen, um den Pfad zur Word-Vorlage dynamisch zu gestalten, sodass du das Makro ohne Anpassungen auf verschiedenen Computern verwenden kannst.
Benutzerdefinierte Formate: Experimentiere mit verschiedenen Word-Dokumentformaten, um das Layout deiner Dokumente zu verbessern.

FAQ: Häufige Fragen

1. Wie erstelle ich einen Serienbrief in Word mit Excel-Daten?
Du kannst Excel als Datenquelle für einen Serienbrief nutzen, indem du in Word die Funktion "Serienbrief" auswählst und die Excel-Datei als Datenquelle angibst.

2. Kann ich mehrere Zellen in ein Word-Dokument übertragen?
Ja, du kannst das Makro anpassen, um Daten aus mehreren Zellen zu lesen und diese an verschiedenen Textmarken im Word-Dokument einzufügen.

Word Dokument erstellen aus Excel Datei

Forumthread: Word Dokument erstellen aus Excel Datei

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Word Dokument aus Excel Datei erstellen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread