Testergebnis (funktioniert)
24.05.2025 18:46:04
Christian
Hallo Eifeljoi,
der finale Code in der Originaldatei sieht jetzt so aus:
let
A = Date.ToText(Date.From(DateTime.LocalNow()), "yyyy-MM-dd"),
Quelle = Csv.Document(
File.Contents("C:\Users\chris\Downloads\zHV_aktuell_csv." & A & "\zHV_aktuell_csv." & A & ".csv"),
[Delimiter=";", Columns=17, Encoding=65001, QuoteStyle=QuoteStyle.None]
),
#"Höher gestufte Header" = Table.PromoteHeaders(Quelle, [PromoteAllScalars=true]),
#"Geänderter Typ" = Table.TransformColumnTypes(#"Höher gestufte Header", {
{"SeqNo", Int64.Type}, {"Type", type text}, {"DHID", type text}, {"Parent", type text},
{"Name", type text}, {"Latitude", type number}, {"Longitude", type number},
{"MunicipalityCode", Int64.Type}, {"Municipality", type text},
{"DistrictCode", type text}, {"District", type text}, {"Description", type text},
{"Authority", type text}, {"DelfiName", type text}, {"THID", type text},
{"TariffProvider", type text}, {"LastOperationDate", type datetime}
}),
#"Entfernte Spalten" = Table.RemoveColumns(#"Geänderter Typ", {
"Type", "DHID", "Parent", "MunicipalityCode", "DistrictCode", "District",
"Description", "Authority", "DelfiName", "THID", "TariffProvider"
}),
#"Gefilterte Zeilen" = Table.SelectRows(#"Entfernte Spalten", each [Municipality] > "-"),
#"Geänderter Typ1" = Table.TransformColumnTypes(#"Gefilterte Zeilen", {
{"LastOperationDate", type date}
}),
latRef = 50.762407,
lonRef = 6.999864,
MitEntfernung = Table.AddColumn(#"Geänderter Typ1", "Entfernung_km", each
let
lat1 = latRef * Number.PI / 180,
lon1 = lonRef * Number.PI / 180,
lat2 = [Latitude] * Number.PI / 180,
lon2 = [Longitude] * Number.PI / 180,
dLat = lat2 - lat1,
dLon = lon2 - lon1,
a = Number.Power(Number.Sin(dLat / 2), 2) +
Number.Cos(lat1) * Number.Cos(lat2) * Number.Power(Number.Sin(dLon / 2), 2),
c = 2 * Number.Atan2(Number.Sqrt(a), Number.Sqrt(1 - a)),
r = 6371,
dist = r * c
in
Number.Round(dist, 7)
),
Ergebnis = Table.ReorderColumns(MitEntfernung,{"SeqNo", "Name", "Latitude", "Longitude", "Municipality", "LastOperationDate", "Entfernung_km"}),
#"Sortierte Zeilen" = Table.Sort(Ergebnis,{{"Entfernung_km", Order.Ascending}}),
#"Gefilterte Zeilen1" = Table.SelectRows(#"Sortierte Zeilen", each [Entfernung_km] = 80),
// Angepasst: "Koordinaten" mit Punkt als Dezimaltrennzeichen >>>
MitKoordinatenSpalte = Table.AddColumn(#"Gefilterte Zeilen1", "Koordinaten", each
Number.ToText([Latitude], "0.000000", "en-US") & " " & Number.ToText([Longitude], "0.000000", "en-US"),
type text
),
#"Neu angeordnete Spalten" = Table.ReorderColumns(MitKoordinatenSpalte,{
"SeqNo", "Name", "Latitude", "Longitude", "Koordinaten", "Municipality", "LastOperationDate", "Entfernung_km"
})
in
#"Neu angeordnete Spalten"
funktioniert, danke würde mich aber trotzdem mal interessieren, wo diese Rattenschwänze 9999.....6 herkamen
Schönes Wochenende
Christian