SUMMENPRODUKT funktioniert nicht

13.02.2025 11:56:13

Falko

Hallo zusammen,

in einer Tabelle bei uns werden Einrichtungen verwaltet, bei denen Mängel auftreten können. Diese möchte ich auszählen. Das Zählen der Mängel einzeln funktioniert super. Nun möchte ich aber die Mängel verschiedener Einrichtungstypen auswerten. Die Formel dazu wäre:

=SUMMENPRODUKT((('Einrichtungen + Prüfungen'!L6:L975="EH stW")+('Einrichtungen + Prüfungen'!L6:L975="EH WgB"))*(('Einrichtungen + Prüfungen'!S6:S975="*,1,*")+('Einrichtungen + Prüfungen'!S6:S975="*, 1,*")+('Einrichtungen + Prüfungen'!S6:S975="1")+('Einrichtungen + Prüfungen'!S6:S975="1,*")+('Einrichtungen + Prüfungen'!S6:S975="*, 1")+('Einrichtungen + Prüfungen'!S6:S975="*,1")))

Im vorderen Teil stehen die beiden Einrichtungstypen, im hinteren der Mangel 1 in seinen verschiedenen Schreibweisen, die die Mitarbeiter in die Liste eintragen könnten. Als Ergebnis erhalte ich aber immer 0. Vielleicht hat hier ja jemand eine Idee, wo der Fehler liegt. Vielen Dank schon mal.

AW: SUMMENPRODUKT funktioniert nicht

13.02.2025 12:01:31

BoskoBiati

Hi,

Wildcards funktionieren in SUMMENPRODUKT nicht. Ansonsten würde ich über Datengültigkeit die Eingabe für die Nutzer beschränken.
ISTZAHL(SUCHEN wäre hier der richtige Term.

Gruß

Edgar

AW: SUMMENPRODUKT funktioniert nicht

13.02.2025 13:07:42

Falko

Die Eingabemöglichkeiten der Nutzer zu beschränken würde hier in der Abteilung zu Problemen führen, das kann ich schon mal vergessen. Ich habe gut ein Jahr gekämpft um durchzusetzen, dass es in der Datenbank völlig egal ist, ob vor deren Name noch Herr, Frau, Hr. oder Fr. steht (ich musste die Aufträge nach Name auswerten). Mit ISTZAHL habe ich noch nie gearbeitet. Hast du eine Idee?

AW: SUMMENPRODUKT funktioniert nicht

13.02.2025 14:31:58

Uduuh

Hallo,
=SUMMENPRODUKT((('Einrichtungen + Prüfungen'!L6:L975={"EH stW"."EH WgB"}))*(ISTZAHL(SUCHEN("1";'Einrichtungen + Prüfungen'!S6:S975))))

Gruß aus'm Pott
Udo

AW: SUMMENPRODUKT funktioniert nicht

13.02.2025 14:59:13

BoskoBiati

Hi,

sowas macht man mit Gültigkeit, damit legt man zulässige Eingaben fest.

Gruß

Edgar

AW: SUMMENPRODUKT funktioniert nicht

13.02.2025 12:02:43

SF

Hola,
du fragst mit zB "1" einen TEXT ab. Liegen die Daten wirklich als Text vir?
Gruß,
steve1da

AW: SUMMENPRODUKT funktioniert nicht

13.02.2025 21:01:40

Daniel

HI

nutze doch ZählenWenns:
ausführlich:

=ZählenWenns('Einrichtungen + Prüfungen'!L6:L975;"EH stW";'Einrichtungen + Prüfungen'!S6:S975;"*1*")+ZählenWenns('Einrichtungen + Prüfungen'!L6:L975;"EH Wgb";'Einrichtungen + Prüfungen'!S6:S975;"*1*")

oder kompakter:

=Summe(ZählenWenns('Einrichtungen + Prüfungen'!L6:L975;{"EH stW";"EH Wgb"};;'Einrichtungen + Prüfungen'!S6:S975;"*1*"))

in älteren Excelversionen muss man die die Formel mit Summe mit STRG+SHIFT+ENTER abschließen, oder man verwendet SUMMENPRODUKT statt SUMME

oder was ganz anderes, diese Variante mit Summenprodukt:

=SummenProdukt(IstZahl(Finden('Einrichtungen + Prüfungen'!L6:L975;"|EH stW|EH Wgb|"))*IstZahl(Finden("1";'Einrichtungen + Prüfungen'!S6:S975)))

FINDEN oder SUCHEN ergeben die Position des gesuchten Textes (1. Parameter) innerhalb eines längeren Textes (2. Parameter) und erzeugen einen Fehler, wenn der kurze Text nicht gefunden werden kann.
das ISTZAHL prüft, ob ein Formelergebnis eine Zahl ist und gibt dann WAHR aus, sonst FALSCH
durch die Kombinantion von von IstZahl mit Suchen oder finden kann man also prüfen, ob ein Text in einem anderen Text vorhanden ist.
das WAHR wird in der Multiplikation zu eine 1 und das FALSCH zu einer 0, womit man das dann für solche Zählaufgaben verwenden kann.

Gruß Daniel

AW: SUMMENPRODUKT funktioniert nicht

14.02.2025 08:44:10

Falko

Vielen Dank für die vielen Vorschläge. Die funktionieren zwar alle im Prinzip, geben aber alle Ergebnisse aus, die nicht stimmen. Ich könnte mir vorstellen dass es daran liegt, dass dort nicht nur die 1 vorkommt, sondern die Mängel von 1 bis 29 durchnummeriert sind und in der Spalte in unterschiedlicher Anzahl vorkommen. Kann man das noch irgendwie lösen? Es soll die 1 erkannt werden, aber eben nicht alle anderen (zweistelligen) Zahlen, in denen eine 1 vorkommt. Ab der Nummer 10 funktionieren die Formeln übrigens fehlerfrei. Ich brauche jetzt nur noch eine Lösung für die einstelligen Zahlen.

Nicht weiter ohne Mappe! Owt

14.02.2025 20:05:41

Uduuh

AW: SUMMENPRODUKT funktioniert nicht

15.02.2025 22:12:55

Daniel

ja, da müsstest du mal zeigen, was so alles in den Zellen drin stehen kann, und was wie gezählt werden soll.

AW: SUMMENPRODUKT funktioniert nicht

18.02.2025 14:35:44

Falko

Da der Upload nicht funktioniert hier mal ein Beispiel:

In Spalte L steht die Art der Einrichtung. Diese kann ganz unterschiedlich sein:
Art der
Einrichtung
APH
Wohn-PH
APH
APH
APH
EH WgB
APH
APH
APH
APH
APH
APH
APH
APH
APH
EH stW
EH WgB

In Spalte S werden die Mängel eingetragen. Diese gehen von 1 bis 29. Eingetragen werden die von verschiedenen Personen, die alle ihre eigenen Schreibweisen haben, und bei denen es eher schwer wird, eine einheitliche Schreibweise einzuführen.

Art der Mängel
8, 18, 19
3,8,12
2,8,20
8
8, 20
3, 6, 8, 12, 14, 18, 20
2, 8, 12, 20
19
20, 12, 16, 14, 4, 21, 6, 9, 2,
2,3,4,5,8,12,14,18,20,17
2, 8, 15, 18, 20
8, 16, 20
4, 8, 15, 20
15, 4, 8, 2, 6, 5, 12, 20, 9
8, 20, 12, 18, 15, 2
14
14

Ich zähle diese Mängel auch schon, und das funktioniert super. Nur mit der Kombination aus Einrichtung und Mangel komme ich nicht weiter. Das Problem sind vor allem die einstelligen Zahlen, mit den zweistelligen funktionieren eure Formeln ohne Probleme.

AW: SUMMENPRODUKT funktioniert nicht

18.02.2025 17:18:08

daniel

Hi
Am sinnvollsten ist, erstmal die Schreibweise zu vereinheitlichen.

Dazu in einer Zusatzspalte (bspw Spalte T) diese Formel:

=" "&Glätten(Wechseln(S2;",";" "))&" "

Dann steht vor und nach jeder Zahl genau ein Leezeichen. Sollten die Kollegen auch mal andere Trennzeichen verwenden, dann füge weitere Wechseln-Funktionen hinzu.

Das Auswerten geht dann einfach mit ZählenWenns, hier zählst du an alle APH mit Mangel 2

=ZählenWenns(L:L;"APH";T:T;"* 2 *")

Wichtig sind die Leezeichen, denn die verhindern, dass 12 oder 20 mitgezählt werden.

Gruß Daniel

SUMMENPRODUKT funktioniert nicht

Forumthread: SUMMENPRODUKT funktioniert nicht

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

SUMMENPRODUKT funktioniert nicht

Forumthread: SUMMENPRODUKT funktioniert nicht

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread