Löschen von Zeilen

29.04.2025 15:03:33

NicoHendrik

Hallo alle zusammen,

Wenn die Zelle C8 leer ist soll der Inhalt von Zellen K8 bis NL8 gelöscht werden.

Wenn die Zelle C57 leer ist soll der Inhalt von Zellen K57 bis NL57 gelöscht werden.

Dies soll von C8 bis C57 gelten.

Kann mir bitte jemand dabei helfen?

Gruß Nico

https://www.herber.de/bbs/user/177294.xlsm

AW: Löschen von Zeilen

29.04.2025 15:30:31

velo

Hallo,

kann deine Datei aufgrund der Firmen-Firewall leider nicht aufmachen.

So in etwas?

Option Explicit



Sub d()

    Dim ws As Worksheet

    Dim i As Integer

    

    Set ws = ThisWorkbook.Worksheets("Tabelle1")

    

    For i = 8 To 57

        If ws.Cells(i, 3).Value = "" Then

            ws.Range("K" & i & ":NL" & i).ClearContents

        End If

    Next i

    

End Sub

Oder willst du das ganze mit Events machen?

VG
velo

AW: Löschen von Zeilen

29.04.2025 15:32:53

cysu11

Hallo Nico,

habs in dein Blattereignis eingebaut, siehe Anhang.

https://www.herber.de/bbs/user/177295.xlsm

LG, Alexandra

AW: Löschen von Zeilen

29.04.2025 18:56:47

Piet

Hallo

bitte probiere mal diesen Code aus, der könnte deine Aufgabe erfüllen. Ich habe mir dazu die anderen Lösungen angesehen.

@Alexandra Dein Code löscht, wie ich das sehe, den gesamten Bereich! Da gehen aber bereits eingetragene Urlaubstage verloren!
@Daniel Dein Code ist sehr schnell, löscht alle Leerzeilen, zerreisst aber die Tabelle, weil viele Leerzeilen zwischen den Daten stehen.

Mein Code kopiert Rückwärts die eingetragenen unteren Daten nach oben, lässt aber die Formeln unberührt.
Im Beispiel steht "Peter" mit SEINEN Urlaubstagen ganz oben. Ich nehme seine Urlaubstage mit nach oben!
Ich hoffe ich habe damit die Aufgabenstellung richtig verstanden. Wir werden sehen??

mfg Piet

Sub Zeilen_löschen_RW()

Dim j As Integer

    Application.ScreenUpdating = False

    'Leerzeilen löschen, nach oben kopieren!

    For j = 57 To 8 Step -1

        If Cells(j, 3).Value = Empty Then

           Cells(j + 1, 11).Resize(58 - j, 366).Copy

           Cells(j, 11).PasteSpecial xlPasteValues

           Cells(j + 1, 3).Resize(58 - j, 2).Copy

           Cells(j, 3).PasteSpecial xlPasteValues

        End If

    Next j

    MsgBox "Fertig"

End Sub

AW: Löschen von Zeilen

29.04.2025 21:01:16

NicoHendrik

Hallo Piet, dein Code funktioniert prima.

Danke Nico

AW: Löschen von Zeilen

29.04.2025 22:44:10

daniel

@Daniel Dein Code ist sehr schnell, löscht alle Leerzeilen, zerreisst aber die Tabelle, weil viele Leerzeilen zwischen den Daten stehen.

das müsstest du mir erklären.
Mein Code zerreißt da nichts.
Er lässt die Daten dort, wo sie sind.
Eine Neuanordnung der Daten war nicht gefragt.
Da wäre die Frage, ob man sowas nicht einfacher über Sortieren macht.

AW: @Daniel Sorry, 'zerreißen' war schlecht ausgedrückt oWt

30.04.2025 00:39:03

Piet

...

AW: Löschen von Zeilen

29.04.2025 15:51:50

daniel

Hi
wenn bei deinem ClearAll nur die gelöscht werden sollen, die in Spalte C keinen Eintrag haben, dann so:

Sub ClearAll2()

With Range("C8:C57")

    If WorksheetFunction.CountBlank(.Cells) > 0 Then Intersect(.SpecialCells(xlCellTypeBlanks).EntireRow, Range("K:NL")).ClearContents

End With

End Sub

Gruß Daniel

AW: Löschen von Zeilen

29.04.2025 19:06:26

Piet

Nachtrag

ich sehe gerade den Code des Kollegen GerdL und habe in meinem etwas vergessen. Bitte noch einfügen.
Application.EnableEvents = False - gehört VOR For Next --> Application.EnableEvents = True bitte NACH Next

mfg Piet