Löschen ohne zu löschen

Forumthread: Löschen ohne zu löschen

01.11.2025 15:22:20

NicoHendrik

Hallo alle zusammen,
ich habe hier einen Code zusammengebastelt, der so ganz gut funktioniert.
Wenn ich jetzt in C einen Wert manuell lösche, und der MsgBox frägt ob gelöscht werden soll und man dann mit Nein antwortet, soll der Wert in C nicht gelöscht werden.
Kann jemand mir bitte dabei helfen.

Gruß Nico

Private Sub Worksheet_Change(ByVal Target As Range)



'Name und Inhalt loeschen



    Dim rngRange As Range

    On Error GoTo Fin

    Application.EnableEvents = False

    If Not Intersect(Target, Range("C9:C88")) Is Nothing Then

        For Each rngRange In Target

            If Trim(rngRange.Value) = "" Then

          Select Case MsgBox("Achtung! Name wirklich loeschen? Wenn Ja, wird wird der gesamte Inhalt zu den Name geloescht.", vbYesNo Or vbQuestion, "Loeschen")

               Case vbYes

                Cells(rngRange.Row, 13).Resize(1, 368).ClearContents

       End Select

       End If

    Next rngRange

    End If

    

Fin:

    Application.EnableEvents = True

    

End Sub

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Löschen ohne zu löschen

01.11.2025 16:06:10

Uduuh
AW: Löschen ohne zu löschen

01.11.2025 16:21:24

NicoHendrik
AW: Löschen ohne zu löschen

01.11.2025 21:29:24

Yal
AW: Löschen ohne zu löschen

01.11.2025 22:13:11

Daniel
AW: Löschen ohne zu löschen

02.11.2025 08:35:16

NicoHendrik
AW: Löschen ohne zu löschen

02.11.2025 15:20:24

Uduuh
AW: Löschen ohne zu löschen

02.11.2025 16:47:39

NicoHendrik

AW: Löschen ohne zu löschen

01.11.2025 16:06:10

Uduuh

Hallo,
so?

Private Sub Worksheet_Change(ByVal Target As Range)

  

  'Name und Inhalt loeschen

  

  On Error GoTo Fin

  Application.EnableEvents = False

  If Not Intersect(Target, Range("C9:C88")) Is Nothing Then

    If Target.Count = 1 Then  'nur 1 Zelle

      If Trim(Target.Value) = "" Then

        Select Case MsgBox("Achtung! Name wirklich loeschen? Wenn Ja, wird wird der gesamte Inhalt zu den Name geloescht.", vbYesNo Or vbQuestion, "Loeschen")

          Case vbYes

            Cells(Target.Row, 13).Resize(1, 368).ClearContents

          Case Else

            Application.Undo 'rückgängig

        End Select

      End If

    End If

  End If

  

Fin:

  Application.EnableEvents = True

  

End Sub

Gruß aus'm Pott
Udo

AW: Löschen ohne zu löschen

01.11.2025 16:21:24

NicoHendrik

Danke Udo, klappt Prima

Gruß Nico

AW: Löschen ohne zu löschen

01.11.2025 21:29:24

Yal

Guten Abend zusammen,

darauf achten, dass durch den

If Target.Count = 1 Then

der Code die Löschung nicht verhindert, wenn mehrere Zellen gleichzeitig gelöscht werden...

VG
Yal

AW: Löschen ohne zu löschen

01.11.2025 22:13:11

Daniel

Die Frage an Nico wäre, was passieren soll, wenn mehrere Namen gleichzeitig gelöscht werden.
a) gar nicht fragen und löschen
b) einmal für die ganze Aktion fragen
c) für jeden Namen einzeln fragen
d) komplett abbrechen und alte Namen wieder herstellen
e) Zellen leeren, aber Nachbarzellen nicht bearbeiten

AW: Löschen ohne zu löschen

02.11.2025 08:35:16

NicoHendrik

Guten Morgen Daniel,

b) einmal für die ganze Aktion fragen

Gru? Nico

AW: Löschen ohne zu löschen

02.11.2025 15:20:24

Uduuh

Hallo,

Private Sub Worksheet_Change(ByVal Target As Range)

  

  'Name und Inhalt loeschen

  Dim rngZelle As Range

  Application.EnableEvents = False

  Application.ScreenUpdating = False

  

  If Target.Column = 3 And Target.Columns.Count = 1 Then 'Markierung nur in C

    If Not Intersect(Target, Range("C9:C88")) Is Nothing Then

      If Application.CountA(Target) = 0 Then  'alle leer

        Select Case MsgBox("Achtung! Name wirklich loeschen?" _

            & "Wenn Ja, wird wird der gesamte Inhalt zu dem Namen geloescht.", vbYesNo Or vbQuestion, "Loeschen")

          Case vbYes

            For Each rngZelle In Target

              rngZelle.Offset(, 10).Resize(1, 368).ClearContents

            Next rngZelle

          Case Else

            Application.Undo 'rückgängig

        End Select

      End If

    End If

  End If

  

  Application.EnableEvents = True

  

End Sub

Gruß aus'm Pott
Udo

AW: Löschen ohne zu löschen

02.11.2025 16:47:39

NicoHendrik

Danke Udo,

Grüsse aus den hohen Norden
Nico

Forumthread: Löschen ohne zu löschen

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread