IPAdresse formatieren

14.05.2020 18:53:30

Heinzs

Hallo Excelfans,
in Zeile A1 steht folgender Inhalt 1.20.4.5
Wie kann ich diesen Wert - möglichst mit vorhandenen Excelformeln ohne Makroprogrammierung so umwandeln, daß ich 001.020.004.005 erhalte.
Danke vorab für Hilfe
MfG,
Heinz

AW: mit lupos Formelansatz und ...

14.05.2020 19:23:30

neopa

Hallo Heinz,
... mit (ausblendbaren) Hilfsspalten in Spalte C:E folgende Formel in B1:

=WENN(SPALTE(A1)&gt4;"";TEXT(GLÄTTEN(TEIL(WECHSELN($A1;".";WIEDERHOLEN(" ";19));SPALTE(A1)*20-19;20)) +0;"0000")&WENN(C1="";"";"."&C1))
und diese nach rechts bis Spalte E kopieren und i
st nach unten kopierbar.
Danach steht in Spalte B Deine IP-Adresse als Textwert.
(mehr zu Formelansatz von lupo sieh mal hier: http://www.office-hilfe.com/support/showthread.php/22254)
Gruß Werner
.. , - ...

AW: Streichung der 4. Null ...

15.05.2020 11:38:56

neopa

Hallo,
... Luc hat in seinen Beitrag zu Recht darauf aufmerksam gemacht, dass ich eine 0 in der TEXT()-Formatangabe verwendet hatte.
Die Formel muss natürlich korrekt nur so lauten:
=WENN(SPALTE(A1)&gt4;"";TEXT(GLÄTTEN(TEIL(WECHSELN($A1;".";WIEDERHOLEN(" ";22));SPALTE(A1)*22-21;22)) +0;"000")&WENN(C1="";"";"."&C1))
worin der vordere Formelteil: WENN(SPALTE(A1)&gt4;""; noch weggelassen werden kann, wenn nur bis Spalte E ziehend kopiert wird.
Gruß Werner
.. , - ...

AW: IPAdresse formatieren

14.05.2020 19:49:22

Daniel

Hi
entweder mit einer Zwischenformel
B1: =WECHSELN(A1;".";WIEDERHOLEN(" ";100))
C1: =TEXT(LINKS(B1;3);"000\.")&TEXT(TEIL(B1;100;100);"000\.")&TEXT(TEIL(B1;200;100);"000\.")&TEXT(TEIL(B1;300;100);"000")
wenns direkt in einer Zelle sein soll, kannst du auch das "B1" in der Formel in C1 durch die Formel aus B1 ersetzen (ohne das "=")
wird dann etwas länger, weil es mehrfach vorkommt:
B1: =TEXT(LINKS(WECHSELN(A1;".";WIEDERHOLEN(" ";100));3);"000\.")&TEXT(TEIL(WECHSELN(A1;".";WIEDERHOLEN(" ";100));100;100);"000\.")&TEXT(TEIL(WECHSELN(A1;".";WIEDERHOLEN(" ";100));200;100);"000\.")&TEXT(TEIL(WECHSELN(A1;".";WIEDERHOLEN(" ";100));300;100);"000")
allerdings kann man Zeilenumbrüche auch in Formeln verwenden, um diese innerhalb der Bearbeitungszeile übersichtlicher zu machen (auf das Formelergebnis hat das keinen Einfluss)
=TEXT(LINKS(WECHSELN(A1;".";WIEDERHOLEN(" ";100));3);"000\.")
&TEXT(TEIL(WECHSELN(A1;".";WIEDERHOLEN(" ";100));100;100);"000\.")
&TEXT(TEIL(WECHSELN(A1;".";WIEDERHOLEN(" ";100));200;100);"000\.")
&TEXT(TEIL(WECHSELN(A1;".";WIEDERHOLEN(" ";100));300;100);"000")
Gruß Daniel

Kürzeste Lösung mit XLM-Funktion

14.05.2020 23:42:48

Luc:?

Morhn, Heinz;
falls du die uralten XLM-Fktt verwenden darfst, die nur in benannten Fmln eingesetzt wdn können und außerdem die Speicherung als .xlsm/b erfordern, kannst du dein Problem elegant mit folgd Fmln lösen, sofern du ein dt Xl verwendest (bei einer anderssprachigen Xl-Version musst du die Pktt ggf ersetzen):
=SUMMENPRODUKT(IPWerte;10^(3*{3.2.1.0}))
IPWerte:=AUSWERTEN("{"&A1&"}")
Der sich ergebende maximal 12stellige Wert kann dann entsprd formatiert wdn oder mit der Xl-Fkt TEXT und gleichem Format 000\.000\.000\.000 in dein WunschErgebnis (als Text) gewandelt wdn.
Werner hatte dabei übrigens eine 0 zuviel verwendet.
Gruß, Luc :-?
Der beste Beweis für intelligentes Leben im Universum ist, dass noch niemand versucht hat, Kontakt mit uns aufzunehmen. H.Lesch, 2018, Sonneberg
Deshalb Intelligenz steigern mit

AW: Kürzeste Lösung mit XLM-Funktion

15.05.2020 00:02:02

Daniel

cool.
passt solange es nicht mehr als 15 stellen werden.

AW: Kürzeste Lösung mit XLM-Funktion

15.05.2020 05:11:02

Günther

Moin Heinz,
ein Forum lebt ja von den Gegensätzen. Luc :-? hat was zum Thema "uralt" beigetragen, dann nehme ich mal "recht neu" ... (3 Lösungs-Ansätze mit Power Query).
=> https://my.hidrive.com/lnk/KOAmDlvw
Gruß
Günther
-.-.-.-

Da ich mich nicht mehr über den "eigenwilligen" Hindernislauf beim Foren-Upload ärgern will, stelle ich meine Uploads hier nur noch in meiner DE-Cloud zur Verfügung. Den Link findest du im Beitrags-Text. Abrufe sind natürlich freiwillig und werden selbstredend nicht ausgewertet.

AW: Danke für Deine Aufmerksamkeit owT

15.05.2020 11:43:24

neopa

Gruß Werner
.. , - ...

AW: IPAdresse formatieren

15.05.2020 12:20:19

Heinzs

Hallo alle zusammen,
danke für eure Vorschläge; da die Formeln für Enduser jedoch sehr komplex sind, habe ich ein Makro geschrieben.
Danke nochmals an alle!
MfG
Heinz

Meine auch? Und 'ne fertige VBA-/UDF-Lösung ...

15.05.2020 16:32:49

Luc:?

…hättest du auch haben können!
Leute gibt's… :-[
Luc :-?

IPAdresse formatieren

Forumthread: IPAdresse formatieren

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

IPAdresse formatieren

Forumthread: IPAdresse formatieren

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread