Bedingte Formatierung auf vbRed stellen mit With Anweisungen

11.02.2026 20:19:36

mckater

Moin,

bin gerade am Lieblingsprojekt wieder dabei und hätte da eine Frage.
Bedingte Formatierung, was ich ja so überhaupt nicht mag wirklich....

Rng1.Select

For i = 1 To 1
Application.CutCopyMode = False
Application.CutCopyMode = False
Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlNotBetween, _
Formula1:="=$E$220+$F$220", Formula2:="=$E$220+$G$220"
Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
With Selection.FormatConditions(1).Font
.Color = -16776961
.TintAndShade = 0
End With

Selection.FormatConditions(1).StopIfTrue = False
Next i

Wie kann ich der For, With sagen....hey ich will da nicht .Color = -16776961
Sondern ich will da anstelle der Nummer, vbRED haben (was ja diese Color ist)

Im Internet werde ich da nicht schlau, weil der meckert dann ständig im Modul

Ich will einfach für jede Routine hier anstelle der langen Zahl für ROT, vbRed drinnen haben

Ich habe mehrere For und With im Code.

Vielleicht ist es ja einfach oder auch nicht....mit der Nummer funktioniert es super....aber vbRed mag der nicht in VBA Excel

mfg mckater

AW: Bedingte Formatierung auf vbRed stellen mit With Anweisungen

11.02.2026 20:24:14

Christian

Hallo McKater, ich muss zugeben ich rate hier selber ins blaue hinein, aber probiers mal mit RGB,
also



With Selection.FormatConditions(1).Font

    .Color = RGB(255, 0, 0)

End With

AW: Bedingte Formatierung auf vbRed stellen mit With Anweisungen

12.02.2026 15:38:09

Onur

"Wie kann ich der For, With sagen....hey ich will da nicht .Color = -16776961 -Sondern ich will da anstelle der Nummer, vbRED haben (was ja diese Color ist) " ???
Und warum sagst du es dann "der For, With" nicht einfach ?

 .Color = vbRed

AW: Bedingte Formatierung auf vbRed stellen mit With Anweisungen

12.02.2026 15:59:24

mckater

Hallo Onur,

ganz einfach, weil meine .Color im Code das vbRed nicht wollte
https://www.herber.de/bbs/user/180270.xlsm

Er akzeptierte aber folgendes von Christian im Beitrag:

For i = 1 To 1
Application.CutCopyMode = False
Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlNotBetween, _
Formula1:="=$E$472+$F$472", Formula2:="=$E$472+$G$472"
Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
With Selection.FormatConditions(1).Font
.Color = RGB(255, 0, 0)
.TintAndShade = 0
End With
Selection.FormatConditions(1).StopIfTrue = False
Next i

weil meine .Color im Code das vbRed nicht wollte

12.02.2026 16:11:26

Uduuh

Hallo,
funktioniert bei mir einwandfrei.

Der Code ist aber gruselig.

Gruß aus'm Pott
Udo

AW: weil meine .Color im Code das vbRed nicht wollte

12.02.2026 16:36:02

mckater

Das Coderl ist gruselig

Weil die Bedingte Formatierung kein leichtes Spiel ist!
Das ist nur die einfache Version
Die komplexere ist mit VBA nicht zu schaffen.
(Das gruselige wurde ja durch Makrorekorder erstellt)
Aber wichtig ist ja immer, es klappt.

AW: weil meine .Color im Code das vbRed nicht wollte

12.02.2026 16:43:29

Uduuh

Hallo,

Sub Bedingte_Formatierung()

  Dim rngFormat As Range

  Dim lngSpalte As Integer, lngZeile As Long

  

  With Sheets("measurement_data")

    For lngZeile = 31 To .Cells(Rows.Count, 3).End(xlUp).Row

      Set rngFormat = .Cells(lngZeile, 11)

      For lngSpalte = 13 To 41 Step 2

        Set rngFormat = Union(rngFormat, .Cells(lngZeile, lngSpalte))

      Next lngSpalte

      

      Application.CutCopyMode = False

      With rngFormat

        .FormatConditions.Delete

        .FormatConditions.Add Type:=xlCellValue, Operator:=xlNotBetween, _

          Formula1:="=$E$" & lngZeile & "+$F$" & lngZeile, Formula2:="=$E$" & lngZeile & "+$G$" & lngZeile

        With .FormatConditions(1)

          .SetFirstPriority

          .Font.Color = vbRed

          .StopIfTrue = False

        End With

      End With

    Next lngZeile

  End With

  

End Sub

macht solange in C was steht.

Gruß aus'm Pott
Udo

AW: weil meine .Color im Code das vbRed nicht wollte

12.02.2026 17:25:14

mckater

Hallo Udo aus dem Pott,

ich hab dein Coderl probiert!
Das funzt ja, wie geschmiert!
Den Code würden viele brauchen, den musst öffentlich machen!
Der macht mir die Handarbeit weg und so wenig Code und nicht mal 1 Sekunde ist die Party fertig.

Bin sprachlos!
Da stimmt alles!
Der macht alles RICHTIG!
Ein Code und nicht unsinnig da rumwerkelen wie ICH
Der Code ist genial!!

Wow, bin gerade etwas geflasht, weil das so einfach geht

die komplexe Version mag ich Dir nicht zeigen, weil sonst schaffst das auch noch

Grüße aus dem Ösipott,
mckater

die komplexe Version mag ich Dir nicht zeigen,

12.02.2026 17:28:52

Uduuh

Hallo,
mach mal.

Den Code würden viele brauchen, den musst öffentlich machen!
Ist er doch! ;-)

Gruß aus'm Pott
Udo

AW: die komplexe Version mag ich Dir nicht zeigen,

12.02.2026 18:18:45

mckater

Ja aus dem Pott, aber nur für eine gewisse Zeit....sonst kannst im Album suchen*gg*

Die komplexe Version magst nicht wissen, wenn nicht alle Zeilen mit Nennmaß usw. verbunden sind.
wo eine Zeile mal 5 Zeilen hat und dann 5 darunter....die aber an die Hauptzelle verbunden sein müssen.
Oder mal auch nur 3 Zeilen....es gibt eine erste Zeile mit Nennmaß usw....aber die unteren müssen verbunden sein.
Ich denke das ist mit VBA nicht zu lösen

Wenn man es von Hand lösen kann, ...

12.02.2026 18:46:02

Uduuh

... kann man es auch mit VBA.

AW: Wenn man es von Hand lösen kann, ...

12.02.2026 19:04:49

mckater

Ich denke das kann man nicht lösen!

So ab Zeile 31 wird begonnen....aber oft habe ich nicht in jeder Zeile einen Nennwert mit Otol un Utol....die müssen dann aber verbunden werden.
Weißt? Jedes Projekt ist anders....es läuft halt nicht so ab wie jede Zeile hat das oder jenes....wie soll man das steuern?
ich sage POS 1 okay
Pos 2 ist Zeile 8 und darunter 5 andere Werte die aber mit Zeile 8 verbunden werden müssen

Beispielversion aus einem früheren Projekt....die stellen da die Spiegel ein für Autos

https://www.herber.de/bbs/user/180273.xlsx

Ich habe natürlich die Zeichnung wie auch die Daten

AW: Wenn man es von Hand lösen kann, ...

12.02.2026 19:43:41

schauan

Hallöchen,

oft habe ich nicht in jeder Zeile einen Nennwert mit Otol un Utol....die müssen dann aber verbunden werden.

1)
Du brauchst einfach nur die Werte solange zu lassen, wie keine neuen in den Zellen stehen. Also keine Zellbezüge, sondern fixe Werte nehmen.
2)
Du trägst die Werte in jeder Zeile ein. Du müsstest "Testteil ..." dann natürlich anders verorten. In 43/44, 47-95 usw. geht's doch auch, zumindest, was Werte betrifft ... Dann kannst Du vermutlich generell mit der bF arbeiten, ganz ohne Makro.
3)
Unabhängig davon steht natürlich die Frage, warum Du die Aufgabe mit VBA und bedingter Formatierung lösen willst. Bei Deinem Blattaufbau kannst Du die Farben auch fix per VBA setzen und bei neuen Werten das Makro erneut ausführen.

AW: Wenn man es von Hand lösen kann, ...

12.02.2026 20:24:19

Uduuh

Hallo,
Zeile 31 bis letzte in E:

Sub BedFormat()

  Dim rngF As Range, lngZ As Long, lngS As Long, iAnz As Integer

  Dim strF1 As String, strF2 As String

  Dim objBF As Object

  

  With Sheets("measurement_data")

    For lngZ = 31 To .Cells(Rows.Count, 5).End(xlUp).Row

      If Application.Count(.Cells(lngZ, 5).Resize(, 3)) = 3 Then

        strF1 = "=$E$" & lngZ & "+$F$" & lngZ

        strF2 = "=$E$" & lngZ & "+$G$" & lngZ

      End If

      Set rngF = .Cells(lngZ, 11)

      For lngS = 13 To 41 Step 2

        Set rngF = Union(rngF, .Cells(lngZ, lngS))

      Next lngS

      With rngF

        .FormatConditions.Delete

        Set objBF = .FormatConditions.Add _

          (Type:=xlCellValue, Operator:=xlNotBetween, _

          Formula1:=strF1, Formula2:=strF2)

        With objBF

          .SetFirstPriority

          .Font.Color = vbRed

          .StopIfTrue = False

        End With

      End With

    Next lngZ

  End With

  

End Sub

Gruß aus'm Pott
Udo

AW: Wenn man es von Hand lösen kann, ...

12.02.2026 20:49:36

mckater

Wenn ich diesen Code ausführe

macht er folgendes, ich kann keine Daten mehr rein schreiben....schon aber wenn ich 20 eingebe, macht der ! oder $ oder sonst was

AW: Wenn man es von Hand lösen kann, ...

12.02.2026 21:19:50

mckater

Ich muss mich an Udo aus dem Pott entschuldigen!

Ich denke das sieht sehr gut aus, wie das geht weiß ich nicht, aber es funktioniert!!!
Die komplexe Version auch gelöst!
WOW!
Das ist VBA vom FEINSTEN, so kurzer CODE und der rockt mir das Tabellenblatt!!!!

Ich teste das noch,aber was ich jetzt weiß der erkennt alles mit den Zeilen...WOW!!!

Ich denke du sollst bei Microsoft arbeiten!
Dein Code macht das wie wenn es kein Problem ist!
Dem ist es egal ob mal eine Zeile gebunden werden soll und die nächste Zeile ist aber mit anderen 5 Zeilen gebunden oder auch anders mit mal 2 oder so.
Wie geht das nur?

Ich habe mir die Zellenbereiche mit der Bedingten Formatierung angesehen, die passen auf 100%
WOW!!!
Das ist Coden der höchsten Kunst

Ich muss das noch etwas testen, aber das ist CODEN vom Top LEVEL!!!

Teste das mal in meiner Originalversion.....aber das sieht so perfekt aus OHNE Ahnung zu haben wie das geht.
Normal schreibt man endlos Code rein und deiner erledigt es wie wenn ich habe danach Feierabend.
Unter 10.000 EUR bei Mikrosoft braucht nicht anfangen*gg*(Im Monat)
Gebe Rückmeldung wenn ich noch was finde....das ist sehr viel Wert, weil es ein großes Problem ist

Grüße aus Österreich,
mckater

Die Reaktion ...

13.02.2026 12:35:04

Uduuh

Hallo,
... ist vollkommen überzogen.
Der Code ist Pipifax. Es wird doch nur Zeile für Zeile geprüft, ob in F:H 3 Zahlen stehen. Wenn ja werden die Fomeln für die BF angepasst.
Mehr ist das nicht!

Gruss aus'm Pott
Udo

AW: Die Reaktion ...

13.02.2026 13:22:44

mckater

Moin fast,
Udo aus'm Pott

Naja, was soll ich sagen?
Würde ich das manuell machen würde ich Stunden brauchen
Das geniale an deinem Code ist einfach...der macht das in 2 Sekunden

Die besondere Schwierigkeit lag daran, ...ich habe ja oft mal keinen Nennwert in einer Zeile und darunter messe ich 5 Teile, die aber mit deinem Code es checken!
Ich habe noch nie so einen kurzen Code gesehen der das macht was ich da will.

Die erste Codeversion von Dir hat schon super geklappt! (einfache Version, wo ab Zeile 31 begonnen wird und in jeder Zeile steht ein Nennwert, oTol, uTol und macht das auf die 8 Bauteile wie in meinem Fall.

Abe die KOMPLEXERE Version, das Coderl von Dir macht es wie wenn es das einfachste der Welt ist.
Ich habe in Zeile 31 in Spalte E das Nennmaß, in Spalte F die oTol, in Spalte G die uTol
(Ist gebunden, weil aus dem Tabellenblatt wird ja mit VBA kopiert und ausgewertet...aber da jetzt nicht so wichtig)
Das geniale ist! Sollte mal eine Zeile einen Nennwert haben, oTol, uTol und darunter steht da Messteil 1 bis Messteil 5 oder Flügel 1 und Flügel2 macht er die VERBINDUNG zur obersten Zeile, wo da der Nennwert steht und tuckelt dann weiter und macht wieder alles RICHTIG.
Für mich war das UNLÖSBAR!
Ich muss mir dein Coderl noch mal ansehen...viele Dinge sind mir klar, aber mit dem Code kann ich ja nicht nur 8 Bauteile bestücken, sondern den Rest der Spalten bis ans Ende und der macht Zeile für Zeile seinen JOB
Ich bin echt erstaunt und fassungslos.
Warum? Weil so viele Anfragen über Bedingte Formatierung kommen und ich war echt einer, ich hasste es, weil mal so und dann mal so.
Vorher hab ich das ganze manuell gemacht...dauerte echt über eine Stunde.....alles makieren und jeden Bereich auswählen und so weiter.
Dein Code ablaufen....2 Sekunden und die Party ist fertig!

Dein Coderl macht es Zeile bis Zeile und macht es so lange bis halt mal nix mehr da ist.
Bin gespannt ob ich es schaffe, dein Coderl so umzubauen, das er mir das pro Zeile bis ans Ende macht. (anstelle derzeit 8 Bauteile, sondern xx viele - also alle Spalten auswählen die in Frage kommen.

Denke viele hier sind froh und wenn Sie das prüfen haben Sie keine Sorgen mehr!
(bei mir wird halt nur geprüft ob Nennmaß und oTol drinnen ist, Nennmaß mit unterer Toleranz und dann entscheiden mit vbRed)
Ich hab mir das in das Hauptprojekt gestellt, also "measurement_data"
Das funzt aber so was von gut!

Fazit:
für jedes Projekt das Coderl benutzen.....nix mehr da manuell die Bedingte Formatierung machen!!!! Zeile für Zeile oder auch wenn eine Zeile mit anderen verbunden werden muss.

Sonnige Grüße aus dem Ösiland vom Lehrling in VBA,
mckater

AW: Die Reaktion ...

13.02.2026 16:19:32

Uduuh

Hallo,
Bin gespannt ob ich es schaffe, dein Coderl so umzubauen, das er mir das pro Zeile bis ans Ende macht. (anstelle derzeit 8 Bauteile, sondern xx viele - also alle Spalten auswählen die in Frage kommen.
Das geht so:

Sub BedFormat()

  Dim rngF As Range, lngZ As Long, lngS As Long, lngLS As Long

  Dim iAnz As Integer

  Dim strF1 As String, strF2 As String

  Dim objBF As Object

  

  With Sheets("measurement_data")

    'letzte Spalte bestimmen

    If .Cells(29, Columns.Count) > "" Then

      lngLS = Columns.Count

    Else

      lngLS = .Cells(29, Columns.Count).End(xlToLeft).Column + 2

    End If

    

    'alle Zeilen in E31 bis Ende durchlaufen

    For lngZ = 31 To .Cells(Rows.Count, 5).End(xlUp).Row

    

      If Application.Count(.Cells(lngZ, 5).Resize(, 3)) = 3 Then

        'in E:G sind 3 Zahlen, Formel aufbauen

        strF1 = "=$E$" & lngZ & "+$F$" & lngZ

        strF2 = "=$E$" & lngZ & "+$G$" & lngZ

      End If

      

      'Bereich für Formatiering zussammenstellen

      Set rngF = .Cells(lngZ, 11)

      For lngS = 13 To lngLS Step 2

        Set rngF = Union(rngF, .Cells(lngZ, lngS))

      Next lngS

      

      'Formatierung einfügen

      With rngF

        .FormatConditions.Delete  'erst mal löschen

        Set objBF = .FormatConditions.Add _

          (Type:=xlCellValue, Operator:=xlNotBetween, _

          Formula1:=strF1, Formula2:=strF2)

        With objBF

          .SetFirstPriority

          .Font.Color = vbRed

          .StopIfTrue = False

        End With

      End With

      

    Next lngZ

  End With

  

End Sub

Gruß aus'm Pott
Udo

AW: Die Reaktion ...

13.02.2026 17:12:15

schauan

Hallöchen,

eventuell hast Du schon mal davon gehört, dass eine große Anzahl bedingter Formatierungen die Performance negsativ beeinflussen kann. In einer Datei waren da schon 87 drin ...

Du kanst auch den kompletten Bereich ab K31 nach rechts und unten markieren und nimmst diese Funktion als Bedingung:

Wie ich schon mal schrieb, kann man sich bei einer Makrolösung die letzten Zahlen merken und diese verwenden, bis was neues kommt.
Diese Funktion macht nix anderes.

AW: Die Reaktion ...

13.02.2026 17:46:22

mckater

Das Problem war ja so komplex, weil ich ja mit Zeile 31 beginne....egal hier (ist gebunden für die weiteren VBA CODES der Auswertung)
Natürlich verbraucht es viel Speicher....aber lieber 2 Tage da rumbasteln mit gruseligen Code?

@ Udo aus'n Pott
Coderl schaut wieder super aus!
Muss ich noch testen, weil ich habe derzeit nur 8 Bauteile drinnen....aber die Bedingte Formatierung funzt wie geschmiert
Ich denke mal, wenn ich von 8 auf 100 gehe, macht der es in 5 Sekunden.....die 10 Sekunden PLUS für den neuen Code ist doch keine Frage wert.
Also Hauptprokekt starten....die Bauteile muss ich noch anpassen, aber schaut sehr gut aus!
Ich gebe die Rohaten ein und egal ob ich einen Bindestrich mache, das macht der CODE im red_check von Piet
Denke das ist die Finish Version!

@ schauan

der Code ist perfekt, ob der für 8 Bauteile 2 Sekunden braucht oder für die ganzen Spalten ist egal....ich denke halt 10 Sekunden länger
Ich habe es noch nicht getestet für das ganze Projekt...aber derzeit sieht es so aus....ich habe bis auf Bauteil 20 erweitert und macht das was ich will.
Natürlich braucht es Speicher....ist mir doch egal oder? Ich brauche einen Druckfertigen Ausdruck.....das Tabellenblatt "measuremed_data" ist ja nur was ich eingebe.
Das WICHTISTE ist halt du machst dir den Bauplan mit Nennwert und oTOl UTol und der Code von UDO aus dem Pott macht das.
Das Tabellenblatt "measurement_data" ist ja nur dafür da, wo ich die Messerte eintrage oder von der Messmachine füllen lasse.
Also zur INFO: der VBA läuft viele Routinen ab mit SUBS und wichtig sind halt die Daten in dieser Datei, Rohdatei, weil die kopiert werden.

Erzähle wie du das einfacher machen willst?
Weil der prüft alle Zeilen durch wie Spalten und macht alles RICHTIG.
Eine Kunst für die Bedingte Formatierung im Sinne von meinem Fall mit vbRED

Sonne geht unter aber glücklich für den Durchbruch!
Danke Udo!