AW: Ein Wert aus 3 Werten von Zellen übernehmen
04.11.2024 12:25:12
Yal
Moin Sigfried,
mit einem Doppelklick anstatt einfachen.
klicke auf dem Reiter deines Arbeitsblatt und wähle "Code anzeigen". In der geöffneten Codepane, folgende Code kopieren:
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Static R As Range
If Not Intersect(Target, Range("A2:A8")) Is Nothing Then
Set R = Target.EntireRow
With Range("A2:B8,F2:F8,J2:J8").Font
.ColorIndex = 16 'Grau
.Bold = False 'nicht Fett
End With
With Intersect(R, Range("A2:B8,F2:F8,J2:J8")).Font
.ColorIndex = 56 'Schwarz
.Bold = True 'Fett
End With
ElseIf Not Intersect(Target, Range("C2:E8")) Is Nothing Then
R.Cells(1, "B").Value = Target.Value
ElseIf Not Intersect(Target, Range("G2:I8")) Is Nothing Then
R.Cells(1, "F").Value = Target.Value
ElseIf Not Intersect(Target, Range("K2:M8")) Is Nothing Then
R.Cells(1, "J").Value = Target.Value
ElseIf Not Intersect(Target, Range("A1")) Is Nothing Then
If MsgBox("Spielstand zurücksetzen?", vbYesNo) = vbYes Then
Range("B2:B8,F2:F8,J2:J8").ClearContents
End If
End If
Cancel = True 'der Doppelklick soll keine weitere Auswirkung haben
End Sub
Funktionsweise:
Klicke auf dem Spieler in Spalte A um ihn zu aktivieren,
klicke dann auf die jeweilige Felder, um die Punkte zu allokieren,
klicke auf A1, um nach der Bestätigung den Spiel zurüczusetzen.
Viel Spass
VG
Yal