=RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:08:20

Ray

Moin und sorry, ich kriege das einfach nicht hin....

ich habe in einer Zelle:
Am alten Sportplatz 24

daraus soll in einer anderen Zeller werden:
Am alten Sportplatz

DAS funktioniert mit der f(x):
=LINKS(C178;LÄNGE(C178)-FINDEN(" ";C178)+1)

ABER:
ich habe in einer Zelle:
Schanzenstraße 18

daraus soll in einer anderen Zelle werden:
Schanzenstraße

Die f(x):
=LINKS(C178;LÄNGE(C178)-FINDEN(" ";C178)+1)

macht aber daraus:
Sch

Kann mit bitte jemand erklären warum?

VG aus HH bei, keine Ahnung kalt und verzweifelt....
Ray

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:17:26

SF

Hola,
du kannst am Besten mal die einzelnen Formelinhalte einzeln in Zellen schreiben und schauen welche Zahlen da rauskommen. Also:
=FINDEN(" ";C178)+1
=LÄNGE(C178)
Diese Zahlen setzt du dann in die Rechnung ein. Meiner Meinung nach ist die Formel aber der falsche Ansatz.
Wenn man nach
Excel letztes leerzeichen finden
googlet, landet man zB hier.
https://fasteasy.at/tippshop/index.php?mp=1&id=1&id2=14&id3=1194
Die Formel dort bei Punkt 3 ermittelt die Position des letzten Leerzeichens. Um die Formel einfach noch LINKS() bauen, dann hast du deine Wunschergebnisse.
Gruß,
steve1da

Hilft leider nicht, weil

20.02.2025 16:26:07

Ray

...die Formel aus dem Externen link macht aus
"Am Alten Sportplatz 22" nur "Sportplatz"

AW: Hilft leider nicht, weil

20.02.2025 16:30:41

SF

Bei mir nicht.
Leider zeigst du deine Formel nicht.

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:21:37

Sigi.21

Hallo,

du willst die Straße auslesen? Dann stelle mal einige Bsp. in einer Mappe zur Verfügung.
Gibt es auch Exoten? Wie ...

Straße des 17. Juni 117A
Kolpingstr. 4-6
Am Stein 27Va
... oder in Mannheim ....
N4, 3 c
S1, 1-1/1

Gruß Sigi

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:31:13

Ray

Danke schon mal für Deine Mühe:

Die Straßen sind so aufgebaut:

Am alten Sportplatz 21a
Paul-Mischke-Allee 3
Schanzenstraße 19
Jochen-Klepper-Straße 27

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:38:36

Sigi.21

Hallo Ray,

s. Mappe.
https://www.herber.de/bbs/user/175897.xlsx

Gruß Sigi

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:22:31

Yal

Hallo Ray,

der Elefant wird in Scheiben gegessen.

füge einfach die Formel-Teil einzeln in verschiedenen Zellen:
= FINDEN(" ";C178)
= LÄNGE(C178)
= LÄNGE(C178) - FINDEN(" ";C178)
= LINKS(C178; FINDEN(" ";C178) )
= LINKS(C178; LÄNGE(C178) )
= RECHTS(C178; FINDEN(" ";C178) )
= RECHTS(C178; LÄNGE(C178) )
usw.
Schaue dir die einzelne Ergebnis und analysiere.

Es nutzt nicht, wenn Du alles auf einmal haben willst, und gar nicht verstehst, was dabei passiert.
Wichtig ist nicht, dass du einen "funktionierende" Ergebnis hast, sondern dass Du verstehst und den Weg zum Ergebnis beherrschst.

Viel Erfolg beim gut werden.

VG
Yal

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 21:39:20

Uduuh

Hallo,
siehe https://www.herber.de/excelformeln/pages/Straenname_und_HausNr_trennen.html

Gruß aus'm Pott
Udo

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:33:24

Yal

Hallo zusammen,

die grösste Schwierigkeit ist, dass manche sehr hilfreiche Formeln aus xl365 in xl2016 nicht vorhanden sind.

Weder SUCHEN noch FINDEN ist in der Lage "n-tes Auftreten" als Parameter anzunehmen.
WECHSELN kann das. Daher:

=TEIL(K5;FINDEN(";";WECHSELN(K5;" ";";";LÄNGE(K5)-LÄNGE(WECHSELN(K5;" ";""))))+1;99)

@Ray: hier auch, nehme die Einzelteil des gesamtes und schau dir, was gemacht wird. Die Formel so anzunehmen und gut ist, ist der schnellste Weg, bei kleinsten Änderungen auf dem Forum angewiesen zu sein.

VG
Yal

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 16:39:56

emkaes

Hallo,

oder so

=LINKS(A1;LÄNGE(A1)-VERGLEICH(" *";RECHTS(A1;SPALTE(1:1));0))

die Formel mit Shift+Strg+Enter abschließen, da Matrixformel

AW: =RECHTS/link und finden: Versteh ich einfach nicht

20.02.2025 20:27:50

Michael

Hallo Ray,

es ist nicht das letzte Leerzeichen, nach dem beim Zerlegen von Straßennamen gesucht wird, mitunter fehlt das, bei "42 b" ist das auch wenig hilfreich. Die erste Zahl zu finden, ist viel praktischer:

=WENNFEHLER(RECHTS($A2;LÄNGE($A2)-(AGGREGAT(15;6;FINDEN(ZEILE($1:$9);$A2);1)-1));"")

Dabei ist (von innen nach außen) ZEILE($1:$9) nichts weiter als eine Liste von Zahlen: {1;2;3;4;5;6;7;8;9}
Werden FINDEN neun Suchwerte übergeben, die in A2 gesucht werden sollen, liefert die Funktion neun Ergebnisse: {13;#WERT!;#WERT!;#WERT!;15;#WERT!;#WERT!;#WERT!;#WERT!}
An Position 13 im durchsuchten Text wurde also die 1 gefunden, an Position 15 die 5, in A2 steht "Hauptstraße 105a".
AGGREGAT(15;...;...;1) ist KKLeinste, die 6 entfernt die Fehlerwerte (#WERT!), übrig bleibt also die 11. Davon wird eine 1 abgezogen, die Position ist dann das Zeichen vor der Zahl. Die resultierende 10 wird anschließend von der Länge des durchsuchten Textes subtrahiert. Das ist die Anzahl der Zeichen von RECHTS, die vom durchsuchten String zugeliefert wird.
Drumrum noch ein WENNFEHLER, denn ohne jede Nummer im Straßennamen wirft die Formel einen #ZAHL!-Fehler.

Offensichtlich funktioniert das nicht mit Straßennamen, in denen auch ohne Hausnummer Zahlen vorkommen. Zum Glück sind die selten und mit Berlin oder Mannheim hatte ich noch wenig zu tun.

Doch wenn es darauf ankommen sollte, findest Du die dafür passende Formel hier, ganz unten:
https://www.herber.de/excelformeln/pages/Straenname_und_HausNr_trennen.html
Erklären muss Dir die jemand anders.
Komplizierte Formeln wie von Yal beschrieben in diversen Hilfsspalten oder -zeilen in ihre Einzelteile zu zerlegen ist sehr, sehr hilfreich! Nur mit der eben empfohlenen half das leider auch nicht :·(

Viele Grüße
Michael

=RECHTS/link und finden: Versteh ich einfach nicht

Forumthread: =RECHTS/link und finden: Versteh ich einfach nicht

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

=RECHTS/link und finden: Versteh ich einfach nicht

Forumthread: =RECHTS/link und finden: Versteh ich einfach nicht

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread