(mehrere) Bilder einfügen

Forumthread: (mehrere) Bilder einfügen

16.10.2021 14:13:54

M@tt

Hallo ins Forum,
ich möchte 1 - 6 Bilder , (das ist unterschiedlich) aus einem speziellen Ordner auswählen können und diese Bilder dann in ein Worksheet an vorgegebener Position einfügen.
https://www.herber.de/bbs/user/148643.xlsm
Zusätzlich sollen sie noch verkleinert werden. Leider scheitere ich bisher an der Automatisierung meines Vorhabens an verschiedenster Stelle. Es geht bei der geplanten Bildposition schon los.
Vielen ank für Eure Hilfe ;-).
Gruß M@tt

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: (mehrere) Bilder einfügen

16.10.2021 15:04:28

Hajo_Zi
AW: (mehrere) Bilder einfügen

16.10.2021 15:28:28

Nepumuk
AW: (mehrere) Bilder einfügen

16.10.2021 15:46:28

M@tt

AW: (mehrere) Bilder einfügen

16.10.2021 15:04:28

Hajo_Zi

Hallo M@tt,
warum 6 Variablen für 6 Bereiche?
Die hätte ich doch direkt angegeben Range("A23")...
Bilder einfügen, schaue hier
http://hajo-excel.de/inhalt_vba_bild.htm
Grußformel

AW: (mehrere) Bilder einfügen

16.10.2021 15:28:28

Nepumuk

Hallo M@tt,
teste mal:


Option Explicit
Private Sub CommandButton1_Click()
Dim objFileDialog As FileDialog
Dim objShape As Shape
Dim aobjImageRange(1 To 6) As Range
Dim ialngIndex As Long
Set objFileDialog = Application.FileDialog(msoFileDialogFilePicker)
With objFileDialog
.AllowMultiSelect = True
.InitialFileName = "C:\Users\Ma\OneDrive - GA\Pictures\ZZZProbleme\"
With .Filters
If .Count > 0 Then Call .Delete
Call .Add("Bilddateien", "*.jpg;*.gif;*.bmp")
End With
If .Show Then
Set aobjImageRange(1) = ThisWorkbook.Sheets("Tabelle1").Cells(20, 1)
Set aobjImageRange(2) = ThisWorkbook.Sheets("Tabelle1").Cells(20, 4)
Set aobjImageRange(3) = ThisWorkbook.Sheets("Tabelle1").Cells(30, 1)
Set aobjImageRange(4) = ThisWorkbook.Sheets("Tabelle1").Cells(20, 4)
Set aobjImageRange(5) = ThisWorkbook.Sheets("Tabelle1").Cells(40, 1)
Set aobjImageRange(6) = ThisWorkbook.Sheets("Tabelle1").Cells(40, 4)
For ialngIndex = 1 To .SelectedItems.Count
Set objShape = ThisWorkbook.Sheets("Tabelle1").Shapes.AddPicture( _
Filename:=.SelectedItems(ialngIndex), LinkToFile:=msoFalse, SaveWithDocument:=msoTrue, _
Left:=aobjImageRange(ialngIndex).Left, Top:=aobjImageRange(ialngIndex).Top, Width:=-1, Height:=-1)
With objShape
.LockAspectRatio = msoTrue
.Height = 141
End With
Next
End If
End With
Set objFileDialog = Nothing
Set objShape = Nothing
Erase aobjImageRange
End Sub

Gruß
Nepumuk

AW: (mehrere) Bilder einfügen

16.10.2021 15:46:28

M@tt

Hallo Nepumuk,
vielen herzlichen Dank, das ist die Lösung. Mit soviel Code hätte ich nicht gerechnet :-) Es funktioniert wie gewünscht.
Einen schönen Tag wünsche ich noch allen Helfern sowie den Hilfesuchenden

Forumthread: (mehrere) Bilder einfügen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread