Diagrammpunkte in unterschiedlichen Farben je nach Wert

19.10.2025 23:57:06

Huahu

Hallo Zusammen,

ist es möglich, die Punkte im Punktdiagramm je nach Wert (siehe Datei) in Tier (Spalte "A) in anderen Farben darzustellen? Bspw. T10 = grün; T11 = rot; T12 = blau
https://www.herber.de/bbs/user/179203.xlsx

Ich habe es leider weder selbst noch mit Gemini hinbekommen.

Viele Grüße

AW: Diagrammpunkte in unterschiedlichen Farben je nach Wert

20.10.2025 01:04:19

Oppawinni

Ja, es ist möglich........
wäre dir als Antwort wohl nicht genug?
Ich denke, dass du dafür eben 3 Datenreihen definieren müsstest. Jeder Datenreihe kannst du dann eine eigene Markierung zuweisen.
Da du aber vermutlich deine Datenreihen auch mal eben umsortieren oder filtern möchtest, ohne dass das die Graphik über den Haufen wirft,
wäre es wahrscheinlich sinnvoll für die Graphikdaten Hilfsspalten anzulegen in die du per Formel jeweils die Daten der Reihen T10, T11 und T12 duplizierst, so dass sich die Inhalte der Reihen beim Umsortieren oder Filtern weiterhin in den richtigen Daten entsprechen. Dazu muss man wissen, dass Zellen die den Wert NV() enthalten in der Graphik unberücksichtigt bleiben.
Das erhöht aber natürlich den Aufwand im Fall von Änderungen. Wenn du also z.B. noch ein T13 usw. ergänzt.

https://www.herber.de/bbs/user/168197.xlsm

AW: Diagrammpunkte in unterschiedlichen Farben je nach Wert

20.10.2025 10:56:22

Onur

Sowas ?
https://www.herber.de/bbs/user/179204.xlsx

AW: So etwa dacht ich mir das auch (owT)

20.10.2025 22:57:30

Oppawinni

gut gemacht, Onur, schaun wir mal, ob da noch was kommt.

AW: Diagrammpunkte in unterschiedlichen Farben je nach Wert

20.10.2025 11:44:27

schauan

Hallöchen,

auch nach dem Prinzip der Aufteilung in mehrere Datenreihen hier mal als Prinzip ein anderes Beispiel, Zuordnung anhand der Werte ... Sollte in Deinem Fall, wie bei mir, mit "" gehen statt mit #NV
https://www.herber.de/bbs/user/179205.xlsx

AW: Diagrammpunkte in unterschiedlichen Farben je nach Wert

20.10.2025 12:08:18

UweD

Hallo

hier eine VBA Möglichkeit

- Rechtsclick auf den Tabellenblattreiter von Diagramnm
- Code anzeigen
- Diesen Code reinkopieren

Private Sub Worksheet_Activate()

    Dim Ws1 As Worksheet

    Dim Ws2 As Worksheet

    Dim Cht As Chart

    Dim S As Series

    Dim i As Long

    Dim Kriterium As String

    

    ' Arbeitsblatt & Diagramm festlegen

    Set Ws1 = Worksheets("Overall")

    Set Ws2 = Worksheets("Diagramm")

    Set Cht = Ws2.ChartObjects(1).Chart

    Set S = Cht.SeriesCollection(1)

    

    ' Schleife über alle Punkte der Datenreihe

    For i = 1 To S.Points.Count

        Kriterium = Ws1.Cells(i + 1, 1).Value ' Spalte A, Zeile i+1 (falls Überschrift in Zeile 1)

        

        ' Farbe abhängig vom Inhalt in Spalte A bestimmen

        Select Case Kriterium

            Case "T10"

                S.Points(i).Format.Fill.ForeColor.RGB = RGB(0, 255, 0)   ' grün

            Case "T11"

                S.Points(i).Format.Fill.ForeColor.RGB = RGB(255, 0, 0) ' rot

            Case "T12"

                S.Points(i).Format.Fill.ForeColor.RGB = RGB(0, 0, 255)   ' llau

        End Select

    Next i

End Sub

- Das Makro startet, wenn du zum Diagrammblatt wechselst

AW: Diagrammpunkte in unterschiedlichen Farben je nach Wert

26.10.2025 13:23:33

Huahu

Vielen lieben Dank an alle :)

Ich werde es mir die Tage mal anschauen und euch Bescheid geben, welche Variante ich umsetze. Aber wie gesagt: Vielen Dank schon mal für euren Einsatz. Dieses Forum war früher der Hammer und ist es immer noch. :D

AW: Diagrammpunkte in unterschiedlichen Farben je nach Wert

20.10.2025 19:50:32

Beverly

Hi,

oder einfach so:

Sub Faerben()

    Dim strFormel As String

    Dim lngPunkt As Long

    With Worksheets("Diagramnm").ChartObjects(1).Chart.SeriesCollection(1) '== Achtung Blattname!!!!

        strFormel = Split(.Formula, ",")(1)

        For lngPunkt = 1 To Range(strFormel).Cells.Count

            Select Case Range(strFormel).Cells(lngPunkt).Offset(0, -1).Value

                Case "T10"

                    .Points(lngPunkt).Format.Fill.ForeColor.RGB = RGB(0, 255, 0) ' grün

                Case "T11"

                    .Points(lngPunkt).Format.Fill.ForeColor.RGB = RGB(255, 0, 0) ' rot

                Case "T12"

                    .Points(lngPunkt).Format.Fill.ForeColor.RGB = RGB(0, 0, 255) ' blau

            End Select

        Next lngPunkt

    End With

End Sub

Makro einfach von Hand ausführen - gleichgültig in welchem Tabellenblatt du dichgerade befindest.

Beachte: dein Blatt mit dem Diagramm heißt Diagramnm!!!

Bis später
Karin

Link zur Homepage: https://excel-inn.de/

AW: Hm...

20.10.2025 22:34:27

Oppawinni

Der TO hat "VBA nein" angegeben insoweit wollte ich VBA eher vermeiden.
Aber nun, ok, der hat aber so schöne Rahmen um die Punktmarkierungen, die da nicht eingefärbt würden.
und das mit dem Namen des Blattes "Diagramnm" wird dann auch irgendwie nicht so recht funktionieren wollen....

Von daher vielleicht so:



Private Sub Worksheet_Activate()

    Dim Ws1 As Worksheet

    Dim Ws2 As Worksheet

    Dim Cht As Chart

    Dim S As Series

    Dim i As Long

    Dim Kriterium As String

    

    ' Arbeitsblatt & Diagramm festlegen

    Set Ws1 = Worksheets("Overall")

    Set Ws2 = ActiveSheet

    Set Cht = Ws2.ChartObjects(1).Chart

    Set S = Cht.SeriesCollection(1)

    

    ' Schleife über alle Punkte der Datenreihe

    For i = 1 To S.Points.Count

        Kriterium = Ws1.Cells(i + 1, 1).Value ' Spalte A, Zeile i+1 (falls Überschrift in Zeile 1)

        

        ' Farbe abhängig vom Inhalt in Spalte A bestimmen

        Select Case Kriterium

            Case "T10"

                S.Points(i).Format.Fill.ForeColor.RGB = vbGreen   ' grün

                S.Points(i).MarkerForegroundColor = vbGreen

            Case "T11"

                S.Points(i).Format.Fill.ForeColor.RGB = vbRed ' rot

                S.Points(i).MarkerForegroundColor = vbRed

            Case "T12"

                S.Points(i).Format.Fill.ForeColor.RGB = vbBlue   ' blau

                S.Points(i).MarkerForegroundColor = vbBlue



        End Select

    Next i

End Sub

Diagrammpunkte in unterschiedlichen Farben je nach Wert

Forumthread: Diagrammpunkte in unterschiedlichen Farben je nach Wert

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Diagrammpunkte in unterschiedlichen Farben je nach Wert

Forumthread: Diagrammpunkte in unterschiedlichen Farben je nach Wert

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread