Arbeitsmappe

Arbeitsmappe

11.03.2025 17:53:29

Peter

Hallo

ich möchte gern in Excel eine Übersichttabellenblatt erstellen.

Mit 2 Buton "2025" "2024"

Drücke ich auf 2024 so sollen sich die Tabs Jan2024, Feb2024 usw öffnen.
Sind die Eingaben erledigt, möchte ich zur Übersichttabelle zurück, um in Jan2025 reinzu gehen, oder ich schliesse die Datei.
Beim Aurufen der Datei soll immer die Übersichttabelle angezeigt werden.

Habe schon Versuche gestartet, aber es klappt nicht.

Danke
Gruß Pitt

AW: Arbeitsmappe

11.03.2025 17:57:23

Peter

Hatte die Mappe nicht richtig hochgeladen.
Entschuldigung

https://www.herber.de/bbs/user/176213.xlsm

AW: Arbeitsmappe

11.03.2025 18:10:42

Alwin Weisangler

Hallo Pitt,
du musst das Blatt erst sichtbar machen also so:



    With Sheets("Auto")

        .Visible = -1

        .Activate

    End With

Gruß Uwe

AW: Arbeitsmappe

11.03.2025 18:14:50

Peter

Danke Uwe,

wie mache ich das? bin etwas überfordert.
Danke

AW: Arbeitsmappe

12.03.2025 10:03:15

Alwin Weisangler

Hallo Pitt,

mal ein ganz ander Weg ohne den vielen Buttons auf den Blättern mit einer kleinen Userform.

https://www.herber.de/bbs/user/176216.xlsm

Diese passt sich den Kalenderjahren (letzte 4 Zeichen der Blattregister) an und es ist egal wie viele Kalenderjahre es sind.

Gruß Uwe

AW: Arbeitsmappe

12.03.2025 10:12:23

Alwin Weisangler

Sorry, da hatte ich beim Zurücksetzen das Neueinlesen der Listbox (Kalenderjahre) übersehen.
https://www.herber.de/bbs/user/176217.xlsm

Gruß Uwe

AW: Arbeitsmappe

11.03.2025 18:14:19

daniel

Hi
wenn du Tabellenblätter ein- und ausblendest, musst du sicherstellen, dass mindestes ein Tabellenblatt sichtbar ist,
Das Steuerblatt (Auto) beispielsweise sollte immer sichtbar sein.

dann würde der Code so aussehen:;

dim ws as Worksheet

Sheets("Auto").visible =  xlsheetvisible 'nur zur Sicherheit

for each ws in thisworkbook.Worksheets

    if ws.Name = "Auto" then

        ws.visible = xlsheetvisible

    elseif ws.Name like "2024*" then

        ws.visible = xlsheetvisible

    else

        ws.visible = xlsheethidden

    end if

next

der vergleich mit LIKE und Jokerzeichen erlaubt es dir, alle Blätter, die mit "2024" beginnen in der Schleife anzusprechen, ohne das du da jeden Namen einzeln und vollständig angeben musst.

Gruß Daniel

AW: Arbeitsmappe

11.03.2025 18:36:33

Peter

Hallo daniel,

danke nochmal für Deine Antwort.

Das ist natürlich toll das man nur "2024" eingeben braucht.
Nun ist es so, das wenn ich fertig mit den Eingaben bin, nach 2025 möchte.
Ich müsste dann zurück auf Auto, die 2024 tabellenblätter müßten geschlossen werden.
Gruß Pitt

AW: Arbeitsmappe

11.03.2025 19:27:02

Daniel

Naja, zurück nach "Auto" wirst du ja hoffentlich noch selber hinbekommen (weshalb Auto ja offen bleiben sollte)
Dort richtest du dir einen Button für "2025" ein

AW: Arbeitsmappe

11.03.2025 18:00:50

daniel

Hi
wenn du schon was versuchst hast, dann zeig doch mal deine Versuche.
dann können wir vielleicht darauf aufbauen und müssen nicht bei null starten.
und beschreibe vielleicht genauer, was du haben willst.
was genau meinst du mit Tabs?
sollen sich diese bei klick auf den Button alle gleichzeitig "öffen" (meint vermutlich "eingeblendet werden") oder nach einander, so dass du nach der Eingabe in einen Tab zum nächsten Tab geführt wirst?
Gruß Daniel

AW: Arbeitsmappe

11.03.2025 18:17:05

UweD

Hallo

ohne Buttons ; per Doppelclick

Arbeitsblatt mit dem Namen 'Übersicht'
	A
1	2024
2	2025

- Rechtsclick auf den Tabellenblattreiter Übersicht
- Code anzeigen
- Code rechts reinkopieren

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

    Dim TB As Worksheet

    With ActiveSheet

        If Not Intersect(Target, .Range("A1:A2")) Is Nothing Then

            Cancel = True

            For Each TB In ThisWorkbook.Sheets

                Select Case TB.Name

                    Case "Übersicht"

                        'NIx

                    Case Else

                        TB.Visible = InStr(TB.Name, Target) > 0

                    

                End Select

            Next

        End If

        .Activate

    End With

End Sub

Bei Doppelclick auf A1 wird alles, was nicht 2024 im Blattnamen hat AUSGEBLENDET
A2 analog

LG UweD

AW: Arbeitsmappe

11.03.2025 21:09:16

Yal

Hallo Peter,

deine Schaltfläche sollten keine "Formularsteuerelement" sondern ActiveX-Steuerelement sein.

Wenn diese beiden auf das Blatt "Auto" sich befinden und (z.B.) "cmd2024" und "cmd2025" heissen, so gilt folgenden Code (im Codepane vom Blatt "Auto" abzulegen, spricht auf dem Register des Blattes "Auto" rechtsklicken und "Code anzeigen" wählen):

Private Sub cmd2024_Click()

    Blätter_einblenden "Auto", "2024"

End Sub



Private Sub cmd2025_Click()

    Blätter_einblenden "Auto", "2025"

End Sub



Private Sub Blätter_einblenden(ParamArray Namenteil())

Dim ws As Worksheet

Dim NTeil

Dim Einblenden As Boolean

    

    Application.ScreenUpdating = False

    For Each ws In ThisWorkbook.Worksheets

        Einblenden = False

        For Each NTeil In Namenteil

            If InStr(1, ws.Name, NTeil, vbTextCompare) Then Einblenden = True

        Next

        ws.Visible = Einblenden

    Next

    ThisWorkbook.Worksheets(Namenteil(0)).Activate 'springt auf erstes Blatt der Auflistung

    Application.ScreenUpdating = True

End Sub

Der Code würde auf mit folgendem Aufruf funktionieren
Blätter_einblenden "Auto", "Jan", "Feb", "Mrz"

Wichtig ist, dass "Auto" an erste Stelle ist und den vollständigen Namen des Blattes darstellt, weil darauf wird zurückgesprungen. Was in dem Fall absurd ist, weil wir nicht "wegspringen". Aber
Blätter_einblenden "Jan2024", "2024"
wäre auf möglich. Oder
Blätter_einblenden Format(Date, "MMMYYYY"), Format(Date, "YYYY")

VG
Yal

Verkürzt

11.03.2025 18:26:02

UweD

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

    Dim TB As Worksheet

    If Not Intersect(Target, Range("A1:A2")) Is Nothing Then

        Cancel = True

        For Each TB In ThisWorkbook.Sheets

            If TB.Name > Me.Name Then

                TB.Visible = InStr(TB.Name, Target) > 0

            End If

        Next

    End If

    Me.Activate

End Sub

AW: Verkürzt

11.03.2025 18:40:18

Peter

Danke UweD,

werde es Heute Abend ausprobieren.

Vielen Dank.

Gruß Pitt

AW: Arbeitsmappe

11.03.2025 18:11:06

Peter

Hallo daniel,

Danke für die schnelle Antwort
Tabs sind Tabellenblätter.
Wenn auf dem Buton 2024 gedrückt wird, sollen alle Tabellenblätter von Jan2024-Dez2024 aufgehen.
Wenn auf dem Buton 2025 sollen die Tabellenblätter von Jan2025-Dez2025 angezeigt werden.

Forumthread: Arbeitsmappe

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Arbeitsmappe

Forumthread: Arbeitsmappe

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread