VBA Formel mit Bezug auf Überschrift anstatt Spalte

Forumthread: VBA Formel mit Bezug auf Überschrift anstatt Spalte
3 Beiträge zu diesem Forumthread
Anzeige

Forumthread: VBA Formel mit Bezug auf Überschrift anstatt Spalte

13.10.2025 21:31:31

Muerte

Hallo,

ist es möglich diese Formel so zu ändern, dass anstelle von "V3" die erste Zelle mit Inhalt in der Spalte mit der Überschrift "Stunden" gesucht wird?
Als Destination soll dann auch die Spalte "Stunden" anstatt G genommen werden. Die Überschriften stehen jeweils in der ersten Zeile:

Sheets("Tabelle1").Range("V3").Copy _
Destination:=Sheets("Berechnung").Cells(Rows.Count, "G").End(xlUp).Offset(1, 0)

Danke!

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: VBA Formel mit Bezug auf Überschrift anstatt Spalte

13.10.2025 22:05:48

xlKing
AW: VBA Formel mit Bezug auf Überschrift anstatt Spalte

14.10.2025 13:53:27

Kuwer
AW: VBA Formel mit Bezug auf Überschrift anstatt Spalte

14.10.2025 15:24:30

daniel

AW: VBA Formel mit Bezug auf Überschrift anstatt Spalte

13.10.2025 22:05:48

xlKing

Klar geht das,

einfach mit Namen. Markiere die jeweilige Spalte ab der Überschrift und wähle aus dem Ribbon Formeln im Bereich Namen "Aus Auswahl erstellen". Es wird im Namensmanager ein neuer Name angelegt der sich (sofern die Überschrift in Zeile 1 ist) auf V2:V... bezieht. Im code gibst du dann anstelle des Bezugs einfach den Namen an.

Sheets("Tabelle1").Range("Stunden").Cells(1).Copy _

Destination:=Sheets("Berechnung").Range("Stunden").Cells(Rows.Count - 1).End(xlUp).Offset(1, 0)

Wenn die Überschrift nicht in Zeile 1 sondern z.B. in Zeile 2 ist, musst du statt Rows.Count - 1 dann eben Rows.Count - 2 machen.

Gruß Mr. K.

AW: VBA Formel mit Bezug auf Überschrift anstatt Spalte

14.10.2025 13:53:27

Kuwer

Hallo,

teste mal damit:

Sub aaa()

  Dim rngQuelle As Range, rngZiel As Range

  Dim strQuelle As String, strZiel As String

  

  strQuelle = "Stunden"

  strZiel = "Stunden"

  

  On Error Resume Next

  With Sheets("Tabelle1")

    Set rngQuelle = .Columns(Application.Match(strQuelle, .Rows(1), 0)).Find(what:="*", LookIn:=xlValues)

  End With

  If Not rngQuelle Is Nothing Then

    If rngQuelle.Row > 1 Then

      With Sheets("Berechnung")

        Set rngZiel = .Cells(.Rows.Count, Application.Match(strZiel, .Rows(1), 0)).End(xlUp).Offset(1, 0)

      End With

      If Not rngZiel Is Nothing Then

        rngQuelle.Copy rngZiel

      End If

    End If

  End If

  On Error GoTo 0

End Sub

Gruß, Uwe

AW: VBA Formel mit Bezug auf Überschrift anstatt Spalte

14.10.2025 15:24:30

daniel

HI

beispielsweise so, gleich mit Fehlerprüfung, ob die Überschriften auch vorhanden sind.

dim Quelle as Range

dim Ziel as range

dim Fehler string



set Quelle = Sheets("Tabelle1").Rows(1).Find(what:="Stunden", lookat:=xlwhole)

set Ziel = Sheets("Berechnung").Rows(1).Find(what:="- Stunden", lookat:=xlwhole)



if Quelle is Nothing then Fehler = Fehler & vblf & "- Spalte ""Stunden"" in Quellblatt nicht vorhanden"

if Ziel is Nothing then Fehler = Fehler & vblf & "- Spalte ""Stunden"" in Zielblatt nicht vorhanden"





if Fehler = "" then

    set Quelle = IIF(Quelle.offset(1, 0).value = "", Quelle.End(xldown), Quelle.Offste(1, 0))

    set Ziel = Ziel.offset(rows.count - Ziel.row, 0).End(xlup).Offset(1, 0)

    Quelle.Copy Destination:=Ziel

Else

    Msgbox "Aktion konnte nicht ausgeführt werden weil:" & Fehler

end if