HERBERS

Excel-Forum (Archiv)

20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender

Rückwärts Blättern

Aktuelles Verzeichnis

Übersicht Verzeichnisse

Nächster Thread

Vorwärts blättern

Inhaltsverzeichnis

Feiertage ausschliessen

Forumthread: Feiertage ausschliessen
24 Beiträge zu diesem Forumthread
Anzeige

Forumthread: Feiertage ausschliessen

02.02.2026 11:59:49

Norman

Hallo zusammen,

ich habe versucht mir einen Fristrechner zu bauen. Das funktioniert soweit auch ganz gut. Wenn das Ende auf einen Samstag oder Sonntag fällt, wird der nächste Werktag genommen.
Die Formel steht in c4.
Gibt es eine Möglichkeit, dass auch so bei Feiertagen zu machen? Also wenn das "Zahldatum" auf einen Feiertag fällt, dass dann der nächste Werktag genommen wird?
Beispieldatei:

https://www.herber.de/bbs/user/180139.xlsx

Vielen Dank schonmal!

Norman

24
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Feiertage ausschliessen

02.02.2026 12:08:30

Sigi.21
AW: Feiertage ausschliessen

02.02.2026 12:44:12

Norman
AW: Feiertage ausschliessen

02.02.2026 12:53:25

Sigi.21
AW: Feiertage ausschliessen

02.02.2026 13:12:20

Norman
AW: Feiertage ausschliessen

02.02.2026 14:00:29

Norman
AW: Feiertage ausschliessen

02.02.2026 16:40:20

Sigi.21
AW: Feiertage ausschliessen

03.02.2026 07:17:44

Norman
AW: Feiertage ausschliessen

03.02.2026 09:25:58

Sigi.21
AW: Feiertage ausschliessen

03.02.2026 09:45:59

Norman
AW: Feiertage ausschliessen

03.02.2026 10:50:31

Luschi
AW: Feiertage ausschliessen

03.02.2026 11:08:13

Norman
AW: Feiertage ausschliessen

03.02.2026 11:47:28

Alwin Weisangler
AW: Feiertage ausschliessen

03.02.2026 12:03:05

Norman
AW: Feiertage ausschliessen

02.02.2026 12:13:09

Alwin Weisangler
AW: Feiertage ausschliessen

02.02.2026 14:16:27

Edi
AW: Feiertage ausschliessen

02.02.2026 17:16:48

daniel
AW: Feiertage ausschliessen

02.02.2026 20:18:58

Yal
AW: Feiertage ausschliessen

03.02.2026 13:10:45

daniel
AW: Feiertage ausschliessen

02.02.2026 22:34:37

BoskoBiati
AW: Feiertage ausschliessen

02.02.2026 14:43:03

Norman
AW: Feiertage ausschliessen

02.02.2026 14:51:13

Edi
AW: Feiertage ausschliessen

03.02.2026 07:08:06

Norman
AW: Feiertage ausschliessen

02.02.2026 12:47:07

Norman
AW: Feiertage ausschliessen

02.02.2026 13:45:58

Alwin Weisangler

AW: Feiertage ausschliessen

02.02.2026 12:08:30

Sigi.21

Hallo Normann,

sieh' dir mal die Funktion ARBEITSTAG.INTL() an. Damit geht das.

Gruß Sigi

AW: Feiertage ausschliessen

02.02.2026 12:44:12

Norman

Hi Sigi

lässt Arbeitstag.intl nicht die Wochenenden raus?

AW: Feiertage ausschliessen

02.02.2026 12:53:25

Sigi.21

Hallo Norman,

ja bzw. jein. Kommt drauf an, wie du das anwendest.
Du willst alle Tage bei der Frist haben, nur das Ziel soll nicht WoEnde oder FT sein?
https://www.herber.de/bbs/user/180141.xlsx
Dann, s. Mappe.

Gruß Sigi

AW: Feiertage ausschliessen

02.02.2026 13:12:20

Norman

Servus,
diese Formel ist genial. Alles funktioniert.

VIELEN DANK und noch eine schöne Woche!

Norman

AW: Feiertage ausschliessen

02.02.2026 14:00:29

Norman

Hallo Sigi,

Funktioniert leider doch nicht ganz. Wenn ich bei 14 Tagen den 27.01.2026 eingebe müsste eigentlich der 09.02.2026 rauskommen. Als Ergebnis kommt auch 4062 raus.
Was im Datumsformat der 09.02.2026 wäre. aber bei der Formel kommt leider der 10.02.2026 raus.

AW: Feiertage ausschliessen

02.02.2026 16:40:20

Sigi.21

Hallo Norman,

also: 27.01.2026 + 14 Tage ergibt doch den 10.02.2026. Das ist ganz korrekt nach Excel-Logik!
Wenn das bei dir anders sein soll, dann musst du mal GENAU erklären, was oder wie du das willst.

Gruß Sigi

AW: Feiertage ausschliessen

03.02.2026 07:17:44

Norman

Guten Morgen Sigi,

"also: 27.01.2026 + 14 Tage ergibt doch den 10.02.2026" - das stimmt schon, aber in der Formel ist schon beim Ausgangsdatum "-1"
Deswegen verstehe ich auch nicht das Ergebnis.
Das müsste eigentlich der 09.02.2026 sein.

Der 27.01.2026 wird in diesem Fall mitgezählt (Beginnfrist).

Beispiel hier:
https://www.smart-rechner.de/fristen/rechner.php

Liebe Grüße
Norman

AW: Feiertage ausschliessen

03.02.2026 09:25:58

Sigi.21

Hallo Norman,

also inklusive dem Ausgangsdatum. Dann alle Tage, lediglich das Fristende muss(!) ein Arbeitstag sein. Falls WoE, dann nächster ArbTag.
Eine genaue Beschreibung von Anfang an, hätte das ganze Hin und Her erspart. (s. Mappe, Formel und Lambda-Fkt.)

https://www.herber.de/bbs/user/180146.xlsx
Gruß Sigi

AW: Feiertage ausschliessen

03.02.2026 09:45:59

Norman

Hallo Sigi,

vielen Dank, das sieht super aus.
Die Formel bei "Ziel" funktioniert jetzt.
Nur kurze Info: die freien Tage hatten sich bei dir durch das kopieren verschoben.

Nochmal vielen Dank und sorry wegen dem Hin und Her :-)

Schönen Tag
Norman

AW: Feiertage ausschliessen

03.02.2026 10:50:31

Luschi

Hallo Norman,

vielen Dank, das sieht super aus.

Also bei dieser Formel im Beispiel von Sigi sieht überhaupt nix super aus: =WENN(B3>0; ARBEITSTAG.INTL((A3+B3-1)-1; 1; 1; J3:J15); "-" )
Bei mir sieht das so aus: =WENN(B3>0;ARBEITSTAG.INTL(A3;B3; 1; 1; $J$3:$J%15); "-" )
- die freie Tage-Liste muß absolut gesetzt werden
- (A3+B3-1)-1 berücksichtigt keinerlei Wochenende

Gruß von Luschi
aus klein-Paris

AW: Feiertage ausschliessen

03.02.2026 11:08:13

Norman

Hallo Luschi,

vielen Dank.
Die Feiertage habe ich absolut gesetzt. Dann hat alles funktioniert.
Test für mehrere Feiertage hintereinander:

Eingang: 21.03.2026 Tage: 14 Ziel= 07.04.2026
Alles passt? Die Feiertagsliste muss halt noch absolut gesetzt werden.

AW: Feiertage ausschliessen

03.02.2026 11:47:28

Alwin Weisangler

Hallo,

sorry das ich mich nochmals melde. Du hast schon längst eine funktionierende Formel von mir.
Man kann zwar ne Wissenschaft draus machen. Dazu habe ich auch noch eine ebenfalls ohne die .INTL:


=LET(xA; $C$2+13;xB; $G$4:$G$13;xC; WENN(WOCHENTAG(xA;2)>5; xA+8-WOCHENTAG(xA;2); xA);xD; WENN(WOCHENTAG(xC+1;2)>5; xC+1+8-WOCHENTAG(xC+1;2); xC+1);WENN(ISTFEHLER(VERGLEICH(xC; xB; 0));xC;xD))

Warum habe ich ARBEITSTAG.INTL() nie verwendet. Wenn das Startdatum auf einem Feiertag fällt kann in ungünstiger Konstellation zu einer falschen Ausgabe kommen.

Gruß Uwe

AW: Feiertage ausschliessen

03.02.2026 12:03:05

Norman

Vielen Dank Uwe,

Ich arbeite meist auch so lange, bis es für mich optimal ist.
Mit der Formel LET habe ich mich noch nie beschäftigt. Die muss ich mir in Ruhe mal anschauen.

An alle nochmal vielen Dank!

AW: Feiertage ausschliessen

02.02.2026 12:13:09

Alwin Weisangler

Hallo,
eine von diversen Möglichkeiten um bei deiner ursprünglichen Vorgabe zu bleiben:


=ZÄHLENWENN(G4:G13;C4)+WENN(WOCHENTAG($C$2+13)=7;$C$2+15;WENN(WOCHENTAG($C$2+13)=1;$C$2+14;$C$2+13))

Gruß Uwe

AW: Feiertage ausschliessen

02.02.2026 14:16:27

Edi

Das ist ja ein wenig tricky

Da ein Feiertag ja auch auf ein Wochenende fallen kann, bzw. an Weihnachten auch mal zwei Feiertage hintereinander kommen können, muss man wohl tatsächlich jeden Feiertag für sich betrachten.

Ich hab da mal was gebastelt.

https://www.herber.de/bbs/user/180143.xlsx

Ist bestimmt nicht die schönste und eleganteste aller Lösungen, aber sie sollte funktionieren (hab jetzt allerdings nicht alle Feiertage getestet)
Viele Grüße

Edi

AW: Feiertage ausschliessen

02.02.2026 17:16:48

daniel

Hi

probiere es mal so.
die Formel ist noch schematisch, dh du musst anstelle der berschreibungen (kursiv) die entsprechenden Berechnungsformeln oder Zellbezüge einsetzen:

=LET(a;FristTermin;WENN(NETTOARBEITSTAGE.INTL(a;a;1;feiertagsliste)=1;a;ARBEITSTAG.INTL(a;1;1;feiertagsliste)))

mit dem ersten a;FristTermin weist du den geplanten Fristtermin einer Variablen (a) zu. Das mache ich, weil ich diesen Wert mehrfach benötigte und in so nur einmal berechnen muss und ansonsten die Variable verwenden kann.

das NETTOARBEITSTAGE.INTL(a;a;1;feiertagsliste)=1 prüft dann, ob das Fristdatum auf einen Arbeitstag oder auf einen freien Tag fällt.
ist es ein Arbeitstag, wird es verwendet, wenn nicht, wirt mit ARBEITSTAG.INTL der nächste Arbeitstag ermittelt.

Gruß Daniel

AW: Feiertage ausschliessen

02.02.2026 20:18:58

Yal

Moin,

ich komme auf folgende "Formel":

=MIN(NACHZEILE({0;1;2;3;4;5};LAMBDA(x;LET(T;$C$2+13+x;T+ODER(WOCHENTAG(T;2)>5;NICHT(ISTFEHLER(SVERWEIS(T;G4:G13;1;0)))*9999)))))

Was passiert:
- man erzeugt eine Reihe 0 bis 5
- diese Liste wird auf das Eingangsdatum ($C$2) + 13 Tage addiert
- wenn ein diesen Tage am Wochenende oder in der Feiertag-Liste vorliegt, 9999 dazu addiert,
- aus diesen Ergebnisse das Minima.

VG
Yal

AW: Feiertage ausschliessen

03.02.2026 13:10:45

daniel

Hi

vielleicht auch einfach so (kursive Wörter durch die entsprechende Berechnungsformel oder Zellbezug auf die entsprechenden Werte ersetzen)

=ARBEITSTAG.INTL(FristTermin-1;1;1;feiertagsliste)

Gruß Daniel

AW: Feiertage ausschliessen

02.02.2026 22:34:37

BoskoBiati

Hi,

vielleicht geht es auch so:

=MIN(WENN((REST(C2+ZEILE(A13:A18);7)>1)*(ZÄHLENWENN(G4:G13;C2+ZEILE(A13:A18))=0);C2+ZEILE(A13:A18)))

=LET(xa;C2;xb;ZEILE(A13:A18);xc;G4:G13;xd;C2+xb;xe;ZÄHLENWENN(xc;xd);MIN(WENN((REST(xd;7)>1)*(xe=0);xd)))

Gruß

Edgar

AW: Feiertage ausschliessen

02.02.2026 14:43:03

Norman

Hi Edi,

kann ich in Spalte i die verschachtelte Wenn-Formel b.ei allen verwenden?
Außer bei Samstag und Sonntag

LG
Norman

AW: Feiertage ausschliessen

02.02.2026 14:51:13

Edi

Nicht wirklich.
Für die meisten Feiertage funktioniert sie, aber nicht, wenn zwei Werktage hintereinander Feiertage sind.
Das ist an Ostern und Weihnachten der Fall.
Heißt, für Karfreitag und den 1. Weihnachtsfeiertag kannst du die nicht verwenden.
Ansonsten sollte die verschachtelte Formel auch bei den anderen funktionieren.

AW: Feiertage ausschliessen

03.02.2026 07:08:06

Norman

Guten Morgen zusammen,

vielen lieben Dank für die vielen Ideen.

Leider kann ich die alle erst heute Nachmittag testen. Momentan nutze ich die von Edi.

Vielen Dank nochmal an alle und einen schönen Tag!
Norman

AW: Feiertage ausschliessen

02.02.2026 12:47:07

Norman

Hi,

vielen Dank auch Dir.
Da habe ich leider einen Zirkelbezug.
Kann man meine aktuelle Formel einfacher gestalten?

AW: Feiertage ausschliessen

02.02.2026 13:45:58

Alwin Weisangler

sorry,

da war ich noch nicht richtig munter.
Du hast ja O365. Dann wäre das eine von vielen Möglichkeiten:

=LET(xA; $C$2+13;xB; WENN(WOCHENTAG(xA;2)>5; xA+8-WOCHENTAG(xA;2); xA);xC; WENN(WOCHENTAG(xB+1;2)>5; xB+1+8-WOCHENTAG(xB+1;2); xB+1);WENN(ISTNV(VERGLEICH(xB; $G$3:$G$13; 0)); xB; xC))

oder:

=LET(xA;$C$2+13;xB;WENN(WOCHENTAG(xA;2)>5;xA+8-WOCHENTAG(xA;2);xA);WENN(ISTNV(VERGLEICH(xB;$G$4:$G$13;0));xB;WENN(WOCHENTAG(xB+1;2)>5;xB+1+8-WOCHENTAG(xB+1;2);xB+1)))

Gruß Uwe

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!