Mehrere Ergebnisse EINEM Kunden zuweisen

Forumthread: Mehrere Ergebnisse EINEM Kunden zuweisen
3 Beiträge zu diesem Forumthread
Anzeige
VBA Beispiele zu verwandten Themen

Forumthread: Mehrere Ergebnisse EINEM Kunden zuweisen

02.05.2024 13:56:04

Kevin K.

Hallo zusammen,

hoffe Ihr könnt mir behliflich sein bei meinem kleinem Anliegen.
In meiner Liste habe ich Kundennummern und Kennungen. Jede Kudnennummer hat mehrere Kennungen.
Ich würde gerne in einem neuen Sheet die doppelten Kundennummern rauslöschen (Duplikate löschen) und mir rechts ALLE Ergebnisse anzeigen lassen (getrennt nach Komma) die dem Kunden zugeordnet sind.

Ziel: Links die Kundennummer nur einmal (keien duplikate) und rechts ALLE dazugehörigen Kennungen getrennt nach Komma.

Im Anhang habe ih mal ein Beispiel erstellt.

Tabelle 1 Ausgangsposition, Tabelle 2 Wunschposition.

Datei: https://www.herber.de/bbs/user/169214.xlsx

VIELEN LIEBEN DANK IM VORAUS

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Mehrere Ergebnisse EINEM Kunden zuweisen

02.05.2024 14:16:19

peter
AW: Mehrere Ergebnisse EINEM Kunden zuweisen

02.05.2024 14:27:52

{Boris}
AW: Mehrere Ergebnisse EINEM Kunden zuweisen

02.05.2024 17:31:14

Kevin K.

AW: Mehrere Ergebnisse EINEM Kunden zuweisen

02.05.2024 14:16:19

peter

Hallo

in A2:


=SORTIEREN(EINDEUTIG(Tabelle1!A2:A13))

in B2:


=TEXTVERKETTEN(",";WAHR;SPALTENWAHL(FILTER(Tabelle1!A2:B13;Tabelle1!A2:A13=A2);2))

Peter

AW: Mehrere Ergebnisse EINEM Kunden zuweisen

02.05.2024 14:27:52

{Boris}

Hi Peter,

SPALTENWAHL braucht es hier nicht, wenn man den Filterergebnisbereich nur auf die Spalte B beschränkt:

=TEXTVERKETTEN(",";WAHR;FILTER(Tabelle1!B$2:B$13;Tabelle1!A$2:A$13=A2))

Hab noch die Zeilen fixiert, damit man die Formel auch runterkopieren kann.

Aus Laune am Rande - alles in nur EINER Formel:

=LET(e;SORTIEREN(EINDEUTIG(Tabelle1!A2:A13));HSTAPELN(e;NACHZEILE(e;LAMBDA(a;TEXTVERKETTEN(",";WAHR;FILTER(Tabelle1!B2:B13;Tabelle1!A2:A13=a))))))

VG, Boris

AW: Mehrere Ergebnisse EINEM Kunden zuweisen

02.05.2024 17:31:14

Kevin K.

Super vielen lieben Dank