Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1980to1984
1980to1984
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Anzeige
Inhaltsverzeichnis

=min -> nur jede 3 Zeile betrachten

Forumthread: =min -> nur jede 3 Zeile betrachten

=min -> nur jede 3 Zeile betrachten
05.07.2024 17:45:25
Stefan
Hallo zusammen,

ich bräuchte bitte mal wieder eure Hilfe.
Ich möchte in einer zelle (a1) die kleinste Einheit einer Tabelle (E7:V183) anzeigen lassen.

=min(E7:V183)

Es soll aber jetzt nur jede 3 Zeile betrachtet werden, also E7:V7, E10:V10, E13:V13, ...
Wie kann ich dies in eier Formel darstellen?

Vielen Dank im Voraus

Gruß
Stefan

Anzeige

12
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: =min -> nur jede 3 Zeile betrachten
05.07.2024 18:03:23
daniel
Hi

=Aggregat(15;6;E7:V183/(Rest(Zeile(E7:V183);3)=1);1)

Gruß Daniel
AW: =min -> nur jede 3 Zeile betrachten
05.07.2024 18:31:47
Stefan
Hallo Daniel,

Danke für die schnelle Antwort.
Ich dachte ich kann das dann einfach auf meine Tabelle übertragen / ändern. Klappt leider nicht

Ich hab mal eine Beispieldatei gebastelt, diese geht über 2 Tabellenblätter.
Auf Tabelle 1 sollte eigentlich Ergebnis 1 = 1, ergebnis 2=2, Ergbenis 3=3 sein.
Kannst du mal schauen wo ich hier einen Fehler drin habe.

https://www.herber.de/bbs/user/170725.xlsx

Danke
Gruß
Stefan
Anzeige
AW: =min -> nur jede 3 Zeile betrachten
05.07.2024 18:43:22
BoskoBiati2
Hi,

da kein Wunschergebnis vorliegt, vielleicht so: 

=AGGREGAT(15;6;Tabelle2!$E$7:$V$183/(REST(ZEILE(Tabelle2!$E$7:$V$183);3)=REST(ZEILE(A1);3));1)



Gruß

Edgar
AW: =min -> nur jede 3 Zeile betrachten
05.07.2024 19:40:48
daniel
Hi
das passt schon
du musst, wenn du die Formel in weitere Zellen kopierst, die Zellbereiche, die dabei nicht mitwandern sollen, fixieren, also:

=Aggregat(15;6;$E$7:$V$183/(Rest(Zeile($E$7:$V$183);3)=1);1)

wenn du nicht mehr die Zeilen 7, 10, 13, 16 usw auswerten willst sondern die nächsten Zeilen 8, 11, 14, 17, dann ist der Rest-Wert der Zeile nicht mehr 1, sondern 2.
und wenn du die Zeilen 9, 12, 15, 18 auswerten willst, ist der Restwert 0.
das musst du in der Formel noch anpassen.

Ergebnis 1: =Aggregat(15;6;$E$7:$V$183/(Rest(Zeile($E$7:$V$183);3)=1);1)
Ergebnis 2. =Aggregat(15;6;$E$7:$V$183/(Rest(Zeile($E$7:$V$183);3)=2);1)
Ergebnis 3: =Aggregat(15;6;$E$7:$V$183/(Rest(Zeile($E$7:$V$183);3)=0);1)


Gruß Daniel
Anzeige
AW: Deine Angaben sind mE nicht eindeutig, ...
06.07.2024 12:53:54
neopa C
Hallo Stefan,

... deshalb nachgefragt:
Welche Ergebniswerte möchtest Du als 1., 2., 3., ermitteln , wenn Du in Deiner Tabelle2 alle 1en durch z..B. eine 4 und alle 3en durch z..B. eine 7 ersetzt?

Gruß Werner
.. , - ...
AW: Deine Angaben sind mE nicht eindeutig, ...
08.07.2024 11:25:29
Stefan
Hallo Werner,

sorry, beim zweiten mal lesen meiner frage habe ich selbst gemerkt das es nicht ganz klar ist...

für Ergebnis 1 (Tabelle1), soll das kleinste Ergebnis aus Tabelle2 Reihe 7, 10, 13, ...
für Ergebnis 2 (Tabelle1), soll das kleinste Ergebnis aus Tabelle2 Reihe 8, 11, 14, ...
für Ergebnis 3 (Tabelle1), soll das kleinste Ergebnis aus Tabelle2 Reihe 9, 12, 15, ...

Wenn also z.B. in Zeile 9 sich ein Ergebnis von 3 auf 1 ändert, soll in Tabelle1 Ergbenis 3 auch auf 1 ändern.

Gruß
Stefan
Anzeige
AW: dann ...
08.07.2024 12:07:23
neopa C
Hallo Stefan,

... reicht auch eine Formel, die Du einfach nach unten ziehen kannst.
In meiner älteren XL-Version z,B. so: =AGGREGAT(15;6;Tabelle2!$E$7:$V$183/(REST(ZEILE($E$7:$V$183);3)=REST(ZEILE(B1);3));1)

Gruß Werner
.. , - ...
AW: dann ...
08.07.2024 12:54:18
Stefan
Hallo,

vielen Dank schon mal. In meiner Beispieldatei funktioniert es wie gewünscht...
Ich habe versucht dies nun in meine Tabelle zu übernehmen, leider bekomme ich hier nur #ZAHL angezeigt.

=AGGREGAT(15;6;Trim A!$F$7:$W$183/(REST(ZEILE('Trim A'!$F$7:$W$183);3)=REST(ZEILE(B1);3));1)

Kannst du mir sagen ob ich hier einen Fehler drin habe?

Gruß
Stefan
Anzeige
AW: sagen kann ich es nicht ;-) aber ...
08.07.2024 15:52:23
neopa C
Hallo Stefan,

... ich kann es Dir schreiben. Es fehlen bei Dir Hochkommas um den Tabellenblattnamen. Also richtig muss es bei Deinem Blattnamen (beinhaltet mit einem Leerzeichen ein Sonderzeichen) so: =AGGREGAT(15;6;'Trim A'!F$7:W$183/(...

wobei Du für ZEILE() den Blattnamen nicht brauchst.

Also korrekt ausreichend ist: =AGGREGAT(15;6;'Trim A'!F$7:W$183/(REST(ZEILE(F$7:F$183);3)=REST(ZEILE(B1);3));1)

Gruß Werner
.. , - ...
Anzeige
AW: sagen kann ich es nicht ;-) aber ...
08.07.2024 18:41:14
Stefan
Vielen Herzlichen Dank, jetzt funktioniert es genau wie gewünscht. :) :) :)
AW: =min -> nur jede 3 Zeile betrachten
05.07.2024 20:25:57
daniel
noch ne Variante für Excel 365

=LET(x;Tabelle2!E7:V183;b;3;MIN(ZEILENWAHL(x;SEQUENZ(ZEILEN(x)/b;;1;b))))

die 1 steht dafür, dass in der ersten Zeile bekonnen werden soll, dh dann diese 1 auf 2 und 3 für die weiteren Auswertungen abändern.

Gruß Daniel
Anzeige
AW: =min -> nur jede 3 Zeile betrachten
05.07.2024 19:30:26
Luschi
Hallo Stefan,

entweder so: =AGGREGAT(15;6;Tabelle2!$E$7:$V$183/(REST(ZEILE(Tabelle2!$E$7:$V$183);3)=0);1)
oder als 365-Array-Formel:
=LET(a;Tabelle2!E7:E183;
b;WEGLASSEN(REDUCE("";a;
LAMBDA(aa;bb;
WENN(REST(ZEILE(bb);3)=0;
VSTAPELN(aa;BEREICH.VERSCHIEBEN(bb;;0;;18));aa)));1);MIN(b))

Gruß von Luschi
aus klein-Paris

PS: beide Formeln in Deiner Beispieldatei getestet!


Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Live-Forum - Die aktuellen Beiträge
Datum
Titel
17.05.2026 19:23:24
VBA - Blattschutz lässt sich mit Code nicht ausschalten
17.05.2026 13:47:03
Laufende Uhrzeit in einer Zelle
14.05.2026 13:31:09
Zeichen ausblenden
14.05.2026 09:50:42
Makro für MacOs
13.05.2026 19:14:18
Gleichheitszeichen
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum