Copy/Paste ohne Formatierung

Martin · 2019-06-26T10:03:48+00:00

Hallo zusammen, ein Programm von mir wird auch von anderen Personen genutzt. Immer wieder stelle ich dabei fest, dass mittels Copy/Paste die Formatierungen der ungeschützten Zellen munter geändert werden. Gibt es irgendeine Möglichkeit dies zu verhindern? Z.B. durch - nur "nur Werte einfügen erlauben" - keine Änderungen der Formatierung ungeschützter Zellen beim Einstellen des Blattschutzes zulassen - ... Vielen Dank und viele Grüße Martin

och, das könnte schon per Code gehen, auch ohne direkte Kenntnis der ursprünglichen Formatierung.
der Ablauf im Change-Event-Makro müsste folgender sein:
1. Inhalte der geänderten Zellen in einer Variable zwischenspeichern
2. UNDO ausführen um die ursprüngliche Formatierung wieder herzustellen
3. Inhalte aus dem Array wieder in die Zellen zurückschreiben
das ganze wird etwas komplizierter, weil man berücksichtigen muss, dass der Anwender auch mehrere, nicht zusammenhängende Zellen gleichzeit ändern kann.
Code im Modul des tabellenblatts:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Zelle As Range
Dim arrAdressen
Dim arrFormeln
Dim i As Long
ReDim arrAdressen(1 To Target.Cells.Count) As String
ReDim arrFormeln(1 To Target.Cells.Count) As String
For Each Zelle In Target.Cells
i = i + 1
arrAdressen(i) = Zelle.Address
arrFormeln(i) = Zelle.FormulaR1C1
Next
With Application
.EnableEvents = False
.Undo
For i = 1 To UBound(arrAdressen)
Range(arrAdressen(i)).FormulaR1C1 = arrFormeln(i)
Next
.EnableEvents = True
End With
End Sub

Gruß Daniel

nun gut, kommt halt noch darauf an, was du sonst noch so in dem Blatt machst.
es werden halt die Eingaben erstmal rückgängig gemacht und dann die Werte einzeln nochmal eingegeben.
wenn du jetzt noch komplexe Berchnungen hast, die von den geänderten Zellen abhängen, werden diese jedesmal neu angestoßen.
Optimieren kann man min Makro noch an zwei stellen:
1. neben den Events auch auch noch die automatische Neuberechnung ausschalten
2. die Formeln nicht für jede Zelle einzeln, sondern für jeden Zellblock speichern (Areas)

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Zelle As Range
Dim arrAdressen
Dim arrFormeln
Dim i As Long
Dim AktZelle As Range
Dim Calc As Long
ReDim arrAdressen(1 To Target.Areas.Count) As String
ReDim arrFormeln(1 To Target.Areas.Count) As Variant
Set AktZelle = ActiveCell
For Each Zelle In Intersect(Target, Target.Worksheet.UsedRange).Areas
i = i + 1
arrAdressen(i) = Zelle.Address
arrFormeln(i) = Zelle.FormulaR1C1
Next
With Application
.EnableEvents = False
Calc = .Calculation
.Calculation = xlCalculationManual
.Undo
For i = 1 To UBound(arrAdressen)
Range(arrAdressen(i)).FormulaR1C1 = arrFormeln(i)
Next
.Calculation = Calc
.EnableEvents = True
End With
AktZelle.Activate
End Sub

Gruß Daniel

Forumthread: Copy/Paste ohne Formatierung

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial