Anzahl eindeutiger Daten ermitteln

02.04.2025 17:20:48

JoergD

Hallo liebes Forum,

normalerweise kann ich mich in Excel ganz gut über Wasser halten, aber bei meinem jetzigen Vorhaben scheitere ich, daher hoffe ich, dass mir hier mit der geballten Excel-Erfahrung weitergeholfen werden kann.

Ich habe eine vereinfachte Beispieltabelle hochgeladen: https://www.herber.de/bbs/user/176549.xlsx

Die Tabelle besitzt vier Spalten: Datum, userid, stunden_projekt_vor_ort, spesentage_gesamt

Die Kombinationen aus Datum und userid können beliebig häufig vorkommen. stunden_projekt_vor_ort ist eine Zahl größer oder gleich Null.

In der Spalte "spesentage_gesamt" soll die Anzahl der Tage des Monats aus Spalte "Datum" stehen, für die gilt:
1. userid = userid in dieser Zeile
2. Summe "spesen_projekt_vor_ort" größer Null

In diesem Beispiel sollte die Spalte spesentage_gesamt wie folgt gefüllt sein:
Mitarbeiter_1: 0 für alle Januar-Daten, 2 für alle Februar-Daten
Mitarbeiter_2: 0 für alle Daten
Mitarbeiter_3: 0 für alle Daten
Mitarbeiter_4: 3 für alle Januar-Daten, 1 für alle Februar-Daten

Ich habe schon mit Hilfsspalten, mit SUMMENPRODUKT usw. einige Wege durchprobiert, jedoch ohne Erfolg. Habt ihr vielleicht eine Idee?

Vielen Dank schon einmal in Voraus!

Viele Grüße
Jörg

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 17:26:02

SF

Hola,
rein mit Summenprodukt bekomme ich andere Zahlen heraus.
Im Titel steht eindeutig, im Text steht davon nichts mehr.
Wie kommst du genau auf deine Ergebnisse?
Gruß,
steve1da

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 18:01:52

UweD

Hallo

Eindeutig??

Wenn ich den Text so berücksichtige, dann wäre die Formel so:

Stimmt aber nicht mit deinen händischen Angaben überein. (wer hat nun Recht?)

=SUMMENPRODUKT((TEXT([Datum];"JJJJMM")=TEXT(A2;"JJJJMM"))*([userid]=B2)*([stunden_projekt_vor_ort]>0))

LG UweD

Im Anhang habe...

02.04.2025 19:21:32

Case

Moin Jörg, :-)

... ich dir ein Beispiel mit Power Query erstellt: ;-)
https://www.herber.de/bbs/user/176554.xlsx

Servus
Case

AW: Im Anhang habe...

03.04.2025 15:13:03

JoergD

Hallo Case,

vielen Dank! Für meinen Anwendungsfall ist es einfacher, die Formel von Rolf zu nutzen, statt mit Power Query zu arbeiten. Ich behalte mir die Idee aber für zukünftige Sachen im Hinterkopf.

Viele Grüße
Jörg

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 18:26:04

JoergD

Hallo,

diese Formel bringt im konkreten Beispiel für Mitarbeiter_4 im Januar eine 6 zurück, da es 6 Einträge in der Tabelle sind, die die Voraussetzungen erfüllen. An der Stelle bin ich vorhin bei selbst schreiben ausgestiegen.

Wenn man von dort aus noch auf die 3 für drei verschiedene Daten im Januar kommt, dann wäre das Ziel erreicht.

Viele Grüße
Jörg

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 19:31:34

UweD

Hallo nochmal

Mit dem Hinweis aus dem anderen Beitrag so?? (geht bestimmt noch kürzer)

=LET(Anz;EINDEUTIG(FILTER([Datum];(TEXT([Datum];"JJJJMM")=TEXT([@Datum];"JJJJMM"))*([userid]=[@userid])*([stunden_projekt_vor_ort]>0)));ANZAHL(FILTER(Anz;Anz>0)))

LG UweD

AW: Anzahl eindeutiger Daten ermitteln

03.04.2025 15:02:10

JoergD

Hallo Uwe,

vielen Dank, die Formel funktioniert in meiner Beispieltabelle. Auf den ersten Blick war ich leicht überfordert :) aber wenn man das Ganze rückwärts auseinanderbaut, dann verstehe ich es. Die Funktion LET ist mir bis heute noch nicht über den Weg gelaufen. Hier lernt man immer etwas dazu.

Viele Grüße
Jörg

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 19:52:05

Rolf

Hallo Joerg,

mein Formel-Vorschlag für D2:

=ANZAHL(EINDEUTIG(FILTER([Datum];(MONAT([Datum])=MONAT(A2))*([userid]=B2)*([stunden_projekt_vor_ort]>0);"")))

Gruß Rolf

AW: Anzahl eindeutiger Daten ermitteln

03.04.2025 15:08:33

JoergD

Hallo Rolf,

vielen Dank auch an dich, in meiner Beispieltabelle funktioniert es. :)

Vereinfacht gesagt rechnet deine Formel das gleiche wie die von UweD, ist aber kürzer und für meine Excel-Kenntnisse einfacher nachzuvollziehen.

Ich teste es gleich in meiner "großen" Tabelle.

Viele Grüße
Jörg

AW: Anzahl eindeutiger Daten ermitteln

03.04.2025 16:54:57

UweD

Hallo

Ja, auf das Let- Konstrukt kann verzichtet werden

Aber pass auf, wenn du mal gleiche Monate aus unterschiedlichen Jahren in der Tabelle hast...

Bei Rolf bleibt das Jahr unbeachtet

=ANZAHL(EINDEUTIG(FILTER([Datum];(TEXT([Datum];"JJJJMM")=TEXT([@Datum];"JJJJMM"))*([userid]=[@userid])*([stunden_projekt_vor_ort]>0);"")))

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 17:46:51

JoergD

Hallo,

vielen Dank fürs Anschauen meines Problems.

Vielleicht habe ich mich missverständlich ausgedrückt. Die Zahlen, die ich bei den einzelnen Mitarbeitern genannt habe, sind die, die ich herausbekommen MÖCHTE, es aber mit meinen Excel-Künsten nicht schaffe.

Beispiel:
Mitarbeiter_4 hat am 08.01. einen Eintrag mit "stunden_vor_ort" > 0 (Zeile 100), am 14.01. zwei Einträge (Zeilen 216 und 220) und am 15.01. drei Einträge (Zeilen 234, 239 und 241). Entsprechend hätte ich gerne, dass die Spalte "spesentage_gesamt" in allen Zeilen in denen das "Datum" im Januar liegt und in dem in "userid" Mitarbeiter_4 steht, mit der Zahl 3 für drei eindeutige Daten (08.01., 14.01., 15.01.) ausgefüllt wird.

Viele Grüße
Jörg

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 17:54:31

SF

=ANZAHL2(EINDEUTIG(FILTER(A2:A993;(MONAT(A2:A993)=1)*(B2:B993="mitarbeiter_4")*(C2:C993>0))))

AW: Anzahl eindeutiger Daten ermitteln

02.04.2025 18:21:28

JoergD

Für (B2:B993="mitarbeiter_4") funktioniert das. Für mitarbeiter_2 leider nicht, da wird eine 1 angezeigt und es müsste eine 0 sein.

Da die Formel in jeder Zeile der Spalte "spesentage_gesamt" steht, müsste z. B. auch für B2:B993 ein tab_vo[userid] in der Formel stehen, aber ich denke, das ist jetzt noch nicht das Entscheidende.

Anzahl eindeutiger Daten ermitteln

Forumthread: Anzahl eindeutiger Daten ermitteln

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Anzahl eindeutiger Daten ermitteln

Forumthread: Anzahl eindeutiger Daten ermitteln

13 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread