Fehler in Formel, finde ihn aber nicht.

06.07.2025 15:37:02

Marcus

Hallo zusammen ich habe mir über ChatCPT eine Formel erstellen lassen.
es kommt aber immer nur #Name?

Ausgang:
Es werde in OSS "A8" daten gefiltert.
Es soll nun alle doppelten "Bestellnummern" zusammengefasst werden und dementsprechend die Summen für "Netto" "Mwst" und "Brutto" erstellt werden

ChatGPT hat mir folgende Formel gegeben:

=VSTACK(
{"Bestellnummer";"Summe AD";"Summe AQ";"Summe BA"};
LET(
daten; INDIREKT("'"&B4&"-"&C4&"'!A:CQ");
bestNr; INDEX(daten;;7);
bp; INDEX(daten;;68);
cp; INDEX(daten;;80);
ad; INDEX(daten;;30);
aq; INDEX(daten;;43);
ba; INDEX(daten;;53);
gefiltert; FILTER(HSTACK(bestNr; ad; aq; ba); (bp=F4)*(cp="UNION-OSS"));
gruppen; EINDEUTIG(INDEX(gefiltert;;1));
summiert; LAMBDA(bn; HSTACK(
bn;
SUMMEWENNS(INDEX(gefiltert;;2); INDEX(gefiltert;;1); bn);
SUMMEWENNS(INDEX(gefiltert;;3); INDEX(gefiltert;;1); bn);
SUMMEWENNS(INDEX(gefiltert;;4); INDEX(gefiltert;;1); bn)
));
MAP(gruppen; summiert)
)
)

Diese Formel habe ich in H8 eingefügt. Es kommt aber immer der Fehler. Ich weis aber nicht was falsch ist.

Hier die Datei https://www.herber.de/bbs/user/178015.xlsx

Könnte mir jemand einen Tip geben.

Vielen Dank und viele Grüße
Marcus

AW: Fehler in Formel, finde ihn aber nicht.

06.07.2025 16:17:44

RPP63

Moin!
VSTACK ist auf deutsch VSTAPELN

Gruß Ralf

AW: Fehler in Formel, finde ihn aber nicht.

06.07.2025 16:23:03

Marcus

Hallo Ralf
Danke für die Nachricht.
habe es geändert es kommt leider immer noch #Name?

VG Marcus

AW: Fehler in Formel, finde ihn aber nicht.

06.07.2025 16:30:02

RPP63

Wenn es vstack nicht gibt, was gilt dann wohl für hstack?

AW: Fehler in Formel, finde ihn aber nicht.

06.07.2025 17:22:16

Marcus

Ich habe nun beide Sachen Geändert. Nun steht aber #CALC!

Neue Formel

=VSTAPELN(

    {"Bestellnummer";"Summe AD";"Summe AQ";"Summe BA"};

    LET(

        daten;      INDIREKT("'"&B4&"-"&C4&"'!A:CQ");

        bestNr;     INDEX(daten;;7);

        bp;         INDEX(daten;;68);

        cp;         INDEX(daten;;94);

        ad;         INDEX(daten;;30);

        aq;         INDEX(daten;;43);

        ba;         INDEX(daten;;53);

        gefiltert;  FILTER(HSTAPELN(bestNr; ad; aq; ba); (bp=F4)*(cp="UNION-OSS"));

        gruppen;    EINDEUTIG(INDEX(gefiltert;;1));

        summiert;   LAMBDA(bn; HSTAPELN(

                          bn;

                          SUMMEWENNS(INDEX(gefiltert;;2); INDEX(gefiltert;;1); bn);

                          SUMMEWENNS(INDEX(gefiltert;;3); INDEX(gefiltert;;1); bn);

                          SUMMEWENNS(INDEX(gefiltert;;4); INDEX(gefiltert;;1); bn)

                      ));

        MAP(gruppen; summiert)

    )

)

Hier die neue Datei

keine Bspdatei

06.07.2025 18:04:19

Christian

Hallo Marcus,

mit deinem Problem selber bin ich überfragt. Allerdings sehe ich in deinem Beitrag keine neue Bsp Datei, solltest du vielleicht nochmal uploaden.

Gruß
Christian

AW: keine Bspdatei

07.07.2025 09:33:18

schauan

... die neue Formel (Beitrag von 15:22) einfach in die ursprüngliche Datei übertragen, dann geht's auch ohne erneuten Upload ;-)

AW: Fehler in Formel, finde ihn aber nicht.

06.07.2025 19:49:57

BoskoBiati

Hi,

ChatGPT ist kein Excel-Könner!

=LET(daten;INDIREKT("'"&B4&"-"&C4&"'!A3:CQ300");bestNr;INDEX(daten;;7);bp;INDEX(daten;;68);cp;INDEX(daten;;94);ad;INDEX(daten;;30);aq;INDEX(daten;;43);ba;INDEX(daten;;53);gefiltert;FILTER(SPALTENWAHL(daten;7;30;43;53);(bp=F4)*(cp="UNION-OSS"));gruppen;SORTIEREN(EINDEUTIG(INDEX(gefiltert;;1));1;1);sumad;NACHZEILE(gruppen;LAMBDA(a;SUMMEWENN(bestNr;a;aq)));sumaq;NACHZEILE(gruppen;LAMBDA(a;SUMMEWENN(bestNr;a;ad)));sumba;NACHZEILE(gruppen;LAMBDA(a;SUMMEWENN(bestNr;a;ba)));VSTAPELN(HSTAPELN("Bestellnummer";"Summe AD";"Summe AQ";"Summe BA");HSTAPELN(gruppen;sumad;sumaq;sumba)))

Gruß

Edgar

AW: Fehler in Formel, finde ihn aber nicht.

06.07.2025 20:16:03

Marcus

Hallo Edgar Viele Dank für die Hilfe

Vg Marcus

AW: Fehler in Formel, finde ihn aber nicht.

07.07.2025 19:40:38

Onur

Hi,

Meine Formel:

=LET(rn;$C$8:$F$114;zu;ZUZEILE({"Bestellnummer";"Summe AD";"Summe AQ";"Summe BA"});be;SORTIEREN(EINDEUTIG(INDEX(rn;;4)));bes;FILTER(be;be>0);ad;SUMMEWENNS(INDEX(rn;;2);INDEX(rn;;4);bes);aq;SUMMEWENNS(INDEX(rn;;1);INDEX(rn;;4);bes);ba;SUMMEWENNS(INDEX(rn;;3);INDEX(rn;;4);bes);hs;HSTAPELN(bes;ad;aq;ba);VSTAPELN(zu;hs))

kommt aber auf andere Ergebnisse:

https://www.herber.de/bbs/user/178032.xlsx

Fehler in Formel, finde ihn aber nicht.

Forumthread: Fehler in Formel, finde ihn aber nicht.

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Fehler in Formel, finde ihn aber nicht.

Forumthread: Fehler in Formel, finde ihn aber nicht.

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread