Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 05:27:25

JederMann

Guten Morgen zusammen,

ich sitze vor einer Herausforderung bei folgender Tabelle:

Userbild

Folgenden Aufbau hat die Tabelle:

In den Zellen A2:A4 stehen die Anmeldedaten als Datum formatiert (TT.MM.JJJJ).

In den Zellen B2:B4 stehen die Eintrittsdaten (Kursbeginn) als Datum formatiert (TT.MM.JJJJ).

In den Zellen C2:C4 stehen die Austrittsdaten (Kursende) als Datum formatiert (TT.MM.JJJJ).

In den Zellen D1:I1 stehen Datumsangaben (z. B. 01.06.2025) als Datum formatiert (MM/JJJJ).

Nun sollen im Bereich D2:I4 mit kopierfähiger Formel folgende Buchstaben erscheinen:

"-": Der Teilnehmende hat sich in diesem Monat noch nicht angemeldet oder der Kurs ist in diesem Monat bereits vorbei.

"A": Der Teilnehmende hat sich in diesem Monat bereits angemeldet, aber der Kurs hat in diesem Monat noch nicht begonnen.

"S": Der Kurs findet in diesem/diesen Monat(en) statt.

Vielen Dank für Eure Hilfe und Unterstützung.
JederMann

AW: ... logisch operieren ...

17.12.2025 08:23:52

schauan

... müsste man(n) ergründen ...
Schaue Dir WENN, UND, ODER, und ein paar Operatorren wie GRÖßER, KLEINER, GLEICH an ...

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 11:40:44

Alwin Weisangler

Hallo JederMann,

in Zelle D1:

=LET(xA;3;xB;DATUM(JAHR(MIN(A1:A100));MONAT(MIN(A1:A100));1);xC;DATUM(JAHR(MAX(C1:C100));MONAT(MIN(C1:C100));1);EDATUM(xB; SEQUENZ(1; MONAT(xC)-MONAT(xB)+xA; 0; 1)))

in Zelle D2 runter und rüberziehen:

=WENNNV(WENNS(UND(MONAT($A2)=MONAT(D$1);MONAT($B2)>MONAT(D$1));"A";UND(MONAT($B2)=MONAT(D$1);MONAT($C2)>=MONAT(D$1));"S");"-")

Hinweis: Die Anzahl der auszuwertenden Zeilen fürs monatliche Sequenzieren kannst du selbst anpassen.

Gruß Uwe

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 12:07:55

JederMann

Hallo Uwe,

vielen Dank für die interessante Antwort. Meine ersten Ansätze waren tatsächlich wie schauan schreibt mit WENN, UND, ODER sowie ">=" und "", aber sie funktionierten nur in einer Zelle und nicht als kopierfähige Formel. Dein Ansatz funktioniert supert. Die einzige Frage, die sich mir stellt:

Wenn ich Deine Antwort in die Zellen D1 sowie D2:D4 einfüge, dann steht in den Zellen mit der Formel "#ÜBERLAUF!". Was hat das zu bedeuten. Habe ich die Formel falsch eingefügt?

Vielen Dank und viele Grüße
JederMann

AW: ... an der richtigen Stelle ein paar Dollar ausgeben ...

17.12.2025 13:23:43

schauan

... und es klappt:

Also, das stimmt nicht ....
mit WENN, UND, ODER sowie ">=" und "", aber sie funktionierten nur in einer Zelle und nicht als kopierfähige Formel

schaue Dir das an:

=WENN(ODER(MONAT(D$1)=MONAT($B2);MONAT(D$1)=MONAT($C2));"S";WENN(UND(MONAT(D$1)>=MONAT($A2);MONAT(D$1)=MONAT($C2));"A";"-"))

Voraussetzung - auch in einigen anderen Antworten - in Zeile 1 stehen Daten und keine "verdrehten Zahlen" ... Davon gehe ich aus, Du wolltest ja "ziehen" ;-)

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 12:12:38

Alwin Weisangler

oder ein einem Rutsch alles. In Zelle D1:


=LET(xA; 3;xAnm; A2:A100;xEin; B2:B100;xAus; C2:C100;xLz; MAX(WENN((xAnm>"")+(xEin>"")+(xAus>""); ZEILE(xAnm)-ZEILE(A2)+1));xB; DATUM(JAHR(MIN(xAnm)); MONAT(MIN(xAnm)); 1);xC; DATUM(JAHR(MAX(xAus)); MONAT(MAX(xAus)); 1);xMon; EDATUM(xB; SEQUENZ(1; MONAT(xC)-MONAT(xB)+xA; 0; 1));xSp; SPALTEN(xMon);xD; xMon;xRowIndex; SEQUENZ(xLz; 1; 1; 1);xMatrix;MATRIXERSTELLEN(xLz;xSp;LAMBDA(pI;pJ;LET(a; INDEX(xAnm; pI);b; INDEX(xEin; pI);d; INDEX(xAus; pI);m; INDEX(xMon; pJ);WENNNV(WENNS(UND(MONAT(a) = MONAT(m); MONAT(b) >  MONAT(m)); "A";UND(MONAT(b) =  MONAT(m); MONAT(d) >= MONAT(m)); "S");"-"))));VSTAPELN(xD; xMatrix))

Das kann man noch als benutzerdefinierte Formel in den den Namanesmanager packen.
In den Namenmanager:
Name: TeilnahmeAuswerten
Formel:


=LAMBDA(AnzahlÜberhang;SpalteAnmeldung;SpalteEintritt;SpalteAustritt;LET(xLz; MAX(WENN((SpalteAnmeldung>"")+(SpalteEintritt>"")+(SpalteAustritt>""); ZEILE(SpalteAnmeldung)-ZEILE(Tabelle1!A2)+1));xB; DATUM(JAHR(MIN(SpalteAnmeldung)); MONAT(MIN(SpalteAnmeldung)); 1);xC; DATUM(JAHR(MAX(SpalteAustritt)); MONAT(MAX(SpalteAustritt)); 1);xMon; EDATUM(xB; SEQUENZ(1; MONAT(xC)-MONAT(xB)+AnzahlÜberhang; 0; 1));xSp; SPALTEN(xMon);xD; xMon;xRowIndex; SEQUENZ(xLz; 1; 1; 1);xMatrix;MATRIXERSTELLEN(xLz;xSp;LAMBDA(pI;pJ;LET(a; INDEX(SpalteAnmeldung; pI);b; INDEX(SpalteEintritt; pI);d; INDEX(SpalteAustritt; pI);m; INDEX(xMon; pJ);WENNNV(WENNS(UND(MONAT(a) = MONAT(m); MONAT(b) >  MONAT(m)); "A";UND(MONAT(b) =  MONAT(m); MONAT(d) >= MONAT(m)); "S");"-"))));VSTAPELN(xD; xMatrix)))

In Zelle D1:

=TeilnahmeAuswerten(3;A2:A4;B2:B4;C2:C4)

Gruß Uwe

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 12:52:08

JederMann

Auch das ist eine starke Antwort. Vielen Dank auch Dir!

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 13:19:26

Alwin Weisangler

Das was ich dir gezeigt habe spillt (breitet sich aus) so, wie die Einträge in Spalte A bis C vorhanden sind.
Da braucht es keinerlei weitere Eingriffe in der Tabelle. Einzig die Formel muss bis zur letzten Zeile erweitert werden.

Man kann auch dies noch automatisieren, aber mit Blick auf die Perfomance habe ich dies nicht eingebaut.

Gruß Uwe

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 13:24:39

JederMann

Ah, das war mir nicht bewusst. Danke für die Ergänzung. Das Einzige, was ich bei Deiner Lösung nicht hinbekommen habe, dass bei Änderung des Austrittsdatums nach hinten z. B. 15.10.2025 auch das "S" eine Spalte weiter nach hinten mitgeht.

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 13:44:58

schauan

Hallöchen,

schaue mal nach den Bedingungen, wie S eingetragen wird:
UND(MONAT(b) = MONAT(m); MONAT(d) >= MONAT(m)); "S")
besser wäre:
UND(MONAT(b) = MONAT(m); MONAT(d) >= MONAT(m)); "S")

Bei meiner WENN habe ich auch nur zwei Monate berücksichtigt. Wen ein Lehrgang auch 3 Monate gehen kann, dann
ODER(MONAT(D$1)>=MONAT($B2);MONAT(D$1)=MONAT($C2))

Ein Jahreswechsel wird übrigens nur bei Sigi berücksichtigt, wenn ich nichts übersehen habe :-(

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 14:24:13

Alwin Weisangler

Hallo Miteinander,

das stimmt. An beide Sachen hatte ich nicht gedacht. Ist aber kein Problem. Da waren nur kleine Anpassungen erforderlich. Ich hoffe, dass ich alle Erforderlichkeiten nun erwischt habe.

Formel für Namensmanager:


=LAMBDA(AnzahlÜberhang;SpalteAnmeldung;SpalteEintritt;SpalteAustritt;LET(xLz; MAX(WENN((SpalteAnmeldung>"")+(SpalteEintritt>"")+(SpalteAustritt>""); ZEILE(SpalteAnmeldung)-ZEILE(Tabelle1!A9)+1));xB; DATUM(JAHR(MIN(SpalteAnmeldung)); MONAT(MIN(SpalteAnmeldung)); 1);xC; DATUM(JAHR(MAX(SpalteAustritt)); MONAT(MAX(SpalteAustritt)); 1);xMon;EDATUM(xB;SEQUENZ(1;(JAHR(xC)-JAHR(xB))*12 + (MONAT(xC)-MONAT(xB)) + AnzahlÜberhang;0;1));xSp; SPALTEN(xMon);xD; xMon;xMatrix;MATRIXERSTELLEN(xLz;xSp;LAMBDA(r;c;LET(a; INDEX(SpalteAnmeldung; r);b; INDEX(SpalteEintritt; r);d; INDEX(SpalteAustritt; r);m; INDEX(xMon; c);WENNNV(WENNS(UND(a = MONATSENDE(m;0); b > MONATSENDE(m;0)); "A";UND(b = MONATSENDE(m;0); d >= m); "S");"-"))));VSTAPELN(xD; xMatrix)))

Aufruf in Zelle:

=TeilnahmeAuswerten(3;A2:A100;B2:B100;C2:C100)

oder Formel für Zelle:


=LET(xA;3;xAnm;A2:A100;xEin;B2:B100;xAus;C2:C100;xLz;MAX(WENN((xAnm>"")+(xEin>"")+(xAus>"");ZEILE(xAnm)-ZEILE(A2)+1));xB;DATUM(JAHR(MIN(xAnm));MONAT(MIN(xAnm));1);xC;DATUM(JAHR(MAX(xAus));MONAT(MAX(xAus));1);xMon;EDATUM(xB;SEQUENZ(1;(JAHR(xC)-JAHR(xB))*12 + (MONAT(xC)-MONAT(xB)) + xA;0;1));xSp;SPALTEN(xMon);xD;xMon;xMatrix;MATRIXERSTELLEN(xLz;xSp;LAMBDA(r;c;LET(a;INDEX(xAnm; r);b;INDEX(xEin; r);d;INDEX(xAus; r);m;INDEX(xMon; c);WENNNV(WENNS(UND(a = MONATSENDE(m;0); b > MONATSENDE(m;0)); "A";UND(b = MONATSENDE(m;0); d >= m); "S");"-"))));VSTAPELN(xD; xMatrix))

https://www.herber.de/bbs/user/179859.xlsx

Gruß Uwe

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 18:05:24

JederMann

Vielen Dank für Deine Hilfe und Unterstüzung, Uwe!

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 20:27:58

JederMann

Uwe, ich muss nochmal meine Begeisterung für Deine Lösung ausdrücken. Ich habe diese gerade einmal selbst nachgebaut und bin schwer beeindruckt. Vor allem bin ich begeistert, dass kein "Ziehen" der Formeln in die weiteren Zellen erforderlich ist, die Monatsrange sich automatisch anpasst und wirklich nur dort Formeln stehen, wo sie gebraucht werden. Vielen, herzlichen Dank nochmal an dieser Stelle!

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 22:34:55

Alwin Weisangler

Gerne!

Gruß Uwe

AW: ODER ein UND ...

17.12.2025 13:47:27

schauan

... bei mir müsste dann noch aus dem ODER ein UND gemacht werden ...

AW: ODER ein UND ...

17.12.2025 14:00:24

JederMann

Danke auch Dir, schauan!

AW: WENN UND so geht's über den Jahreswechsel...

17.12.2025 14:00:26

schauan

=WENN(UND((D$1>MONATSENDE($B2;-1));(D$1)=($C2));"S";WENN(UND(MONATSENDE(D$1;0)>=MONATSENDE($A2;0);MONATSENDE(D$1;0)=MONATSENDE($C2;0));"A";"-"))

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 12:00:21

UweD

Hallo

Bei deiner Excel-Version wäre =Wenns(Test1; Wert1Wahr; Test2; Wert2Wahr; ...) geeignet

Formuliere mal deine ProsaBedingungen in mathematische Aussagen

So in der Art
- Der Teilnehmende hat sich in diesem Monat noch nicht angemeldet $A2&GT D$1
- der Kurs hat in diesem Monat noch nicht begonnen. Monat/Jahr von $A2&lt Monat/Jahr $B2

usw.

Die kannst du dann entsprechend in der Formel verwenden

LG UweD

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 12:04:55

Sigi.21

Hallo Jedermann,

mit Lambda-Fkt. (s. Mappe)
https://www.herber.de/bbs/user/179854.xlsx

Gruß Sigi

Im Anhang ist...

17.12.2025 14:40:28

Case

Moin, :-)

... eine mögliche Lösung mit Power Query: ;-)
https://www.herber.de/bbs/user/179860.xlsx

Informationen zu Power Query: ;-)
https://excelhero.de/power-query/power-query-ganz-einfach-erklaert/

Servus
Case

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 18:46:58

daniel

Hi
als Formel zum klassischen Ziehen (Formel in erste Zelle Eintragen und in die restlichen kopieren)so:

in D2:

=LET(

Ein;MONATSENDE($B2;0);

Aus;MONATSENDE($C2;0);

Anm;MONATSENDE($A2;0);

Dat;MONATSENDE(D$1;0);

WENN(ODER(Dat&ltAnm;Dat&gtAus);"---";WENN(Dat>=Ein;"S";"A")))

oder auch ohne LET

=WENN(ODER(MONATSENDE(D$1;0)MONATSENDE($C2;0));"---";WENN(MONATSENDE(D$1;0)>=MONATSENDE($B2;0);"S";"A"))

oder nach eine anderen Methode, ohne WENN

=LET(

a;HSTAPELN(0;MONATSENDE($A2;0);MONATSENDE($B2;0);MONATSENDE($C2;1));

b;HSTAPELN("---";"A";"S";"---");

XVERWEIS(MONATSENDE(D$1;0);a;b;;-1;2))

Gruß Daniel

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 20:21:58

JederMann

Vielen Dank auch für Deine Antwort, Daniel.

AW: Im Anhang ist...

17.12.2025 18:07:11

JederMann

Klasse, auch Dir Case danke für Deine Hilfe und Unterstützung. Das muss ich mir ansehen!

Nachfolgend noch...

17.12.2025 18:30:24

Case

Moin, :-)

... zwei Möglichkeiten mit Power Query - einmal in einer anderen Ausgabeform und einmal mit Pivot-Table-Bericht-Ausgabe. ;-)
https://www.herber.de/bbs/user/179866.xlsx

Servus
Case

AW: Nachfolgend noch...

17.12.2025 18:42:55

JederMann

Genial. Vielen Dank. Du motivierst mich, mir PowerQuery anzueignen. Ich habe schon mit den ersten drei Videos von excelhero begonnen.

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 12:13:33

JederMann

Hallo Sigi,

vielen Dank. Wow, das ist ja cool. Ich versuche die Mappe einmal nachzubauen und zu verstehen, dann melde ich mich zurück.

Viele Grüße
JederMann

AW: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

17.12.2025 12:50:42

JederMann

Deine Lösung beeindruckt mich wirklich. Vielen Dank. Sie funktioniert super.

Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

Forumthread: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

26
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

Forumthread: Prüfen, ob ein Datum innerhalb eines Datumsbereichs liegt

26 Beiträge zum Forumthread Beiträge zu diesem Forumthread

26
Beiträge zum Forumthread

Beiträge zu diesem Forumthread