Tabelle umformen für Serienbrief

Forumthread: Tabelle umformen für Serienbrief
5 Beiträge zu diesem Forumthread
Anzeige

Forumthread: Tabelle umformen für Serienbrief

30.12.2025 09:49:31

Simon

Hallo,
ich habe eine Tabelle mit 2 Spalten. In Spalte A steht der Verkaufsberater und in Spalte B der Kunde die ein Produkt gekauft haben.
Ich bräuchte jetzt eine Tabelle für einen Serienbrief, sprich in Spalte A steht der Verkaufsberater und in den folgenden Spalten die Kunden.
Anbei eine Beispieldatei:
https://www.herber.de/bbs/user/179926.xlsx
Danke schon vorab für eure Unterstützung

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Tabelle umformen für Serienbrief

30.12.2025 10:23:33

Alwin Weisangler
Falls du mit...

30.12.2025 11:34:31

Case
AW: Tabelle umformen für Serienbrief

30.12.2025 15:24:02

Simon
Mal bewusst einfach

31.12.2025 07:02:17

RPP63
AW: Tabelle umformen für Serienbrief

30.12.2025 10:46:27

Alwin Weisangler

AW: Tabelle umformen für Serienbrief

30.12.2025 10:23:33

Alwin Weisangler

Hallo Simon,


=LET(xA;EINDEUTIG(A4:A12);xB;MAX(ZÄHLENWENN(A4:A12; xA));MATRIXERSTELLEN(ANZAHL2(xA);xB+1;LAMBDA(i;j;WENN(j=1;INDEX(xA; i);WENNFEHLER(INDEX(FILTER(B4:B12; A4:A12=INDEX(xA; i); "");j-1);"")))))

Gruß Uwe

Falls du mit...

30.12.2025 11:34:31

Case

Moin Simon, :-)

... "inteligenter Tabelle" arbeitest, dann wäre auch Power Query eine Möglichkeit: ;-)
https://www.herber.de/bbs/user/179928.xlsx

Informationen dazu: ;-)
https://excelhero.de/excel-tabellen/excel-tabelle-erstellen/
https://excelhero.de/power-query/power-query-ganz-einfach-erklaert/

Servus
Case

AW: Tabelle umformen für Serienbrief

30.12.2025 15:24:02

Simon

Danke für die interessanten Lösungen, die muss ich mir mal genauer ansehen!

Mal bewusst einfach

31.12.2025 07:02:17

RPP63

Moin!
Eine schlanke Version mit NACHZEILE() habe ich noch nicht hinbekommen.
Aber es geht ja auch mit zwei Formeln:
Erstelle die Liste der Verkäufer mittels
A16: =EINDEUTIG(A4:A12)
In B16: =MTRANS(FILTER(B$4:B$12;A$4:A$12=A16))
B16 ziehst Du soweit wie nötig herunter.

	A	B	C	D	E
3	Verkaufsberater	Kunde
4	Müller	Kunde1
5	Müller	Kunde2
6	Müller	Kunde3
7	Müller	Kunde4
8	Meyer	Kunde 5
9	Meyer	Kunde 6
10	Schulz	Kunde 7
11	Schulz	Kunde 8
12	Schulz	Kunde 9
13
14
15	Zieldatei für Serienbrief
16	Müller	Kunde1	Kunde2	Kunde3	Kunde4
17	Meyer	Kunde 5	Kunde 6
18	Schulz	Kunde 7	Kunde 8	Kunde 9

Zelle	Formel
A16	=EINDEUTIG(A4:A12)
B16	=MTRANS(FILTER(B$4:B$12;A$4:A$12=A16))

Gruß Ralf

AW: Tabelle umformen für Serienbrief

30.12.2025 10:46:27

Alwin Weisangler

Nun habe ich das mal ein bisschen aufgeräumt.

Zellformel:

=LET(xA;A4:A12;xB;B4:B12;xC;EINDEUTIG(xA);xD;MAX(ZÄHLENWENN(xA;xC));MATRIXERSTELLEN(ANZAHL2(xC);xD+1;LAMBDA(i;j; WENN(j=1;INDEX(xC; i);WENNFEHLER(INDEX(FILTER(xB;xA=INDEX(xC;i);"");j-1);"")))))

oder besser als benutzerdefinierte Formel im Namensmanager:
Name: KundenZuweisen
Formel:

=LAMBDA(Berater;Kunden;LET(xC;EINDEUTIG(Berater);xD;MAX(ZÄHLENWENN(Berater;xC));MATRIXERSTELLEN(ANZAHL2(xC);xD+1;LAMBDA(i;j;WENN(j=1;INDEX(xC; i);WENNFEHLER(INDEX(FILTER(Kunden; Berater=INDEX(xC;i);"");j-1);""))))))

Aufruf in Zelle: