schnellere Variante als Indirekt?

Forumthread: schnellere Variante als Indirekt?

17.02.2025 19:58:16

Christian

Hallo,

bitte helft mir

Ich versuche in der Formel

=WENN(ODER(A7282>A7283;B7282>B7283);"site:www.imdb.com/title "&A7283&" "&B7283;"")

die 7283 durch die aktuelle Zeile, 7282 durch die Zeile zuvor zu ersetzen, damit ich mir die Formel irgendwo abspeichern und beliebig einfügen kann, ohne die Zellbezüge anzupassen.

=WENN(ODER(INDIREKT("A"&ZEILE()-1)>INDIREKT("A"&ZEILE());INDIREKT("B"&ZEILE()-1)>INDIREKT("B"&ZEILE()));"site:www.imdb.com/title "&INDIREKT("A"&ZEILE())&" "&INDIREKT("B"&ZEILE());"")

funktioniert, dauert aber bei 300Tsd Zeilen auch recht lange zum Berechnen. Gibt es da auch eine schnellere Variante? Danke
Christian

PS: Ich würde gerne bei einer Formellösung bleiben. PQ nimmt mir m.E. die Flexibilität sie mal eben beliebig irgendwo einfügen zu können.

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: schnellere Variante als Indirekt?

17.02.2025 20:06:25

Daniel
AW: schnellere Variante als Indirekt?

17.02.2025 20:11:38

RPP63
AW: schnellere Variante als Indirekt?

17.02.2025 20:24:44

Christian
AW: schnellere Variante als Indirekt?

17.02.2025 21:12:43

Eifeljoi 5

AW: schnellere Variante als Indirekt?

17.02.2025 20:06:25

Daniel

Hi
INDIREKT ist nicht per se langsam, sondern hat den Effekt, dass Zellen mit Indirekt in der Formel bei jeder Änderung irgendeiner anderen Excelzelle in irgendeiner geöffneten Exceldatei neu berechnet werden, also sehr häufig.

INDIREKT braucht man aber nur, wenn man mit Namen arbeitet oder das Tabellenblatt selbst Teil der Berechnung ist.
Wenn man nur Zellebezüge innerhalb des gleichen Tabellenblatts berechnen will, ist INDEX die bessere Alternative, weil es den o.g. Effekt nicht hat.

Ersetze also:

INDIREKT("A"&ZEILE()-1)>INDIREKT("A"&ZEILE())
und vergleichbare ausdrücke durch
INDEX(A:A;ZEILE()-1)>INDEX(A:A;ZEILE())

Gruß Daniel

AW: schnellere Variante als Indirekt?

17.02.2025 20:11:38

RPP63

Moin!
Das Problem ist nicht die schiere Größe von 300tsd Zeilen, sondern die Tatsache, dass alle 300.000 Formeln bei jeder Änderung in der Tabelle neu berechnet werden müssen!
(Stichwort Volatilität)
INDEX(A:A;ZEILE()-1)
ist das gleiche (nur eben nicht volatil!) wie
INDIREKT("A"&ZEILE()-1)

Gruß Ralf

AW: schnellere Variante als Indirekt?

17.02.2025 20:24:44

Christian

Hallo ihr beiden,

WENN(ODER(INDEX(A:A;ZEILE()-1)>INDEX(A:A;ZEILE());INDEX(B:B;ZEILE()-1)>INDEX(B:B;ZEILE()));"site:www.imdb.com/title "&INDEX(A:A;ZEILE())&" "&INDEX(B:B;ZEILE());"")

funktioniert und ist auch schneller.
Danke für die Erklärung und die Unterstützung
Christian

PS: Schönen Abend noch

AW: schnellere Variante als Indirekt?

17.02.2025 21:12:43

Eifeljoi 5

Hallo
Mein Tipp zur Alternative:
Schmeiße alle Formeln raus und nutze Power Query.

schnellere Variante als Indirekt?

Forumthread: schnellere Variante als Indirekt?

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread