FILTER-Formel

FILTER-Formel

07.03.2025 18:29:04

Herbert Grom

Hi,

aus einer Datumsliste möchte ich nur die Donnerstage und Freitage filtern. ich habe es u. a. mit der nachfolgenden Formel erfolglos probiert. Auch mit UND oder & hat es nicht funktioniert, es wird immer auch ein Samstag mit aufgelistet. Könnt ihr mir bitte sagen, wo da mein Denkfehler liegt? Vielen Dank im Voraus.

=FILTER(E3:$E$18;ODER(WOCHENTAG(E3:$E$18;2)=4;WOCHENTAG(E3:$E$18;2)=5))

Servus

AW: FILTER-Formel

07.03.2025 18:44:15

daniel

Hi
ODER ist in solchen Matrixformeln nicht verwendbar, weil es dir nicht für jeden einzelnen Wert der Matrix das ODER durchführt, sondern einfach alle Werte nimmt und diese dann gesamtheitlich verodert, so dass du nur einen einzigen Ergebniswert bekommst und keine Ergebnismatrix ,die du eigentlich haben möchtest.

ODER ist in Excel keine Einzelwertoperation (vergleichbar +), sondern eine Massendatenauswertefunktion, die viele Werte zu einem zusammenfasst (vergleichbar SUMME())

in solchen Matrixberechnungen muss man ODER und auch UND durch + und * ersetzen (welche wie zuvor gesagt Einzelwertoperatoren sind, die für jeden Matrixwert ein eigenes Ergebnis liefern.
Hierbei hilft, dass in Excelformeln die Zahl 0 wie ein FALSCH und jede andere Zahl wie ein WAHR gewertet wird, wenn sie dort stehen, wo eigentlich boolsche Ausdrücke stehen sollten.

hier kann man einfach rechnen:

=FILTER(E3:$E$18;(WOCHENTAG(E3:$E$18;2)=4)+(WOCHENTAG(E3:$E$18;2)=5))

oder ein anderer Weg:

=FILTER(E3:$E$18;ISTZAHL(FINDEN((WOCHENTAG(E3:$E$18;2);"45")))

dieser bietet sich dann an, wenn die Anzahl der Wochentage, die gefiltert werden sollen, sich auch mal ändern können, das geht hier nämlich flexibel über den einen Text, ohne das die Formel geändert werden muss.

Gruß Daniel

AW: FILTER-Formel

07.03.2025 20:07:29

Onur

Wenn du schon mit ODER oder UND arbeiten willst, gibt es auch diese (UND-) Möglichkeit:

=FILTER(E3:$E$18;(WOCHENTAG(E3:$E$18;2)>=4)*(WOCHENTAG(E3:$E$18;2)=5))

AW: FILTER-Formel

08.03.2025 11:16:22

Herbert Grom

Hi Onur,

so hatte ich es auch schon probiert, allerdings mit dem klitzekleinen Unterschied, dass ich, anstatt des Sternchens, das & genommen hatte. Und jetzt weiß ich, dank dir, was ein einziges falsches Zeichen doch bewirken kann. Mercie vielmals.

Servus

UND ODER watt?

07.03.2025 20:41:03

RPP63

Moin!
Anders gefragt:
Für Dein Beispiel (Filtern nach Wochentag DO oder FR) gibt es ja außer 2 noch ein paar andere Argumente in WOCHENTAG()
Die 16 liefert Wochentage von 1 (SA) bis 7 (FR)
Folglich nix ODER, sondern
=FILTER(A2:A36;WOCHENTAG(A2:A36;16)>5)

	A	B	C
1	Datum		DO \| FR
2	Mo\|07.04.		Do\|02.01.
3	Mi\|28.05.		Do\|22.05.
4	Mo\|10.02.		Fr\|21.03.
5	Do\|02.01.		Fr\|24.01.
6	Do\|22.05.		Fr\|10.01.
7	Sa\|08.03.		Fr\|16.05.
8	Mo\|26.05.		Fr\|14.03.
9	Fr\|21.03.		Fr\|07.02.
10	Fr\|24.01.		Do\|22.05.
11	Sa\|12.04.		Do\|24.04.
12	Fr\|10.01.		Fr\|17.01.
13	Fr\|16.05.		Fr\|31.01.
14	Mo\|24.02.		Fr\|04.04.
15	So\|09.02.		Do\|20.03.
16	Mo\|13.01.
17	Sa\|15.03.
18	Mi\|28.05.
19	Di\|08.04.
20	Fr\|14.03.
21	Di\|28.01.
22	So\|23.03.
23	Fr\|07.02.
24	Sa\|18.01.
25	Sa\|15.02.
26	Di\|11.02.
27	Mi\|19.03.
28	Do\|22.05.
29	So\|13.04.
30	Do\|24.04.
31	Fr\|17.01.
32	Mi\|28.05.
33	Fr\|31.01.
34	Fr\|04.04.
35	Do\|20.03.
36	Di\|04.03.

Zelle	Formel
C2	=FILTER(A2:A36;WOCHENTAG(A2:A36;16)>5)

Gruß Ralf

AW: UND ODER watt?

07.03.2025 21:17:05

Daniel

Montag und Donnerstag?
wie geht das ohne ODER?

AW: UND ODER watt?

08.03.2025 08:22:26

BoskoBiati

Hi,

statt WOCHENTAG wäre ja auch REST eine Möglichkeit:

=FILTER(A2:A36;REST(A2:A36;7>5)

Gruß

Edgar

AW: UND ODER watt?

08.03.2025 11:18:14

Herbert Grom

Hi Ralf,

vielen Dank, das ist auch eine geile Formel und so knackig.

Servus

AW: UND ODER watt?

08.03.2025 09:03:56

RPP63

Moin Edgar!
Ich erlaube mir, Deine Formel um 2 Zeichen [) und =] zu ergänzen:

=FILTER(A2:A36;REST(A2:A36;7)>=5)

AW: UND ODER watt?

08.03.2025 11:25:41

Herbert Grom

Hi Edgar,

auch dir (und Ralf) vielen Dank für deine Formel, die ist ja noch knackiger! Früher war das mal im Spotlight-Forum ein regelrechter Wettbewerb, wer hat die kürzeste Formel. Da gab es die irrsten Dinger, aber am Ende nur noch von Mathematikern zu verstehen. Aber funktioniert haben sie alle.

Servus

AW: UND ODER watt?

08.03.2025 19:42:08

Daniel

Kann man machen.
Ist aber meiner Ansicht nach mehr Selbstbefriedigung für Nerds als praktikable Lösung.

Danke, owT

08.03.2025 10:22:22

BoskoBiati

Gruß

Edgar

AW: UND ODER watt?

07.03.2025 21:25:38

RPP63

Ich habe mich auf diesen Thread bezogen, Daniel!
Hier war von Anfang an von DO und FR die Rede.
Dies habe ich mit meiner einfachen Formel gelöst.
Das widerspricht ja auch nicht den bisherigen Anmerkungen, wie man UND oder ODER in Filter-Formeln einbaut.

Gruß Ralf

AW: interessiert mich; deshalb nachgefragt ...

08.03.2025 11:07:04

neopa C

Hallo Ralf,

... habe in meiner alten XL-Version keine FILTER()-Funktion und kann selbst nachfolgendes nicht testen.

Für eine notwendige Überprüfung einer einzigen Datenzeile ohne ODER(), reicht in alten XL-Versionen als Teilformel =MAX(--(REST(A2;7)={2;5})). Allerdings würde bei der notwendigen Bereichsauswertung MAX() ja auch den Bereich auswerten und demzufolge immer eine 1 ermitteln. Deshalb könnte man in alten XL z.B. die Teilformel
=ISTZAHL(VERGLEICH(--(REST(A$2:A$36;7));{2.5};0)) einsetzen. Aber das sollte doch in XL365 ohne ODER() doch sicherlich auch einfacher möglich sein, oder?

Gruß Werner
.. , - ...
aus C the unseen

AW: interessiert mich; deshalb nachgefragt ...

08.03.2025 15:56:38

Daniel

Ja, sowas ist auch möglich.
Das entspricht in etwa meinem zweiten Lösungsvorschlag, nur das ich die Positiv-Datenmenge als Text angebe.

Kleiner Tipp: die Online-Version von Excel ist kostenlos verwendbar. Damit kann man sich schon mal mit den neuen Funktionen vertraut machen.

AW: interessiert mich; deshalb nachgefragt ...

08.03.2025 17:59:33

Daniel

Statt ODER() könnte man auch verwenden:
ZÄHLENWENNS(X;WOCHENTAG(Y;2))

Wobei Y das Datum ist und X der Zellbereiche, in dem die Positiv-Wochentage gelistet sind.

Gruß Daniel

AW: FILTER-Formel

07.03.2025 19:23:26

Herbert Grom

Hi Daniel,

vielen Dank für deine Vorschläge. Beide funktionieren prima. Bei der 2. hast du nur eine Klammer zu viel gesetzt. Aber das war sicher der eingebaute Fehler, den ich finden sollte! ;o)=)

So funzt auch die:

=FILTER(E3:$E$18;ISTZAHL(FINDEN(WOCHENTAG(E3:$E$18;2);"45")))

=FILTER(E3:$E$18;ISTZAHL(FINDEN((WOCHENTAG(E3:$E$18;2);"45")))

Servus

AW: FILTER-Formel

07.03.2025 19:30:09

daniel

Fehler passieren.
zum Testen braucht man eine Beispieldatei
diese zu erstellen ist Aufgabe des Fragestellenden.
Wer keine Beispieldatei mitliefert, muss damit rechnen, dass er selber die Tippfehler, die so passieren können korrigieren muss

AW: FILTER-Formel

07.03.2025 19:31:35

daniel

letzten Endes will ich dir auch keine fertige Lösung liefern, sondern ich will, dass du verstehst worum es geht und dann in der Lage bist, dir deine Formel selber zu schreiben.

AW: FILTER-Formel

07.03.2025 19:35:18

Herbert Grom

Aber Daniel, dass war doch keine Kritik, ich bin doch froh, dass du mein Problem so schnell gelöst hast! Vielen Dank noch mal!

Servus

AW: FILTER-Formel

07.03.2025 19:40:24

daniel

ich habs auch nicht als Kritik empfunden
ich hab dir nur erklärt, was ich warum mache (oder auch nicht mache)

	A	B	C
1	Datum		DO \| FR
2	Mo\|07.04.		Do\|02.01.
3	Mi\|28.05.		Do\|22.05.
4	Mo\|10.02.		Fr\|21.03.
5	Do\|02.01.		Fr\|24.01.
6	Do\|22.05.		Fr\|10.01.
7	Sa\|08.03.		Fr\|16.05.
8	Mo\|26.05.		Fr\|14.03.
9	Fr\|21.03.		Fr\|07.02.
10	Fr\|24.01.		Do\|22.05.
11	Sa\|12.04.		Do\|24.04.
12	Fr\|10.01.		Fr\|17.01.
13	Fr\|16.05.		Fr\|31.01.
14	Mo\|24.02.		Fr\|04.04.
15	So\|09.02.		Do\|20.03.
16	Mo\|13.01.
17	Sa\|15.03.
18	Mi\|28.05.
19	Di\|08.04.
20	Fr\|14.03.
21	Di\|28.01.
22	So\|23.03.
23	Fr\|07.02.
24	Sa\|18.01.
25	Sa\|15.02.
26	Di\|11.02.
27	Mi\|19.03.
28	Do\|22.05.
29	So\|13.04.
30	Do\|24.04.
31	Fr\|17.01.
32	Mi\|28.05.
33	Fr\|31.01.
34	Fr\|04.04.
35	Do\|20.03.
36	Di\|04.03.

Forumthread: FILTER-Formel

20
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

FILTER-Formel

Forumthread: FILTER-Formel

20 Beiträge zum Forumthread Beiträge zu diesem Forumthread

20
Beiträge zum Forumthread

Beiträge zu diesem Forumthread