Altersklassen

Forumthread: Altersklassen

Altersklassen

22.07.2025 17:27:34

PleinCiel

Hallo zusammen,

ich habe in meiner Mitarbeitertabelle eine Zelle in der das Alter berechnet wird

=DATEDIF(J181;HEUTE();"Y")

. Dies funktioniert auch tadellos.

Nun soll er mir in einer anderen Spalte die Altersgruppe ausspucken. Dazu nutze ich folgenden Code:

=VERWEIS(DATEDIF(J181;HEUTE();"y")-(TEXT(J181;"MMTT")*1>630)+(TEXT(HEUTE();"MMTT")*1>630);{18;25;35;45;55;60;65};{"18-24";"25-34";"35-44";"45-54";"55-59";"60-64";"65+"})

Jetzt ist mir aber aufgefallen, das jemand der am 15.11.1965 geboren ist, also 59 Jahre ist korrekt in die Altersgruppe 55-59 eingruppiert wird aber jemand anderes der am 25.01.1966 geboren ist, also auch 59 Jahre ist, in die Altersgruppe 60-64 eingruppiert wird.

Wo ist der Fehler, ich werde noch bekloppt :-)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Altersklassen

22.07.2025 17:54:21

daniel
Probiere es...

22.07.2025 18:04:42

Case
AW: Altersklassen

22.07.2025 18:11:12

Yal
AW: Altersklassen

22.07.2025 18:25:24

BoskoBiati
AW: Altersklassen

22.07.2025 19:20:49

daniel
AW: Altersklassen

23.07.2025 11:33:02

PleinCiel
AW: Altersklassen

22.07.2025 18:29:39

BoskoBiati
AW: Altersklassen

22.07.2025 18:01:20

PleinCiel
AW: Altersklassen

22.07.2025 18:48:52

daniel

AW: Altersklassen

22.07.2025 17:54:21

daniel

Hi

wo kommt denn dieser Teil der Berechnung her:

-(TEXT(J181;"MMTT")*1>630)+(TEXT(HEUTE();"MMTT")*1>630)

dh machst den Menschen um ein Jahr älter, wenn das aktuelle Datum in der zweiten Jahreshälfte liegt
und du machst den Menschen um ein Jahr jünger, wenn sein Geburtsdatum in der zweiten Jahreshälfte liegt.

was soll damit bezweckt werden?
vielleicht überlegst du dir da nochmal die Logik

Gruß Daniel

Probiere es...

22.07.2025 18:04:42

Case

Moin, :-)

... mal so: ;-)

=WAHL(VERGLEICH(DATEDIF(A2;HEUTE();"Y");{0;18;25;35;45;55;60;65};1);"unter 18";"18-24";"25-34";"35-44";"45-54";"55-59";"60-64";"65+")

Servus
Case

AW: Altersklassen

22.07.2025 18:11:12

Yal

Hallo Plein (man spricht sich im Forum per Vorname an ;-)

Du kannst eine Zuordnung des Alters mithilfe VERWEIS erreichen. Dafür brauchst Du
eine aufsteigende Datumliste.
Diese in im Spalte B Anhand des Alters im Spalte A.
In Spalte C wird einen Text erzeugt.
In Spalte E sind willkürliche Datum aufegestellt,
in F die Zuordnung mit Verweis.
Bis auf Spalte A (eingegebene, feste Werte) sind alle Formel in der Spalte dieselbe wie in Zeile 4.

Userbild

Für ein Datum vor dem 22.07.1960 müsste davor eine gültige Datum wie z.B. 01.01.1900 (aufsteigend) eingetragen werden.

VG
Yal

AW: Altersklassen

22.07.2025 18:25:24

BoskoBiati

Hi,

ich würde das vorschlagen:

=LET(xa;UNTERGRENZE(DATEDIF(J181;HEUTE();"Y");5);xa-(xa25)*2&" - "&xa+4)

Gruß

Edgar

AW: Altersklassen

22.07.2025 19:20:49

daniel

Hi

das DateDif schaltet am Geburtstag auf die neue Jahreszahl um, von daher brauchst du meiner Ansicht nach keine weitere Korrekturrechnungen.

ich würde hier auch den SVerweis nehmen, den kann man auch mit einer Matrixkonstante füttern und ich finde diese übersichtlicher, weil Suchwert und dazugehöriger Ergebniswerte direkt nebeneinander stehen und nicht in zwei Listen getrennt sind:

=SVERWEIS(DATEDIF(J181;HEUTE();"Y");{0."0-17";18."18-24";25."25-34";35."35-44";45."45-54";55."55-59";60."60-64";65."65+"};2;1)

Gruß Daniel

AW: Altersklassen

23.07.2025 11:33:02

PleinCiel

Hallo Daniel,

Danke für die Info. Hab den Code so umgesetzt und er funktioniert super.

Vielen Dank für die Hilfe.

AW: Altersklassen

22.07.2025 18:29:39

BoskoBiati

Hi,

kleine Verbesserung (65+):

=LET(xa;UNTERGRENZE(DATEDIF(A1;HEUTE();"Y");5);xb;xa-(xa25)*2&" - "&xa+4;xc;"65+";WENN(xa>64;xc;xb))

Gruß

Edgar

AW: Altersklassen

22.07.2025 18:01:20

PleinCiel

Hallo Daniel,

das ist das nächste Problem. Die Datei wo ich mir die Erklärung zur Formel geschrieben hatte, habe ich nicht mehr deswegen steck ich gerade fest.

AW: Altersklassen

22.07.2025 18:48:52

daniel

naja, ich habe dir ja beschrieben, was die beiden Formelteile bewirken.
ich halte sie nicht für sinnvoll und würde nur mit dem von DateDiff berechneten Wert rechnen.
Aber das musst du entscheiden.

Forumthread: Altersklassen

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread