Dynamische Verformelung abhängig vom ausgewählten Monat

02.09.2025 18:43:39

Manfred Will

Hallo,

wie wäre eine passende Formel, um je nach Auswahl des Monats oben die richtigen Monatsspalten unten anzusteuern?

https://www.herber.de/bbs/user/178819.xlsx

Vielen Dank

AW: Dynamische Verformelung abhängig vom ausgewählten Monat

02.09.2025 18:55:17

SF

Hola,
zB der Wverweis(). Vorher aber die Werte in C10, E10, G10.... in echte Zahlen umwandeln weil du ansonsten eine ZAHL mit einem TEXT vergleichst.
Gruß,
steve1da

AW: Dynamische Verformelung abhängig vom ausgewählten Monat

02.09.2025 19:06:17

SF

Wenn der Aufbau immer gleich ist und die Reihenfolge der Kategorien auch, reicht der Wverweis().
Wenn es variabel ist:
https://www.herber.de/excelformeln/pages/Koordinaten_aus_Suchbegriff_in_Zeile_und_Spalte_bestimmen.html

AW: Dynamische Verformelung abhängig vom ausgewählten Monat

02.09.2025 19:10:48

Alwin Weisangler

Hallo,

oder auch so:

=INDEX($C$10:$L$12;ZEILE()-1;VERGLEICH($F3;$C$10:$L$10;0))

Aber ebenso Zahlen mit Zahlen vergleichen und nicht Textzahlen mit Zahlen wie im Beispiel.

Gruß Uwe

AW: hierzu reicht alternativ auch nur eine Funktion aus ...

02.09.2025 22:10:41

neopa C

Hallo Manfred,

... und zwar in G3: =AGGREGAT(15;6;C$11:L$99/(B$11:B$99=D3)/(-C$10:L$10=-F3);1)
(durch das - in der Formel vor einer Ziffernfolge, mit oder ohne Komma, welche als Texte formatiert sind, werden echte Excelzahlenwerte generiert, welche somit auch gleichzeitig negiert werden; das - vor dem bereits "echten Zahlenwert" ist dann natürlich für den Vergleich mit den negierten Werten notwendig)

Gruß Werner
.. , - ...
aus C the unseen

Manfred will...

05.09.2025 01:39:32

SF

....scheinbar nicht mehr antworten....

AW: hierzu reicht alternativ auch nur eine Funktion aus ...

02.09.2025 23:31:56

daniel

Ist zwar nur eine Funktion, aber man darf sich nicht täuschen lassen.
In einer 10x10-Matrix muss bei dieser Formel der Vergleich zweier Zellen (=) 200× durchgeführt werden um das Ergebnis zu finden.
In der Index+Vergleich+Vergleich-Formel nur maximal 20x, minimal sogar nur 2×.

In großen Tabellen und vielen derartigen Auswertungen wird Aggregat langsamer sein , weil es mehr rechnen muss.

AW: hierzu reicht alternativ auch nur eine Funktion aus ...

03.09.2025 00:40:44

Luschi

Hallo Excel-Fan's,

meine Spill-Formel sieht so aus:

=NACHZEILE(D3.:.D8;LAMBDA(a;LET(b;FILTER($C$11:$L$99;$B$11:$B$99=a);

                                c;VERGLEICH(--$F3;--$C$10:$L$10;0);

                                d;INDEX(b;1;c);

d)))

Gruß von Luschi
aus klein-Paris

AW: uff ...

03.09.2025 11:15:04

neopa C

Hallo Luschi,

... Dein Lösungsvorschlag schreckt mich, ehrlich gesagt eher ab, mich von meinem alten XL_Versionen zu trennen. Zudem u.a. auch meine Lösungsformel automatisch "spillt" (wenn B2:G4 zuvor als "intelligente" Tabelle formatiert wurde, wozu ja nur eine Tastenkombination und eine Mausklick notwendig ist).

Warum hast Du als PQ-Fan anstelle dessen nicht eine PQ-Lösung aufgezeigt? Denn zumindest für mich ist fast offensichtlich, das Manfred in seiner Originaldatei zumindest seine Daten bereits in einer "intelligente" Tabelle zu stehen hat.

Gruß Werner
.. , - ...
aus C the unseen

AW: Nanu, warum uff ...?

03.09.2025 18:17:57

Luschi

Hallo Werner,

ich wußte gar nicht, daß Du so leicht erschreckbar bist. Man muß eben in E_365 auch mal ein bißchen umdenken und nicht immer die gleichen Gleise zum Ziel benutzen,
Aber es hindert Dich doch auch niemand, in der neuen Version mit den alten, liebgewonnenen Mustern weiterzuarbeiten; nur die Aggregat-Fkt. wirst Du schnell links liegen lassen.

Gruß von Luschi
aus klein-Paris

AW: nun, einfach deshalb weil ...

05.09.2025 10:21:56

neopa C

Hallo Luschi,

... ich mir momentan nicht vorstellen kann und auch nicht möchte, dass für eine so relativ einfache Aufgabe in /mit XL365 eine so relativ komplexe Formel eingesetzt werden muß/sollte.

Gruß Werner
.. , - ...
aus C the unseen

AW: Dein Hinweis ist richtig wie wichtig, nur ...

03.09.2025 11:03:55

neopa C

Hallo Daniel,

... ist dieser zumindest mE leider nur unvollständig.

Denn selbst bei einer Datenmatrix von z.B. 100 x 24 spielt das, auf was Du berechtigt hinweist, bei der heute eingesetzten Hardware eine meist unter-/nachgeordnete Rolle. Aber natürlich sollte das ein jeder immer zumindest im Hinterkopf behalten.

Es gibt aber mE viel mehr zu beachten als allein das. Das wichtigste ist zuallererst eine möglichst gut durchdachte Datenstruktur und danach zu überdenken, wie oft eine angestrebte Lösung für die jeweilige Aufgabenstellung benötigt/benutzt wird/werden soll. Selbst wenn eine solche täglich mehrmals benötigt wird, behaupte ich, daß wahrscheinlich in den allermeisten Fällen wirtschaftlich entscheidend sein dürfte, wie lange man Zeit aufwenden muß bzw. aufgewendet hat, eine brauchbare Lösung zu erstellen.

Manfred könnte sich möglicherweise für Deinen Lösungsvorschlag entscheiden, zuerst möglicherweise nicht aus dem von Dir genannten Grund, sondern weil diese für ihn (wie andere auch) möglicherweise am einfachsten/schnellsten nachvollziehbar erscheinen könnte. Andere Lösungsansätze können aber durchaus für ihn aber auch andere (Nachleser des threads) zumindest von Interesse sein. Meinen Lösungsvorschlag hatte ich u.a. deshalb bereits im Betreff als alternativ bezeichnet.

Gruß Werner
.. , - ...
aus C the unseen

AW: Dein Hinweis ist richtig wie wichtig, nur ...

03.09.2025 20:08:19

daniel

Was genau fehlt denn?

Dass sich das nur in großen Tabellen bemerkbar macht, hätte ich erwähnt.

Es ist, wenn man mehrere Alternativen hat, immer gut zu wissen, wie diese Funktionieren, damit man besser einschätzen kann, wann eine Alternative sinnvollere ist und wann eine andere.

AW: dazu ist hierzu bereits alles relevante geschrieben owT

05.09.2025 10:24:11

neopa C

Gruß Werner
.. , - ...
aus C the unseen

AW: Dynamische Verformelung abhängig vom ausgewählten Monat

02.09.2025 18:57:48

Manfred Will

Wverweis auch bei mehreren Suchkriterien ? Monat und Kategorie

AW: Dynamische Verformelung abhängig vom ausgewählten Monat

02.09.2025 19:54:26

BoskoBiati

Hi,

bei Deiner Version geht vielleicht auch das:

=WENNFEHLER(FILTER($G$3:$G$4;($F$3:$F$4=--C$10)*($D$3:$D$4=$B11));"")

Gruß

Edgar

AW: Dynamische Verformelung abhängig vom ausgewählten Monat

02.09.2025 21:38:36

daniel

Hi

Du hast die Monate in Spalten und die Kategorien in Zeilen.
Also bräuchtest du WVerweis für die Monate und SVerweis für die Kategorie.

Das kombiniert man mit Index + 2* Vergleich:

=INDEX($C$11:$L$12;VERGLEICH(D3;$B$11:$B$12;0);VERGLEICH(F3&"";$C$10:$L$10;0))

Oder man nimmt einen der beiden Verweise und bestimmt den 3. Parameter über den Verweis:

=SVERWEIS(D3;$B$11:$L$12;VERGLEICH(F3&"";$B$10:$L$10;0);0)

=WVERWEIS(F3&"";$C$10:$L$12;VERGLEICH(D3;$B$10:$B$12;0);0)

Gruß Daniel

Dynamische Verformelung abhängig vom ausgewählten Monat

Forumthread: Dynamische Verformelung abhängig vom ausgewählten Monat

16
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Dynamische Verformelung abhängig vom ausgewählten Monat

Forumthread: Dynamische Verformelung abhängig vom ausgewählten Monat

16 Beiträge zum Forumthread Beiträge zu diesem Forumthread

16
Beiträge zum Forumthread

Beiträge zu diesem Forumthread