Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1984to1988
1984to1988
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Falsches Jahr in erster KW 2025 angezeigt

Forumthread: Falsches Jahr in erster KW 2025 angezeigt

Falsches Jahr in erster KW 2025 angezeigt
18.07.2024 11:12:59
Sonja24
Hallo,

ich möchte passend zum Datum in der nächsten Zeile die zugehörige KW+Jahr anzeigen. Hierzu verwende ich diese Formel.
Beispieldatei: https://www.herber.de/bbs/user/171089.xlsx

=WENN(UND(MONAT(D3)=1;ISOKALENDERWOCHE(D3)=53);ISOKALENDERWOCHE(D3)&"-"&(JAHR(D3)-1);ISOKALENDERWOCHE(D3)&"-"&JAHR(D3))

Ergebnis:
09. Dez 16. Dez 23. Dez 30. Dez 06. Jan 13. Jan 20. Jan
50-2024 51-2024 52-2024 1-2024 2-2025 3-2025 4-2025


Soweit klappt das auch, bis auf die erste Woche im Januar 2025. Da zeigt mir Excel die KW 1/2024 an.
Ich dachte bei der Verwendung der Isokalenderwoche würde dieses Problem nicht passieren. Wie kann ich es hinbekommen, das ich die richtige KW/Jahr als Ergebnis bekomme?

Gruß
Sonja
Anzeige

26
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: mit KALENDERWOCHE() ...
18.07.2024 11:25:45
neopa C
Hallo Sonja,

... in D3: =WENN(D3="";"";KALENDERWOCHE(D3;21)&"-"&JAHR(D3+6)) und nach rechts ziehend kopieren.

Gruß Werner
.. , - ...
AW: Falsches Jahr in erster KW 2025 angezeigt
19.07.2024 12:44:45
daniel
Hi
die Logik ist die:
wenn Ende Dezember die Kalenderwoche 1 ausgebeben wird, dann ist das schon die Kalenderwoche aus dem Folgejahr.
wenn Anfang Januar die Kalenderwoche 52 oder 53 ausgeben wird, dann ist das noch Kalernderwoche aus dem Vorjahr.
damit ergibt sich folgende Formel, wenn man weiß, dass ein WAHR als 1 und ein FALSCH als 0 verrechnet wird:

=ISOKALENDERWOCHE(D3)&"-"&JAHR(D3)-UND(MONAT(D3)=1;ISOKALENDERWOCHE(D3)&gt50)+UND(MONAT(D3)=12;ISOKALENDERWOCHE(D3)=1)

in Excel 365 würde man das mit LET vereinfachen:

=LET(k;ISOKALENDERWOCHE(D3);j;JAHR(D3);m;MONAT(D3);k&"-"&j+UND(m=12;k=1)-UND(m=1;k>50))

Wenn ISOKALENDERWOCHE fehlt, nimmt man KALENDERWOCHE(datum;21)

Gruß Daniel
Anzeige
AW: wozu dies so? ...
19.07.2024 13:15:50
neopa C
Hallo Daniel,

... Sonja hatte sich doch bereits gestern Mittag für meinen einfacheren Lösungsvorschlag bedankt. Wenn Du in diesem einen potentiellen Fehler siehst, solltest Du dies schon auch so benennen sowie erklären, wo einer solcher vorliegt. Ansonsten sehe ich momentan keinerlei Vorteil in Deinem Formelvorschlag.

Gruß Werner
.. , - ...
Anzeige
AW: wozu dies so? ...
19.07.2024 13:29:57
daniel
wieso nicht? sind alternative Lösungsvorschläge verboten?
darf man nicht mehr andere Möglichkeiten aufzeigen, wie man das Problem lösen kann?
haben wir ein Exklusiv-Recht dass nur einer Antworten darf oder dass nach einem Dankeschön keine anderen mehr Antworten dürfen?
steht dazu was in den Forumsregeln?

ich sehe den Vorteil meiner Lösung darin, dass dass sie der natürlichen Logik folgt und sie so einfacher verständlich ist.
zu jedem Satz aus meiner Beschreibung passt ein Block in der Formel, womit auch der Rechenweg und die Erklärung, warum das so funktioniert gegeben ist.
ich denke immer, dass der Fragesteller eine Lösung braucht, die nicht nur funktioniert, sondern die er auch versteht.

Anzeige
AW: ist nur eine indirekte Antwort auf meine Frage ...
19.07.2024 14:17:25
neopa C
Hallo nochmal,

... natürlich kann und teils sogar sollte man alternative Lösungsvorschläge aufstellen. Ergänzende Erklärungen dazu sind sicherlich für viele Leser willkommen. Wenn aber nach einen durch die/den TE offensichtlich "abgeschlossen" thread (noch dazu einen ganzen Tag später) neue Lösungsmöglichkeiten aufgezeigt werden, könnte dies zumindest evtl. die/den TE verunsichern, wenn der zusätzliche nachträgliche Beitrag nicht als alternativer Lösungsvorschlag gekennzeichnet ist.

Mit Deiner nun erfolgten Aussage, hast Du indirekt bestätigt, dass mein Lösungsvorschlag nicht falsch war/ist. Damit betrachte ich meine Frage nunmehr als beantwortet und den thread für mich als endgültig abgeschlossen.

Gruß Werner
.. , - ...


Anzeige
AW: ist nur eine indirekte Antwort auf meine Frage ...
19.07.2024 14:55:41
daniel
Ok, eigentlich prüfe ich fremde Lösungen nicht.
aber da du mich drum gebeten hast, habe ich ich es gemacht.

ich vermute mal, du meinst diese Lösung hier: =WENN(D3="";"";KALENDERWOCHE(D3;21)&"-"&JAHR(D3+6))
also einfach das Datum für die Ermittlung der Jahreszahl um 6 Tage verschieben.
Das funktioniert vielleicht in diesem Jahr und wenn dann auch nur deshalb weil hier nur Montage abgefragt werden.
Für das Jahr 2020 und 2026 gibt deine Formel für den letzten Montag im Jahr falsche Ergebnisse aus. (Beispiel: 28.12.2020 -> KW53-2021).
also immer, Wenn der letzte Montag im Jahr vor dem 29. liegt.
auch für andere Wochentage stimmt das Ergebnis nicht.
Deine Formel ist nicht allgemeingültig für jedes beliebige Datum anwendbar.
Sie wirkt auch einfach nur dahingeschludert und nicht durchdacht.

sollte ich das bewerten: Setzen 6.
wenn du das mit Absicht machst (du bist ja kein dummer Mensch) sollte man über andere Konsequenzen nachdenken.


Anzeige
AW: solches ist nicht mein Stil ...
19.07.2024 16:28:56
neopa C
Hallo nochmal,

... ich hatte Dich 13:15 höflich angefragt und erhalte daraufhin von Dir eine Aussage, die zumindest aus meiner Sicht schon unsachlich war, wie auch nun teilweise wieder.

Das was ich sachliches auf meine Eingangsfrage an Dich erwartet hatte, hast Du dann erst in Deiner Aussage von 14:55 mitgeteilt. Allerdings dies dann leider wieder eingebettet in unsachliches.

Richtig ist, das ich meinen gestrigen Formelvorschlag hätte auch für andere Jahresübergänge hätte selbst prüfen sollen/können. Nun ja, ich hab von mir nie behauptet und auch nie zum Ausdruck gebracht, das ich fehlerfrei bin. Wie jeder darf jedoch auch ich erwarten, das man sachlich antwortet, wenn man sachlich fragt.

Die Korrektur meiner bisherigen Formel richte ich hier in thread in einen weiteren Beitrag an Sonja direkt.

Gruß Werner
.. , - ...
Anzeige
AW: solches ist nicht mein Stil ...
19.07.2024 17:14:01
daniel
Alle meine Antworten waren sachlich begründet.
Auch in der ersten Antwort. Ich sehe es nicht als meine Aufgabe an,andere Antworten zu prüfen.
Ich kann deine Beschwerde nicht nachvollziehen.
AW: mit KALENDERWOCHE() ...
18.07.2024 11:28:31
Sonja24
Hallo Werner,

danke für Deine Antwort. Ich hatte die Formel kopiert, das Problem bleibt aber leider bestehen

Gruß
Sonja
Anzeige
AW: wie das? ...
18.07.2024 11:37:53
neopa C
Hallo Sonja,

... bei mir sieht es danach wie folgt aus:

Arbeitsblatt mit dem Namen 'BLOM2510D-A11 '
 AAABAC
323. Dez30. Dez06. Jan
452-20241-20252-2025

ZelleFormel
AA3=Z3+7
AB3=AA3+7
AC3=AB3+7
AA4=WENN(AA3="";"";KALENDERWOCHE(AA3;21)&"-"&JAHR(AA3+6))
AB4=WENN(AB3="";"";KALENDERWOCHE(AB3;21)&"-"&JAHR(AB3+6))
AC4=WENN(AC3="";"";KALENDERWOCHE(AC3;21)&"-"&JAHR(AC3+6))
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg


Bei Dir nicht? Wie soll es denn aussehen?

Gruß Werner
.. , - ...


Anzeige
AW: wie das? ...
18.07.2024 11:52:36
Sonja24
Hallo Werner,

konntest Du meine Beispieldatei öffnen? In Zelle AB4 habe ich die gleiche Formel (kopiert) bei Pull von D bis AH, es bleibt aber als Ergebnis 1-2024 anstand 1-2025, so wie von Dir gezeigt.

Ich sehe, das Du nur mir KALENDERWOCHE in Deiner Formel arbeitest, nicht mit ISOKALENDERWOCHE. Aber auch mit dieser Formel kommt bei mir das falsche Jahr raus :-(
=KALENDERWOCHE(AB3;21)&"-"&JAHR(AB3+1-KALENDERWOCHE(AB3;21))
Ergebnis 30 Dez. = 1-2024

Ich habe es auch so versucht E4: =D4 (Formel) +7, aber das funtioniert gar nicht. Da bekomme ich eine #Wert Fehler.

Kann es vielleicht damit zusammenhängen, dass ich in meiner Datum Zeile nur Tag und Monat, aber kein Jahr habe?

Gruß
Sonja
Anzeige
AW: wie das? ...
18.07.2024 11:56:01
BoskoBiati2
Hallo,

in der Datei, die Du eingestellt hast, ist das Datum in D3 mit Jahreszahl, somit haben aller folgenden Datumswerte auch eine Jahreszahl!

Gruß

Edgar
AW: ich hatte Dir aber eine andere Formel aufgezeigt ...
18.07.2024 12:23:26
neopa C
Hallo Sonja,

... und zwar in D4: =WENN(D3="";"";KALENDERWOCHE(D3;21)&"-"&JAHR(D3+6)) welche in AB4 =WENN(AB3="";"";KALENDERWOCHE(AB3;21)&"-"&JAHR(AB3+6)) lautet und ein korrektes Ergebnis ergibt, wie ich auch aufgezeigt hatte.

Gruß Werner
.. , - ...
Anzeige
AW: ich hatte Dir aber eine andere Formel aufgezeigt ...
18.07.2024 12:39:38
Sonja24
Hallo Werner,

ich habe es nochmal mit Deiner Formel versucht. Scheinbar hatte ich vorher ein Copy/Paste Problem

Aber jetzt klappt es. Vielen Dank für Deine Hilfe :-)
AW: bitteschön owT
18.07.2024 12:44:13
neopa C
Gruß Werner
.. , - ...
AW: Korrektur meines bisherigen Formelvorschlags ...
19.07.2024 16:33:50
neopa C
Hallo Sonja,

... durch Beiträge von Daniel (s.u. sowie meine Antworten an ihn) wurde mir inzwischen klar, daß meine bisher aufgezeigte Formel nur für den von Dir aufgezeigten Jahresübergang gelten kann.

Damit auch beliebige andere Jahresübergänge korrekt berücksichtigt werden, würde ich Dir nun deswegen folgende angepaßte Formel vorschlagen:
In D4: =WENN(D3="";"";KALENDERWOCHE(D3;21)&"-"&JAHR(D3+(KALENDERWOCHE(D3;21)=1)*(MONAT(D3)=12)*6))

Gruß Werner
.. , - ...
Anzeige
AW: Korrektur meines bisherigen Formelvorschlags ...
19.07.2024 17:24:35
daniel
Hast du das auch geprüft für den Fall, wenn Anfang Januar noch KW 52 oder 53 ist des Vorjahres ist?
Oder für andere Wochentage nicht nur Montag?
Gruß Daniel
AW: Korrektur meines bisherigen Formelvorschlags ...
19.07.2024 19:53:47
Sigi.21
Hallo alle zusammen,

jetzt muss ich doch noch meinen Beitrag dazu leisten. Das korrekte KW-Jahr zu jedem beliebigen Datum ermittelt ihr so:
in B3 steht ein belieb. Datum: =JAHR(B3+3-REST(B3-2;7)), weil =B3+3-REST(B3-2;7) immer den DO einer KW ergibt. Und DO ist genau die Mitte der KW und liefert somit immer(!) das korrekte Jahr der KW.
Die bisherigen Vorschläge haben beim Jahreswechsel meist Probleme.

(s. Mappe)

Gruß Sigi

https://www.herber.de/bbs/user/171130.xlsx
Anzeige
AW: wie das? ...
18.07.2024 12:00:03
Sonja24
Ah ja, richtig. Ich sehe das Jahr nur nicht wegen der Formatierung der Zelle. Aber dann verstehe ich es noch weniger, daß bei mir immer das falsche Jahr angezeigt wird in der KW
AW: mit KALENDERWOCHE() ...
18.07.2024 11:42:33
BoskoBiati2
Hi,

in D4: 
=ISOKALENDERWOCHE(D3)&"-"&JAHR(D3)+(C3>"")*(ISOKALENDERWOCHE(D3)



nach rechts ziehen.



Gruß



Edgar
Anzeige
AW: im Betreff steht: "mit KALENDERWOCHE()" ;-) ...
18.07.2024 11:48:21
neopa C
Hallo Edgar,

... in meiner älteren XL-Version gibt es ISOKALENDERWOCHE() noch nicht.
Ergibt sich mit Deiner Formel ein anderes Ergebnis als mit meiner Formel?

Gruß Werner
.. , - ...
AW: im Betreff steht: "mit KALENDERWOCHE()" ;-) ...
18.07.2024 11:49:52
BoskoBiati2
Hi Werner,

beide Formeln ergeben das gleiche, richtige Ergebnis.

Gruß

Edgar
Anzeige
AW: aber mE nicht ...
18.07.2024 12:28:58
neopa C
Hallo Edgar,

...denn hier hast Du ansonsten eine andere Formel eingestellt, als Du bei Dir hast. Denn Deine aufgezeigte Formel kann so wie ich die interpretiere nur in D4 ein korrektes Jahr aufzeigen. Denn schon ab E4 sollte ein unzutreffendes Jahr ermittelt werden.

Gruß Werner
.. , - ...
Anzeige
AW: aber mE nicht ...
18.07.2024 12:55:55
BoskoBiati2
Hallo Werner,

da kann ich Dir nicht folgen:

Userbild

Gruß

Edgar
AW: Deine nun aufgezeigte Formel ...
18.07.2024 14:53:47
neopa C
Hallo Edgar,

... unterscheidet sich ja auch von der, die um 11:42 eingestellt hattest, bzw. wie sie da dargestellt ist. Sieh es Dir noch mal an.

Gruß Werner
.. , - ...
Anzeige
AW: Deine nun aufgezeigte Formel ...
18.07.2024 16:43:23
BoskoBiati2
Hallo Werner,

da hat die Forensoftware zugeschlagen, ist mir gar nicht aufgefallen.

Gruß

Edgar
Anzeige

Infobox / Tutorial

Falsches Jahr in der ersten KW 2025 anzeigen

Schritt-für-Schritt-Anleitung

Um die korrekte Kalenderwoche und das Jahr für ein Datum im Excel zu berechnen, kannst Du die folgenden Schritte befolgen:

  1. Datum eingeben: Gib das gewünschte Datum in eine Zelle ein (z.B. in D3).

  2. Formel anwenden: Verwende eine der folgenden Formeln in der Zelle, in der die KW und das Jahr angezeigt werden sollen:

    • Für Excel-Versionen ohne ISOKALENDERWOCHE:

      =WENN(D3="";"";KALENDERWOCHE(D3;21)&"-"&JAHR(D3+6))

    • Für Excel-Versionen mit ISOKALENDERWOCHE:

      =ISOKALENDERWOCHE(D3)&"-"&JAHR(D3)-(UND(MONAT(D3)=1;ISOKALENDERWOCHE(D3)>50)+UND(MONAT(D3)=12;ISOKALENDERWOCHE(D3)=1))

  3. Formel nach rechts ziehen: Kopiere die Formel nach rechts, um die KW für die folgenden Daten zu berechnen.

  4. Formatierung überprüfen: Stelle sicher, dass die Zellen mit den Ergebnissen korrekt formatiert sind, um das Jahr anzuzeigen.

Häufige Fehler und Lösungen

  • Falsches Jahr angezeigt: Wenn in der ersten Kalenderwoche 2025 (KW 1 2025) das Jahr 2024 angezeigt wird, überprüfe, ob ISOKALENDERWOCHE korrekt verwendet wird.

    • Lösung: Stelle sicher, dass das Datum in der Zelle auch das Jahr enthält. Eine Formel wie =WENN(D3="";"";KALENDERWOCHE(D3;21)&"-"&JAHR(D3+6)) könnte helfen.

  • #WERT! Fehler: Wenn Du einen #WERT! Fehler erhältst, könnte das daran liegen, dass das Datum nicht korrekt eingegeben wurde.

    • Lösung: Überprüfe die Eingabedaten auf Richtigkeit und Format.

Alternative Methoden

Wenn Du alternative Formeln zur Berechnung der Kalenderwoche und des Jahres ausprobieren möchtest, kannst Du folgende Ansätze verwenden:

  • Mittelwert der KW:

    =JAHR(B3+3-REST(B3-2;7))

    Diese Formel nutzt den Donnerstag einer Woche, um das korrekte Jahr zu ermitteln.

  • Mit LET in Excel 365:

    =LET(k;ISOKALENDERWOCHE(D3);j;JAHR(D3);m;MONAT(D3);k&"-"&j+UND(m=12;k=1)-UND(m=1;k>50))

    Diese Formel vereinfacht die Berechnung und macht sie leserlicher.

Praktische Beispiele

Hier sind einige Beispiele, wie Du die Formeln in der Praxis anwenden kannst:

  • Beispiel 1: Datum in D3: 30.12.2024

    • Ergebnis: 52-2024

  • Beispiel 2: Datum in D3: 06.01.2025

    • Ergebnis: 1-2025

  • Beispiel 3: Datum in D3: 01.01.2025

    • Ergebnis: 1-2025, wenn die Formel korrekt angewendet wird.

Tipps für Profis

  • Verwende ISOKALENDERWOCHE für präzisere Berechnungen, insbesondere bei Jahresübergängen.
  • Achte auf die korrekte Formatierung der Datumszellen, um Fehler zu vermeiden.
  • Nutze die Möglichkeit von Excel, Formeln zu kombinieren, um komplexere Berechnungen durchzuführen.

FAQ: Häufige Fragen

1. Welche Kalenderwoche haben wir aktuell? Du kannst die Formel =ISOKALENDERWOCHE(HEUTE()) verwenden, um die aktuelle Kalenderwoche zu ermitteln.

2. Was ist der Unterschied zwischen KALENDERWOCHE und ISOKALENDERWOCHE? KALENDERWOCHE verwendet die Standardwoche, während ISOKALENDERWOCHE die ISO-Normen befolgt, was zu unterschiedlichen Ergebnissen bei Jahresübergängen führen kann.

3. Wie funktioniert die Berechnung der KW für das Jahr 2025? Für das Jahr 2025 musst Du sicherstellen, dass Du die richtigen Formeln verwendest, um die korrekten Werte zu erhalten, insbesondere für die KW 1 2025, die manchmal fälschlicherweise als KW 52 2024 angezeigt wird.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige