Ordner per Makro anlegen

Forumthread: Ordner per Makro anlegen

20.03.2020 08:22:08

Jacqueline

Moin,
ich möchte aus Excel per Makro heraus Ordner anlegen. Dabei soll a) eine Abfrage aufploppen, in der ich entweder den Pfad eintrage oder die Zelle, in der der Pfad steht und b) eine weitere Abfrage, in der der Ordnername eingetragen werden kann oder die Zelle, in der der Ordnername steht:
Kann mir da jemand behilflich sein?
Vielen Dank im voraus!
J.

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Ordner per Makro anlegen

20.03.2020 08:57:07

volti

Hallo Jaqueline,
teste mal, ob der u.a. Code in Deinem Sinne funktioniert.
Für die Pfadabfrage habe ich einen Dialog gewählt. Da kann man natürlich auch eine Inputbox nehmen, wenn es Dir lieber ist.

Option Explicit

Sub OrdnerAnlegen()

 Dim sOrdner As String, sPfad As String

' sPfad = "$E$2"            'Pfad ohne Auswahl vorgeben, ausremmen und anpassen!!!

 On Error GoTo Fehler

 If sPfad = "" Then         'Pfad per Dialog auswählen

  With Application.FileDialog(msoFileDialogFolderPicker)

      .AllowMultiSelect = False

      .title = "Bitte den gewünschten Pfad auswählen!"

      .InitialFileName = ""

      .InitialView = msoFileDialogViewThumbnail

      .ButtonName = "Auswählen"

      If Not .Show = -1 Then Exit Sub

      sPfad = .SelectedItems(1)

  End With

 ElseIf sPfad Like "$*#" Then

  sPfad = Range(sPfad).value

 Else

 End If

 ChDir sPfad                'Pfad einstellen

'Jetzt neuen Ordner ermitteln und erstellen

 sOrdner = InputBox("Bitte den Namen des neuen Ordners angeben!", "Ordner anlegen")

 If StrPtr(sOrdner) = 0 Then Exit Sub

 If sOrdner Like "$*#" Then sOrdner = Range(sOrdner).value

 MkDir sOrdner

 MsgBox "Der Ordner " & sOrdner & " wurde angelegt", vbInformation, "Ordner erstellen"

 Exit Sub

Fehler:

 MsgBox "Es ist der Fehler " & Err & ", " & Error & " aufgetreten", vbCritical, "Ordner erstellen"

End Sub

viele Grüße
Karl-Heinz

AW: Ordner per Makro anlegen

20.03.2020 09:17:44

Jacqueline

Hallo,
erstmal vielen Dank für einen Input. Nur leider komme ich damit nicht so gut klar. Ich habe in meiner Excel-Datei ich verschiedenen Zellen die Informationen über Speicherort- und Ordnername. Die würde ich gerne durch anklicken auswählen können.
VG J.

AW: Ordner per Makro anlegen

20.03.2020 09:28:00

volti

Hallo Jaqueline,
dann solltest Du mal (D)eine Mappe mit Beispielen hier hochladen....
Wenn Du die Ordner/Pfaddaten in Zellen hast, wozu brauchst Du dann noch die Inputbox(en), das ist mir jetzt nicht klar?
viele Grüße
Karl-Heinz

AW: Tolle Idee , Karl-Heinz ...

20.03.2020 09:36:42

Dieter(Drummer)

Hallo Karl-Heinz,
... hat jetzt nicht unbedingt etwas mit der ursächlichn Anfage zu tun.
Im Rahmen deines angegebenen Code ist eine kleine Grafik, die bei Klick den Code in die Zwischenablage legt. Finde ich einfach toll ... und eine prima Idee.
Gruß und einen erfeulichen Tag, Dieter(Drummer)
PS Dein Code funktioniert prima.

AW: Tolle Idee , Karl-Heinz ...

20.03.2020 09:50:51

volti

Danke Dieter,
für die Rückmeldung und schön, dass es Dir gefällt...
Thread offen, für Ursprungsanfrage...
viele Grüße
Karl-Heinz

AW: Tolle Idee , Karl-Heinz ...

20.03.2020 09:55:23

Jacqueline

Hallo Karl-Heinz,
ich wollte das maximal flexibel gestalten, da ich dieses Problem täglich habe und viele Unterordner erstellen muss. Manchmal habe ich die Pfadangaben, die Ordnerangaben oder gar beide in der Excel-Tabelle, manchmal aber auch nicht. Was mir ad hoc helfen würde, wäre ein Makro, dass in Bezug auf die Zelle, in der ich gerade bin, einen Ordner erstellt. Heißt, dass in dieser Zelle steht die komplette Pfadangabe incl des neuen Ordners.
VG Jacqueline

AW: Tolle Idee , Karl-Heinz ...

20.03.2020 10:40:54

UweD

Hallo
folgendes Vorgehen...
- Doppelclick auf eine Zelle mit der Ordnerangabe
- Prüfung ob in dem gewählten Bereich
- Öffnen der Ordnerauswahl (wie von Karl Heinz beschrieben)
- nach der Auswahl wird der Wert aus der Zelle als Unterordner verwendet.
Microsoft Excel Objekt Tabelle1

Option Explicit 
 
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean) 
    On Error GoTo Fehler 
    Dim RNG As Range 
    Dim sOrdner As String, sPfad As String 
     
    Set RNG = Union(Range("A1:A10"), Range("C20:C25")) ' als Beispiel für Zellen mit Ordnerangaben 
     
    If Not Intersect(Target, RNG) Is Nothing Then 
        Cancel = True 
        If Target <> "" Then 
         
            With Application.FileDialog(msoFileDialogFolderPicker) 
                  .AllowMultiSelect = False 
                  .Title = "Bitte den gewünschten Pfad auswählen!" 
                  .InitialFileName = "" 
                  .InitialView = msoFileDialogViewThumbnail 
                  .ButtonName = "Auswählen" 
                  If Not .Show = -1 Then Exit Sub 
                  sPfad = .SelectedItems(1) 
            End With 
             
            sOrdner = sPfad & "\" & Target.Value 
            MkDir sOrdner 
             
            MsgBox "Der Ordner " & sOrdner & " wurde angelegt", vbInformation, "Ordner erstellen" 
        End If 
 
    End If 
     
    Exit Sub 
Fehler: 
    MsgBox "Es ist der Fehler " & Err & ", " & Error & " aufgetreten", vbCritical, "Ordner erstellen" 
End Sub

Der Code MUSS in den Bereich der Tabelle:
- Rechtsclick auf den Tagellenblattreiter
- Code anzeigen
- In das rechte Fenster kopieren
LG UweD

Tolle Idee , kommt mir aber sehr bekannt vor

20.03.2020 10:10:50

Anton

Hallo ,
ich glaube, das fing in diesem Beitrag an ;-)
mfg Anton

Beliebteste Forumthreads (12 Monate)

Forumthread: Ordner per Makro anlegen

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread