Tabelle Spaltennamen finden

Forumthread: Tabelle Spaltennamen finden

21.12.2025 19:24:54

Ole

Hallo,

ich habe eine Tabelle erstellt, in der ich Namen, Datum und Schichten eingetragen habe. Nun möchte ich eine bestimmte Schicht suchen und den Mitarbeiter, welche diese an einem bestimmten Tag hat. Leider finde ich die Lösung nicht mit Index und Vergleich und komme nicht weiter. Könnt Ihr mir bitte helfen? Gruß Ole

https://www.herber.de/bbs/user/179895.xlsx

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Tabelle Spaltennamen finden

21.12.2025 19:43:18

BoskoBiati
Da ich gerade dran war

21.12.2025 19:46:33

RPP63
AW: Tabelle Spaltennamen finden

21.12.2025 20:01:14

Alwin Weisangler
Als Zusammenfassung …

21.12.2025 20:33:06

RPP63
AW: Tabelle Spaltennamen finden

21.12.2025 21:17:10

snb
Es würde auch...

22.12.2025 11:34:22

Case
Dann lieber der XVERWEIS()

21.12.2025 20:08:14

RPP63
AW: Tabelle Spaltennamen finden

21.12.2025 20:38:25

Alwin Weisangler
AW: Tabelle Spaltennamen finden

21.12.2025 20:51:48

BoskoBiati
AW: Da ich gerade dran war

21.12.2025 19:49:56

Ole

AW: Tabelle Spaltennamen finden

21.12.2025 19:43:18

BoskoBiati

Hi,

eine Möglichkeit:

=INDEX(B1:E1;VERGLEICH(H3;INDEX(B3:.E20000;VERGLEICH(G3;A3:.A20000;0););0))

Gruß

Edgar

Da ich gerade dran war

21.12.2025 19:46:33

RPP63

Moin!

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
1		Torsten	Ingo	Ralf	Jens		Datum	Schicht	Name
2
3	01.01.2026	Schicht 1	Schicht 2	Schicht 3	Schicht 4		04.01.2026	Schicht 2	Ralf
4	02.01.2026	Schicht 2	Schicht 3	Schicht 4	Schicht 1
5	03.01.2026	Schicht 3	Schicht 4	Schicht 1	Schicht 2
6	04.01.2026	Schicht 4	Schicht 1	Schicht 2	Schicht 3
7	05.01.2026	Schicht 1	Schicht 2	Schicht 3	Schicht 4

Zelle	Formel
I3	=INDEX(B1:E1;VERGLEICH(H3;FILTER(B3:E33;A3:A33=G3);0))

Gruß Ralf

AW: Tabelle Spaltennamen finden

21.12.2025 20:01:14

Alwin Weisangler

Hallo,

noch eine weitere Möglichkeit von Vielen:


=LET(xA;FILTER(B3:E33;A3:A33=G3;"");xB;B1:E1;xC;XVERGLEICH(H3;xA;0);INDEX(xB;;xC))

Gruß Uwe

Als Zusammenfassung …

21.12.2025 20:33:06

RPP63

… denn bekanntlich führen viele Wege nach Rom.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
1		Torsten	Ingo	Ralf	Jens		Datum	Schicht	Name
2
3	01.01.2026	Schicht_1	Schicht_2	Schicht_3	Schicht_4		04.01.2026	Schicht_2	Ralf
4	02.01.2026	Schicht_2	Schicht_3	Schicht_4	Schicht_1				Ralf
5	03.01.2026	Schicht_3	Schicht_4	Schicht_1	Schicht_2				Ralf
6	04.01.2026	Schicht_4	Schicht_1	Schicht_2	Schicht_3				Ralf
7	05.01.2026	Schicht_1	Schicht_2	Schicht_3	Schicht_4

Zelle	Formel
I3	=INDEX(B1:E1;VERGLEICH(H3;FILTER(B3:E33;A3:A33=G3);0))
I4	=INDEX(B1:E1;VERGLEICH(H3;INDEX(B3:E33;VERGLEICH(G3;A3:A33;0););0))
I5	=XVERWEIS(H3;FILTER(B3:E33;A3:A33=G3);B1:E1)
I6	=LET(xA;FILTER(B3:E33;A3:A33=G3;"");xB;B1:E1;xC;XVERGLEICH(H3;xA;0);INDEX(xB;;xC))

AW: Tabelle Spaltennamen finden

21.12.2025 21:17:10

snb

Verwende:
- nur 3 Spalten: Datum Name Schicht
- ein Pivottable (hat MS selbst erfunden) : keine Förmel, kein VBA kein PQ, kein Let usw.

Es würde auch...

22.12.2025 11:34:22

Case

Moin, :-)

... mit dem von dir vorgegebenen Tabellen-Layout mit Pivot gehen: ;-)
Userbild

Daten in Power Query laden. ;-)
Datumspalte markieren - Transformieren - Spalten entpivotieren - Andere Spalten entpivotieren. ;-)
Start - Schließen & laden - Schließen und laden in... als PivotTable-Bericht - ins aktuelle Tabellenblatt. ;-)
Nur Name in Zeilen. ;-)
Dann Zeitachse für Datum hinzufügen und Datenschnitt für Schicht. ;-)

Dann eine Schicht auswählen, oder mehrere - das gleiche in der Zeitachse. ;-)
Userbild

Servus
Case

Dann lieber der XVERWEIS()

21.12.2025 20:08:14

RPP63

Dann aber gleich der XVERWEIS() ohne LET(), weil einfach:

=XVERWEIS(H3;FILTER(B3:E33;A3:A33=G3);B1:E1)

;-)

AW: Tabelle Spaltennamen finden

21.12.2025 20:38:25

Alwin Weisangler

noch einmal als kleine Trainingsformel (funktioniert, ist aber nicht ernst gemeint):


=LET(xA; FILTER(B3:E33; A3:A33 = G3; "");

    xB; B1:E1;

    xC; H3;

    xD;REDUCE(""; SEQUENZ(1; SPALTEN(xA));LAMBDA(i;j;WENN(i > "";i;WENN(INDEX(xA;1;j) = xC; j; ""))));INDEX(xB;; xD))

Mal via Schleifendurchlauf und Trefferausgabe.

Gruß Uwe

AW: Tabelle Spaltennamen finden

21.12.2025 20:51:48

BoskoBiati

Hi,

dann hätte ich auch noch was:

=LET(xa;VERGLEICH(G3;A.:.A;0);XVERWEIS(H3;INDEX(B3:.E20000;xa;);$B$1:$E$1;"n.v";0))

=XVERWEIS(H3;INDEX(B3:.E20000;VERGLEICH(G3;A3:.A20000;0););B1:E1;"n.v.";0)

Gruß

Edgar

AW: Da ich gerade dran war

21.12.2025 19:49:56

Ole

Hallo Ralf und Edgar,

vielen Dank für die schnelle Hilfe. Es funktioniert einwandfrei. Schöne Feiertage

Gruß Ole

Forumthread: Tabelle Spaltennamen finden

10 Beiträge zum Forumthread Beiträge zu diesem Forumthread

10
Beiträge zum Forumthread

Beiträge zu diesem Forumthread