Bereich nach einem Kriterium durchsuchen + Wert ausgeben

05.06.2025 11:14:44

Pseudotussi

Hallo,

ich habe mal wieder ein Problem:
Ich habe eine Tabelle, die mit Punkten bzw. Platzierungen gefüllt ist. Nun möchte ich diese Platzierungen in einer aufsteigenden Liste mit Team und Teilnehmer überführen.
Die Funktion für das Feld Team habe ich mir schonmal zusammengebastelt, bei der Spalte für den Teilnehmer (hier soll aus den Zellen A2:A4 die Spieler überführt werden) fehlt mir jegliche Inspiration.

Bitte helft mir :-) Vielen Dank

https://www.herber.de/bbs/user/177671.xlsx

AW: Bereich nach einem Kriterium durchsuchen + Wert ausgeben

05.06.2025 11:22:22

SF

Hola,
im Prinzip genau so nur dass du den Index Bereich auf A2:A4 setzt und Zeile() anstelle von Spalte() verwendest.
Aber: warum fragst du 2mal die gleiche Bedingung ab?

(($B$2:$G$4=$A8)*($B$2:$G$4=$A8))

Gruß,
steve1da

AW: Bereich nach einem Kriterium durchsuchen + Wert ausgeben

05.06.2025 12:35:13

Pseudotussi

Hallo Steve,

in der Spalte Team habe ich die Formel nach Deinem Vorschlag geändert. Keine Ahnung, warum ich die Bedingung 2x abgefragt habe. Wahrscheinlich, weil ich die Funktion nicht so richtig verstanden habe :-( Danke für den Hinweis :-)

In der Spalte Teilnehmer habe ich ebenfalls Deine Empfehlung umgesetzt. Leider erhalte ich eine Fehlermeldung. Was habe ich hier falsch gemacht?

https://www.herber.de/bbs/user/177673.xlsx

AW: die kann so auch nicht funktionieren, denn ...

05.06.2025 12:40:38

neopa C

Hallo nochmal,

... diese müßte hier so: =INDEX(B:B;AGGREGAT(15;6;ZEILE(B$2:B$4)/(C$2:J$4=B8);1)) lauten.

Aber wie in meinem anderen Beitrag geschrieben, wird damit nur eine Teillösung erzeugt.

Gruß Werner
.. , - ...
aus C the unseen

AW: dazu ist ein anderes Ergebnislistung notwendig, denn ...

05.06.2025 12:33:28

neopa C

Hallo Pseudotussi,

... es gibt ja einige Plazierungen, die doppelt oder gar mehrfach vorhanden sind.

Mein Vorschlag dazu wäre akt. folgender, wobei die Formeln A8:C8 weit genug nach unten ziehend zu kopieren sind:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1	Teilnehmer	Team 1	Team 2	Team 3	Team 4	Team 5	Team 6
2	Spieler 1	17	4	10	16	1	9
3	Spieler 2	14	3	7	6	4	18
4	Spieler 3	2	10	10	10	14	7
5
6
7	Platzierung	Team	Teilnehmer
8	1	Team 5	Spieler 1
9	2	Team 1	Spieler 3
10	3	Team 2	Spieler 2
11	4	Team 2	Spieler 1
12	4	Team 5	Spieler 2
13	6	Team 4	Spieler 2
14	7	Team 3	Spieler 2
15	7	Team 6	Spieler 3
16	9	Team 6	Spieler 1
17	10	Team 2	Spieler 3
18	10	Team 3	Spieler 1
19	10	Team 3	Spieler 3
20	10	Team 4	Spieler 3
21	14	Team 1	Spieler 2
22	14	Team 5	Spieler 3
23	16	Team 4	Spieler 1
24	17	Team 1	Spieler 1
25	18	Team 6	Spieler 2

Zelle	Formel
A8	=WENNFEHLER(KKLEINSTE(Tabelle6[[Team 1]:[Team 6]];ZEILE(A1));"")
B8	=WENNFEHLER(INDEX($1:$1;AGGREGAT(15;6;SPALTE(B1:G1)/(B$2:G$4=A8);ZÄHLENWENN(A$8:A8;A8)));"")
C8	=WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE(A$2:A$4)/($B$2:$G$4=$A8)/(Tabelle6[[#Kopfzeilen];[Team 1]:[Team 6]]=B8);ZÄHLENWENNS(A$7:A8;A8;B$7:B8;B8)));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Die Lösungsformeln könnte noch mehr auf die "intelligente" Datenliste angepasst werden, so dass bei einer Erweiterung der Daten keine Formelanpassung mehr notwendig ist. Habe ich aber jetzt erst einmal verzichtet.

Gruß Werner
.. , - ...
aus C the unseen

AW: alternativ und viel einfacher wäre eine PQ-Lösung, ...

05.06.2025 12:51:36

neopa C

Hallo nochmal,

... denn dazu wäre lediglich 15 Mausklicks notwendig (wenn ich mich nicht verzählt habe).
Mehr zu PQ sieh mal hier: https://excelhero.de/power-query/power-query-ganz-einfach-erklaert/

Gruß Werner
.. , - ...
aus C the unseen

Im Anhang habe...

05.06.2025 18:29:24

Case

Moin, :-)

... ich eine mögliche Lösung mit Power Query: ;-)
https://www.herber.de/bbs/user/177678.xlsx

Servus
Case

AW: alternativ und viel einfacher wäre eine PQ-Lösung, ...

05.06.2025 15:07:43

Pseudotussi

Hallo Werner,

vielen lieben Dank für Deine Hilfen. Ich habe mich spontan für Deine WENNFEHLER.... entschieden. Die ist passgenau auf mich zugeschnitten.
Mit Power-Query muss ich mich dringend beschäftigen. Habe schon viel davon gehört und sogar schon einmal nach Anleitung ausprobiert. Leider fehlt hierzu die Zeit :-(
Nochmals vielen lieben Dank

AW: bitteschön owT

05.06.2025 19:57:03

neopa C

Gruß Werner
.. , - ...
aus C the unseen

Bereich nach einem Kriterium durchsuchen + Wert ausgeben

Forumthread: Bereich nach einem Kriterium durchsuchen + Wert ausgeben

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Bereich nach einem Kriterium durchsuchen + Wert ausgeben

Forumthread: Bereich nach einem Kriterium durchsuchen + Wert ausgeben

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread