Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
2004to2008
2004to2008
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Anzeige
Inhaltsverzeichnis

VBA - Seite nicht Drucken wenn bestimmte Zelle 0

Forumthread: VBA - Seite nicht Drucken wenn bestimmte Zelle 0

VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 14:17:42
Tobias1989
Hallo zusammen,

ich habe eine simple VBA Funktion und möchte diese erweitern... Beispiel: ich habe 3 Tabellen Seiten und die sollen per VBA gedruckt werden, wenn aber Tabelle 2 Zelle A1 den Wert 0 hat soll nur Tabelle 1 und 3 gedruckt werden, wenn Tabelle 2 Zelle A1 einen Wert drinnen hat der größer als 0 ist dann soll er Tabelle 1,2 und 3 drucken.

Kann mir jemand helfen ?

Das ist mein VBA

Sub TEST()
'
' TEST Makro
'

'
Sheets(Array("Tabelle1", _
"Tabelle2", _
"Tabelle3")).Select
Sheets("Tabelle1").Activate
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
IgnorePrintAreas:=False
End Sub


Danke im voraus

Anzeige

24
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 14:33:07
Raimund
Hi Tobias1989

Versuche es damit: 

Sub TEST()

    Dim printSheets As Variant

    

    ' Überprüfen des Werts in Zelle A1 von Tabelle2

    If Sheets("Tabelle2").Range("A1").Value > 0 Then

        ' Wenn der Wert größer als 0 ist, drucke alle 3 Tabellen

        printSheets = Array("Tabelle1", "Tabelle2", "Tabelle3")

    Else

        ' Wenn der Wert 0 ist, drucke nur Tabelle 1 und Tabelle 3

        printSheets = Array("Tabelle1", "Tabelle3")

    End If

    

    ' Drucke die ausgewählten Tabellen

    Sheets(printSheets).Select

    ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

End Sub


Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 15:00:39
Yal
Moin zusammen,

Gedankenspiel als Erweiterung von Raimunds Lösung: drucke jedes Blatt dessen Zelle A1 > 0 
Sub DruckeWennA1NichtNull()

Dim Bzd ' Blatt zu drucken

Dim W

    

    Bzd = Array()

' Überprüfen des Werts in Zelle A1 von Tabelle2

    For Each W In Array("Tabelle1", "Tabelle2", "Tabelle3")

        If Worksheets(W).Range("A1").Value > 0 Then

            ReDim Preserve Bzd(UBound(Bzd) + 1)

            Bzd(UBound(Bzd)) = W

        End If

    Next

' Drucke die ausgewählten Tabellen

    If UBound(Bzd) > -1 Then Worksheets(Bzd).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

End Sub


Bei einem Standarddruck wäre es egal: man kann jedes Blatt einzeln drucken. Bei einem Druck in PDF müssen die Blätter als ein Druckauftrag gedruckt werden, sodass alles in einer Datei rauskommt.

VG
Yal
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 15:24:58
Raimund
Hi Tobias1989

Versuche es damit: 

Sub TESTspeichern()

    Dim printSheets As Variant

    Dim pdfFilePath As String

    

    ' Überprüfen des Werts in Zelle A1 von Tabelle2

    If Sheets("Tabelle2").Range("A1").Value > 0 Then

        ' Wenn der Wert größer als 0 ist, wähle alle 3 Tabellen

        printSheets = Array("Tabelle1", "Tabelle2", "Tabelle3")

    Else

        ' Wenn der Wert 0 ist, wähle nur Tabelle 1 und Tabelle 3

        printSheets = Array("Tabelle1", "Tabelle3")

    End If

    

    ' Aktiviere die erste Tabelle in der Liste

    Sheets(printSheets(0)).Select

    

    ' Definiere den Pfad für die PDF-Datei

    pdfFilePath = "C:\Users\ogmes-ap10\Desktop\test.pdf"

    

    ' Exportiere die ausgewählten Tabellen als PDF

    Sheets(printSheets).Select

    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _

        pdfFilePath, Quality:=xlQualityStandard, _

        IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True

End Sub


Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 16:44:41
Raimund
Hi Tobias1989

In deinem VBA-Code fehlen einige wichtige Punkte

Array-Deklaration:
Du hast Dim Bzd ohne Typangabe deklariert. Es sollte als dynamisches Array deklariert werden: Dim Bzd() As String.

Du hast ReDim Preserve Bzd(UBound(Bzd) + 1) verwendet, ohne sicherzustellen, dass Bzd tatsächlich initialisiert war. Du hast ReDim Preserve Bzd(UBound(Bzd) + 1) verwendet, ohne sicherzustellen, dass Bzd tatsächlich initialisiert war.

Die Variable W sollte als Variant deklariert werden, um korrekt mit dem Inhalt des Arrays zu arbeiten.

Versuche es so: 

Sub DruckeWennA1NichtNull()

    Dim Bzd() As String ' Blatt zu drucken

    Dim W As Variant

    Dim BzdCount As Integer



    BzdCount = -1 ' Zähler für das Bzd-Array initialisieren

    ' Überprüfen des Werts in Zelle A1 der angegebenen Blätter

    For Each W In Array("Deckblatt", "Grundler VK-Auswertung", "GrAusfallermittlung vor Poolung")

        If Worksheets(W).Range("A1").Value > 0 Then

            BzdCount = BzdCount + 1

            ReDim Preserve Bzd(BzdCount) ' Array vergrößern

            Bzd(BzdCount) = W

        End If

    Next W

    

    ' Drucke die ausgewählten Tabellen

    If BzdCount > -1 Then

        Worksheets(Bzd).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

    End If

End Sub


Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 16:57:31
Yal
Hallo Raimund,

Du hast recht mit der Erklärung der Initialisierung. Initialisiert ist es mit = Array(). Teste: 

Sub test()

Dim Arr

    Arr = Array()

    MsgBox UBound(Arr)

    ReDim Preserve Arr(UBound(Arr)+1)

    MsgBox UBound(Arr)

End Sub


Typisierung ist auch richtig und zu bevorzugen, aber wir gehen nicht davon aus, dass es hier um ein hochrelevante Datensystem handelt. Ein paar Programmierungsschlampereien zum Gunsten eines kürzeren Code kann man sich gönnen ;-)

VG
Yal
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 17:14:27
Tobias1989
Erstmal wieder dickes Danke aber wäre es möglich (Ihr seht ja wie viele Tabellen bzw. Reiter es gibt) zu sagen

Druck alle die auf A1 größer als 0 sind?

Dann würde ich über all das oben so machen das praktisch alle Seiten die ich nicht brauche automatische eine 0 haben und die anderen einen Wert größer als 0

Danke
Anzeige
Druck alle die auf A1 größer als 0 sind
12.02.2025 17:28:18
RPP63
Moin!
Na, das ist doch ganz einfach: 
Dim ws As Worksheet

For Each ws In ThisWorkbook.Worksheets

   If ws.Range("A1") > 0 Then ws.PrintOut

End With


Gruß Ralf
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 17:32:56
Raimund
Hi Tobias1989

So? 

Sub DruckeWennA1NichtNull()

    Dim ws As Worksheet

    Dim Bzd() As String ' Array für die Blätter, die gedruckt werden sollen

    Dim BzdCount As Integer



    BzdCount = -1 ' Zähler für das Bzd-Array initialisieren



    ' Durchlaufe alle sichtbaren Blätter

    For Each ws In ThisWorkbook.Worksheets

        If ws.Visible = xlSheetVisible Then

            ' Überprüfen des Werts in Zelle A1 des aktuellen Blattes

            If ws.Range("A1").Value > 0 Then

                BzdCount = BzdCount + 1

                ReDim Preserve Bzd(BzdCount) ' Array vergrößern

                Bzd(BzdCount) = ws.Name ' Blattname speichern

            End If

        End If

    Next ws

    

    ' Drucke die ausgewählten Tabellen

    If BzdCount > -1 Then

        Worksheets(Bzd).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

    End If

End Sub


Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 18:45:00
Tobias1989
@Raimund du bist genial, ihr alle seit sehr gut Danke an alle... Könntet ihr mir das gleiche nur für speichern als pdf machen ? Sprich alle Seiten Speichern die A1 größer wie 0 sind ?

Danke
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 19:33:17
Yal
Hallo Tobias,

eigentlich brauchst Du nur die verschiedene Teilstücke miteinander zu kombinieren. Diese Auseinandersetzung ist auch notwendig, um deine Programmierfähigkeit zu stärken und deine Abhängigkeit zu reduzieren. Du willst ja nicht dein Leben lang "VBA nur mit Recorder" bleiben.

Aber falls Du nicht selber drauf kommst: 
Sub DruckeWennA1NichtNull()

    Dim ws As Worksheet

    Dim Bzd() As String ' Array für die Blätter, die gedruckt werden sollen

    Dim BzdCount As Integer



    BzdCount = -1 ' Zähler für das Bzd-Array initialisieren



' Durchlaufe alle sichtbaren Blätter

    For Each ws In ThisWorkbook.Worksheets

        If ws.Visible = xlSheetVisible Then

        ' Überprüfen des Werts in Zelle A1 des aktuellen Blattes

            If ws.Range("A1").Value > 0 Then

                BzdCount = BzdCount + 1

                ReDim Preserve Bzd(BzdCount) ' Array vergrößern

                Bzd(BzdCount) = ws.Name ' Blattname speichern

            End If

        End If

    Next ws

    

' Exportiere die ausgewählten Tabellen als PDF

    If BzdCount > -1 Then

    Worksheets(Bzd).ExportAsFixedFormat Type:=xlTypePDF, _

        Filename:="C:\Users\ogmes-ap10\Desktop\test.pdf", _

        Quality:=xlQualityStandard, IncludeDocProperties:=True, _

        IgnorePrintAreas:=False, OpenAfterPublish:=True

    End If

End Sub


VG
Yal
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 11:15:24
Tobias1989
@YAL Guten Morgen, sorry hatte gestern schon Feierabend, ja ich würde natürlich gerne dazu lernen statt den Recorder zu nutzen, Danke das ihr mir helft. Jetzt habe ich es probiert aber da bleibt er hier hängen:

Worksheets(Bzd).ExportAsFixedFormat Type:=xlTypePDF, _
Filename:="C:\Users\ogmes-ap10\Desktop\test.pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=True

Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 12:13:33
Raimund
Hi Tobias

so?
Alle Blätter mit Wert > 0 in Zelle A1 werden mit jeweiligen Blattnamen gespeichert und gedruckt.

Den Pfad musst Du ändern: pdfFilePath = "C:\Users\luxin\Downloads\" & Bzd(i) & ".pdf" ' Pfad mit Blattnamen 


Sub DruckeUndSpeichereWennA1NichtNull()

    Dim ws As Worksheet

    Dim Bzd() As String ' Array für die Blätter, die gedruckt und gespeichert werden sollen

    Dim BzdCount As Integer

    Dim pdfFilePath As String

    Dim i As Integer



    BzdCount = -1 ' Zähler für das Bzd-Array initialisieren



    ' Durchlaufe alle sichtbaren Blätter

    For Each ws In ThisWorkbook.Worksheets

        If ws.Visible = xlSheetVisible Then

            ' Überprüfen des Werts in Zelle A1 des aktuellen Blattes

            If IsNumeric(ws.Range("A1").Value) And ws.Range("A1").Value > 0 Then

                BzdCount = BzdCount + 1

                ReDim Preserve Bzd(BzdCount) ' Array vergrößern

                Bzd(BzdCount) = ws.Name ' Blattname speichern

            End If

        End If

    Next ws



    ' Verarbeite die ausgewählten Tabellen

    If BzdCount > -1 Then

        For i = 0 To BzdCount

            ' Drucke das aktuelle Blatt

            Worksheets(Bzd(i)).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

            

            ' Speichere das aktuelle Blatt als PDF

            pdfFilePath = "C:\Users\luxin\Downloads\" & Bzd(i) & ".pdf" ' Pfad mit Blattnamen

            ThisWorkbook.Worksheets(Bzd(i)).ExportAsFixedFormat Type:=xlTypePDF, Filename:= _

                pdfFilePath, Quality:=xlQualityStandard, _

                IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False

        Next i

    End If

End Sub


Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 12:41:21
Tobias1989
Funktioniert nicht ganz der speichert dann nur das letzte Blatt als PDF ab und nicht alle in einer PDF Datei
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 12:47:49
Raimund
Hi Tobias

Bei mir werden alle sichtbaren Blätter mit wert > 0 in Zelle A1 unter C:\Users\luxin\Downloads gespeichert

Userbild

Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 12:51:22
Raimund
Hi Tobias

Schwer zu sagen, wo der Fehler liegt, ohne deinen Script zu sehen

Gruss

Raimund
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 13:08:03
Raimund
Hi Tobias

Es is richtig. Es werden alle Blätter einzeln gespeichert und nicht in einer einzigen PDF Datei

Gruss

Raimund
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 18:38:51
Tobias1989
So jetzt konnte ich alles probieren und es klappt alles hervorragend, was für ein tolles Gefühl wenn das alles so reibungslos klappt, aber nur dank eurer Hilfe.

EIN RIESEN DANK AN EUCH BEIDEN @Raimund & @YAL macht weiter so, vielen Dank für eure Hilfe und eure Zeit.

Liebe Grüße
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 12:57:51
Tobias1989
Gestern hast du mir einen Code geschickt der zum Drucken super funktioniert:

Sub DruckeWennA1NichtNull()
Dim ws As Worksheet
Dim Bzd() As String ' Array für die Blätter, die gedruckt werden sollen
Dim BzdCount As Integer

BzdCount = -1 ' Zähler für das Bzd-Array initialisieren

' Durchlaufe alle sichtbaren Blätter
For Each ws In ThisWorkbook.Worksheets
If ws.Visible = xlSheetVisible Then
' Überprüfen des Werts in Zelle A1 des aktuellen Blattes
If ws.Range("A1").Value > 0 Then
BzdCount = BzdCount + 1
ReDim Preserve Bzd(BzdCount) ' Array vergrößern
Bzd(BzdCount) = ws.Name ' Blattname speichern
End If
End If
Next ws

' Drucke die ausgewählten Tabellen
If BzdCount > -1 Then
Worksheets(Bzd).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False
End If
End Sub

Da druckt er zum Beispiel Seite 1 bis 6 (also er zählt die richtig auf)

Bei dem Code jetzt von eben druckt er zwar auch die 6 Seiten aber wie soll ich sagen der steuert die einzeln an Seite 1 von 1, 1 von 1 usw. bis er 6 Seiten hat. Und da ist auch wie du eben geschickt hast bei der PDF das Problem er macht einzelne Datein es sollte aber 6 Seiten in einer PDF sein.

Vielen Dank für deine Mühen und Zeit. :)
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 13:35:42
Raimund
Hi Tobias

Teste das hier:

Pfad anpassen: pdfFilePath = "C:\Users\luxin\Downloads\Alle_Blaetter_Als_PDF.pdf 

Sub DruckeUndSpeichereWennA1NichtNull()

    Dim ws As Worksheet

    Dim Bzd As Collection

    Dim pdfFilePath As String

    Dim i As Integer



    Set Bzd = New Collection ' Collection für die Blätter



    ' Durchlaufe alle sichtbaren Blätter

    For Each ws In ThisWorkbook.Worksheets

        If ws.Visible = xlSheetVisible Then

            ' Überprüfen des Werts in Zelle A1 des aktuellen Blattes

            If IsNumeric(ws.Range("A1").Value) And ws.Range("A1").Value > 0 Then

                Bzd.Add ws.Name ' Blattname zur Collection hinzufügen

            End If

        End If

    Next ws



    ' Überprüfen, ob Blätter gefunden wurden

    If Bzd.Count > 0 Then

        ' Definiere den Pfad für die PDF-Datei

        pdfFilePath = "C:\Users\luxin\Downloads\Alle_Blaetter_Als_PDF.pdf"



        ' Drucke die ausgewählten Blätter

        For i = 1 To Bzd.Count

            ThisWorkbook.Sheets(Bzd(i)).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False

        Next i



        ' Exportiere die ausgewählten Blätter als PDF

        Dim SheetArray() As String

        ReDim SheetArray(1 To Bzd.Count)

        For i = 1 To Bzd.Count

            SheetArray(i) = Bzd(i) ' Fülle das Array mit den Blattnamen

        Next i



        ' Exportiere die Auswahl als PDF

        ThisWorkbook.Sheets(SheetArray).Select ' Wählen Sie alle passenden Blätter aus

        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _

            pdfFilePath, Quality:=xlQualityStandard, _

            IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False



        MsgBox "PDF wurde erfolgreich gespeichert.", vbInformation

    Else

        MsgBox "Keine Blätter zum Exportieren gefunden.", vbExclamation

    End If

End Sub


Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
13.02.2025 13:54:38
Raimund
Hi Tobias

Das Problem mit der steuert die einzeln an Seite 1 von 1, 1 von 1 usw habe ich hoffentlich hier verbessert 

Sub DruckeUndSpeichereWennA1NichtNull()

    Dim ws As Worksheet

    Dim Bzd As Collection

    Dim pdfFilePath As String

    Dim i As Integer



    Set Bzd = New Collection ' Collection für die Blätter



    ' Durchlaufe alle sichtbaren Blätter

    For Each ws In ThisWorkbook.Worksheets

        If ws.Visible = xlSheetVisible Then

            ' Überprüfen des Werts in Zelle A1 des aktuellen Blattes

            If IsNumeric(ws.Range("A1").Value) And ws.Range("A1").Value > 0 Then

                Bzd.Add ws.Name ' Blattname zur Collection hinzufügen

            End If

        End If

    Next ws



    ' Überprüfen, ob Blätter gefunden wurden

    If Bzd.Count > 0 Then

        ' Definiere den Pfad für die PDF-Datei

        pdfFilePath = "C:\Users\luxin\Downloads\Alle_BlaetterPDF.pdf"



        ' Exportiere die ausgewählten Blätter als PDF

        Dim SheetArray() As String

        ReDim SheetArray(1 To Bzd.Count)

        For i = 1 To Bzd.Count

            SheetArray(i) = Bzd(i) ' Fülle das Array mit den Blattnamen

        Next i



        ' Exportiere die Auswahl als PDF

        ThisWorkbook.Sheets(SheetArray).Select ' Wählen Sie alle passenden Blätter aus

        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _

            pdfFilePath, Quality:=xlQualityStandard, _

            IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False



        ' Drucke die ausgewählten Blätter

        ThisWorkbook.Sheets(SheetArray).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False



        MsgBox "PDF wurde erfolgreich gespeichert und Blätter wurden gedruckt.", vbInformation

    Else

        MsgBox "Keine Blätter zum Exportieren gefunden.", vbExclamation

    End If

End Sub


Gruss

Raimund
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 15:34:37
Yal
Achtung: die Unterschied zwischen "ActiveSheet" und "ActiveWindow.SelectedSheets" beachten

entweder: 
    ' Exportiere die ausgewählten Tabellen als PDF

    Worksheets(printSheets).Select

    ActiveWindow.SelectedSheets.ExportAsFixedFormat Type:=xlTypePDF, _

        Filename:=pdfFilePath, _

        Quality:=xlQualityStandard, IncludeDocProperties:=True, _

        IgnorePrintAreas:=False, OpenAfterPublish:=True
oder 
    ' Exportiere die ausgewählten Tabellen als PDF

    Worksheets(printSheets).ExportAsFixedFormat Type:=xlTypePDF, _

        Filename:=pdfFilePath, _

        Quality:=xlQualityStandard, IncludeDocProperties:=True, _

        IgnorePrintAreas:=False, OpenAfterPublish:=True


VG
Yal
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 15:14:32
Tobias1989
Danke ihr seit echt super :) das klappt mega... eine Frage wenn ich das ganze genauso als PDF abspeichern will also unter den gleichen Voraussetzungen (Tabelle 2 Zelle A1 0 = gleich nicht mit drucken bzw. abspeichern) wie lautet dann der Code ?

Hier wieder ein Beipspiel:

Sub TESTspeichern()
'
' TESTspeichern Makro
'

'
Sheets(Array("Tabelle1", "Tabelle2", "Tabelle3")).Select
Sheets("Tabelle1").Activate
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
"C:\Users\ogmes-ap10\Desktop\test.pdf", Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
True
End Sub

Danke
Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 16:30:04
Tobias1989
Also ich versteh nicht das es funktioniert bei einer Test Tabelle aber wenn ich es in meiner richtigen Tabelle anwenden möchte kommt ein fehler ?? Was mach ich falsch ?

Sub DruckeWennA1NichtNull()
Dim Bzd ' Blatt zu drucken
Dim W

Bzd = Array()
' Überprüfen des Werts in Zelle A1 von Grundler VK-Auswertung
For Each W In Array("Deckblatt", "Grundler VK-Auswertung", "GrAusfallermittlung vor Poolung")
If Worksheets(W).Range("A1").Value > 0 Then
ReDim Preserve Bzd(UBound(Bzd) + 1)
Bzd(UBound(Bzd)) = W
End If
Next
' Drucke die ausgewählten Tabellen
If UBound(Bzd) > -1 Then Worksheets(Bzd).PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False
End Sub


hier ein Bild:
Userbild

er hängt bei If Worksheets(W).Range("A1").Value > 0 Then

Anzeige
AW: VBA - Seite nicht Drucken wenn bestimmte Zelle 0
12.02.2025 16:49:09
Yal
Hallo Tobias,

wenn man ganz weit reinzoomt... und genau schaut... sieht man, ...
dass der Klammer am Ende von Tabelle2 (Grundler VK-Auswertung )
mehr Abstand vom letzten Buchstaben als die anderen Blätternamen.

d.h. am Ende von "Grundler VK-Auswertung" gibt ein Leerzeichen.
Entweder korrigierst Du den Blattname (besser) oder andere den VBA-Code in "Grundler VK-Auswertung " (mit Leerzeichen, weniger gut).

Die genaue Lauterung der Fehlermeldung wäre auch gut gewesen. Ein Blick auf deinem Bildschirm haben wir nicht.

VG
Yal
Anzeige

Forumthreads zu verwandten Themen

Dynamischen Hyperlink im Web aufrufen
Heidi
Hallo Forum,

habe lange selbst geknobelt, komme aber nicht mehr weiter.

Zum Hintergrund:
Ich surfe per VBA-Schleife verschiedene Webseiten an und kopiere Teile des Html-Quellcodes raus, um mit dessen Inhalt Auswertungen in Excel zu machen. Das funktioniert auch soweit alles,...
03.01.2004 20:09:56
Thread-ID: 358306
2 Beiträge
Variables Array in Select verwenden
Guido

Hallo VBA Experten,
ich möchte verschiedene Arbeitsblätter als PDF ausdrucken worfür ich auch eine Lösung habe jedoch möchte ich nun die Auswahl welche Arbeitsblätter ausgedruckt werden varaibel gestalten.
Über eine Combobox besteht die Möglichkeit eine vordefinierte Version auszuwählen...
02.01.2019 14:20:41
Thread-ID: 1665354
4 Beiträge
Array variabel befüllen für PDF-Erstellung
Heiko

Ich habe mal wieder eine VBA-Frage. Ich verwende folgende Code: Sub print_PDF() Dim FileName As Variant Dim DetailName As String Dim PDF_auswahl As Integer DetailName = Worksheets("PDF").Cells(2, 24).Value PDF_auswahl = Worksheets("PDF").Cells(1, 22).Value FileName = ThisWorkbook.Path & "\"...
20.05.2015 18:21:14
Thread-ID: 1426998
3 Beiträge
Anzeige
VBA Excel Sheets automatisch an DIN A4 Druckseite anpassen
Aurum
Hallo,
Auf der Arbeit haben wir sehr Datenlastige Excels die Gedruckt werden müssen. Eine Art des Druckens ist die Formelansicht. Hierbei besonders mühsam ist das Erstellen der Formelansicht bei jedem Sheet und dann das justieren der Zellbreite sowie die Skalierung mind 50% pro Seite. Hinzu komm...
26.07.2024 15:29:42
Thread-ID: 1986129
10 Beiträge
Beim Klicken nächstes Video abspielen
Christian
Hallo Excel VBA Experten,

ich habe eine funktionierende userForm, die Videos in einer Zufallsreihenfolge wiedergibt.

Mein noch nicht ungesetzter Wusch ist es, per CommandButton die Schleife zu beenden und das nächste Video wiederzugeben.
Ich habe mir vereinzelt von ChatGPT hel...
23.03.2023 16:03:05
Thread-ID: 1925330
1 Beitrag
VBA-Code erweitern (Schließen der UF)
André

Hi zusammen,
man ist ja nie ganz glücklich bzw. eine nie fertig mit einer richtig perfekten Excelmappe.
Habe nen Klasse VBA Code bereits von HeinzH erhalten. Vielen Dank an dieser Stelle.
Würde diesen Code gerne erweitern. Der Code sieht so aus:
Option Explicit
Private Sub...
17.02.2006 11:50:54
Thread-ID: 733951
1 Beitrag
Anzeige
Druckreihenfolge
Melanie

Hallo Excel-Profis,
folgende Frage beschäftigt mich. Ich möchte gerne per VBA bestimmte Seiten eines Berichtes ausdrucken. Momentan listet mein Code diese Seiten einfach nacheinander auf:
Sheets("Tabelle1").Select
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True
S...
27.11.2007 11:27:00
Thread-ID: 929999
6 Beiträge
Ausdruck nur bei Wert >0 (Null) ! Nur Wie?
Taurus666

Hallo, Ich habe bereits in anderen Foren die gleiche Frage gestellt,
aber leider keine Antwort erhalten.
Meine Excel-Tabelle besteht aus min. 20 Tabellenblättern und die
wurden "1" - "20" und "c" benannt.
In den Tabellenblätter 1-20 werden Menge und Preis eingegeben.
Jetzt w...
22.12.2004 10:21:35
Thread-ID: 536746
3 Beiträge
VBA-Problem nach Umstellung auf 2010
strodti

Hallo liebes Forum,
gleich vorab: ich habe als Excel-Version Office 2007 angegeben, da Office 2010 nicht in der Auswahlliste erscheint.
Folgendes: Mit Hilfe dieses Forums habe ich unter Excel 2003 den nachstehenden Code zusammengestellt, der auch funktionierte.
Sub drucken() If Shee...
21.12.2010 15:56:18
Thread-ID: 1192373
2 Beiträge
Fehler im VBA Code
Josef

Hallo!
Mit nachfolgendem Makro soll folgender Vorgang durchgeführt werden:
1.)Ist die TextBox2 befüllt und TB3,TB4,TB5 und TB6 leer, dann aktivere das Blatt "Form 909" und bilde eine Gruppe mit dem zweiten Blatt "Form 909a".
2.)Trage die Werte aus den TextBoxen 1, 2 und 3 in die Zel...
14.04.2006 08:54:20
Thread-ID: 755138
2 Beiträge
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Live-Forum - Die aktuellen Beiträge
Datum
Titel
14.05.2026 13:31:09
Zeichen ausblenden
14.05.2026 09:50:42
Makro für MacOs
13.05.2026 19:14:18
Gleichheitszeichen
13.05.2026 14:24:56
VBA Projekt Passwort automatisch eingeben
13.05.2026 08:49:41
Reale Berechnung ohne Nachkommawerte
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum