Formel mit mehreren Variablen gesucht anstatt wenn-Formel

26.03.2025 17:39:37

Mike

Hallo zusammen,

gibt es eine Formel anstatt mit einer sehr langen und aufwendingen WENN DANN SONST Schleife zum Ergebnis zu kommen?
In Spalte A sind Jahre abgetragen, in Spalte B das Produkt, in Spalte C ob groß/klein und in Spalte D sollte die Zuordnung der jeweiligen Ergebnisse aus Spalten A-C stehen. Die Auswahl für den jeweiligen Wert steht im Bereich F2 bis N4.
Die Beispieldatei habe ich beigefügt
https://www.herber.de/bbs/user/176442.xlsx

Beispiel:
Spalte A Spalte B Spalte C Spalte D
3,2 Produkt A groß 15
19,5 Produkt B groß 6,5
5,9 Produkt A klein 12

klein groß groß groß groß groß groß groß
1 >=1 >=3 >=5 >=10 >=20 >=30
12 12,0 12,0 14,0 15,0 17,0 19,0 22,0 24,0 Produkt A
0,5 0,5 0,5 2 2,5 3,5 6,5 8,5 10 Produkt B

Vielen herzlichen Dank vorab für eure Hilfe & Unterstützung.
Beste Grüße,
Mike

AW: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

26.03.2025 18:16:06

BoskoBiati

Hi,

z.B. so:

https://www.herber.de/bbs/user/176443.xlsx

Gruß

Edgar

AW: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

26.03.2025 18:42:03

daniel

HI

mit etwas Umgestaltung der Datentabelle, so das Excel damit arbeiten kann.
die anschauliche Form für den Anwender schreibt man dann darüber
https://www.herber.de/bbs/user/176444.xlsx

Gruß Daniel

AW: ohne WENN(), mit AGGREGAT() und WECHSELN() ...

26.03.2025 20:02:27

neopa C

Hallo Mike,

... für Deine Datenstruktur mit folgender Formel in D2:

=AGGREGAT(14;6;H$3:N$4/(O$3:O$4=B2)/(A2*(C2="groß")>=(WECHSELN(WECHSELN(H$2:N$2;"1";0);">=";"")+0));1)

und diese nach unten ziehend kopieren.

Gruß Werner
.. , - ...
aus C the unseen

AW: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

26.03.2025 20:41:44

Oppawinni

Also.. Wenn, dann, sonst... ist keine Schleife... eher eine bedingte Ausführung, oder Verzweigung, Kaskade usw...
Es ist merkwürdig, dass auch in Programmierer-Foren Leute immer wieder von einer If-Schleife schreiben. Auch die gibt es IMHO nicht.
Man könnte dein Thema in eine Formel packen, mit eingebauter Tabelle in Form von Matrixkonstanten...

=INDEX({24.28.30.34.38.44.48;1.4.5.7.13.17.20;24.24.24.24.24.24.24;1.1.1.1.1.1.1};VERGLEICH(B2&" "&C2;{"Produkt A groß";"Produkt B groß";"Produkt A klein";"Produkt B klein"};0);VERGLEICH(A2;{-1E+99;1;3;5;10;20;30};1))/2

aber schön ist anders.
Hier habe ich die Tabelle aber anders gestaltet, als du sie in deinem Excelblatt hast, um einen einfacheren Zugriff zu haben.
Im Prinzip nutze ich 4 Zeilen für "Produkt A groß";"Produkt B groß";"Produkt A klein","Produkt B klein" und 7 Spalten
Für die "kleinen Produkte" stehen dann halt in den Spalten überall die gleichen Werte...

AW: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

27.03.2025 22:32:33

Mike

Vielen Dank allen (Edgar, Werner, Daniel & Oppawinni) für die schnelle und hilfreiche Antwort, hat super geklappt! :-)

AW: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

26.03.2025 18:20:06

BoskoBiati

Hi,

da Deine Version kein XVERWEIS kennt:

=WENN(C2="klein";INDEX($G$3:$G$4;VERGLEICH(B2;$O$3:$O$4;0));INDEX($H$3:$N$4;VERGLEICH(B2;$O$3:$O$4;0);VERGLEICH(A2;$H$2:$N$2;1)))

Gruß

Edgar

AW: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

26.03.2025 18:25:57

BoskoBiati

Hi,

ganz ohne WENN:

=INDEX($G$3:$N$4;VERGLEICH(B2;$O$3:$O$4;0);1+(C2="groß")*VERGLEICH(A2;$H$2:$N$2;1))

Gruß

Edgar

AW: die Formeln ergeben bei mir aber nur #NV ?! owT

26.03.2025 19:57:30

neopa C

Gruß Werner
.. , - ...
aus C the unseen

AW: die Formeln ergeben bei mir aber nur #NV ?! owT

26.03.2025 20:12:07

BoskoBiati

Hi,

Du hast aber beachtet, dass ich die Tabelle etwas umgebaut habe?

Gruß

Edgar

AW: hatte Deine Formeln in die Datei des TE eingesetzt owT

26.03.2025 20:17:04

neopa C

Gruß Werner
.. , - ...
aus C the unseen

AW: mit Deiner "Umgestaltung" gehts aber auch einfacher ...

26.03.2025 20:36:04

neopa C

Hallo Edgar,

... dann reicht =AGGREGAT(14;6;H$3:N$4/(O$3:O$4=B2)/(A2*(C2="groß")>=H$2:N$2);1)

Gruß Werner
.. , - ...
aus C the unseen

AW: ergänzend dazu noch mit meiner "Umgestaltung" ...

26.03.2025 20:41:18

neopa C

Hallo nochmal,

... so:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	Jahre	Produkt	groß/klein	Zuordnung je nach Produkt (A/B) und groß/klein
2	3,20	Produkt A	groß	15			groß	0	>=1	>=3	>=5	>=10	>=20	>=30
3	2,15	Produkt A	klein	12		klein	12,0	12,0	14,0	15,0	17,0	19,0	22,0	24,0	Produkt A
4	1,84	Produkt A	klein	12		klein	0,5	0,5	2	2,5	3,5	6,5	8,5	10	Produkt B
5	4,51	Produkt A	groß	15
6	7,28	Produkt A	groß	17
7	1,90	Produkt A	klein	12
8	1,08	Produkt A	klein	12
9	5,93	Produkt A	klein	12
10	1,81	Produkt A	groß	14
11	31,24	Produkt A	groß	24
12	0,98	Produkt A	klein	12
13	1,83	Produkt A	klein	12
14	12,25	Produkt A	groß	19
15	19,05	Produkt B	groß	6,5

Zelle	Format	Wert
H2	""0	0
I2	">="0	1
J2	">="0	3
K2	">="0	5
L2	">="0	10
M2	">="0	20
N2	">="0	30

Zelle	Formel
D2	=AGGREGAT(14;6;H$3:N$4/(O$3:O$4=B2)/(A2*(C2="groß")>=H$2:N$2);1)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Gruß Werner
.. , - ...
aus C the unseen

Formel mit mehreren Variablen gesucht anstatt wenn-Formel

Forumthread: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Formel mit mehreren Variablen gesucht anstatt wenn-Formel

Forumthread: Formel mit mehreren Variablen gesucht anstatt wenn-Formel

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread