SendMail-Methode

Forumthread: SendMail-Methode

SendMail-Methode

02.08.2004 12:07:51

matthias

Hallo,
ich möchte die SendMail-Methode benutzen und jedoch neben der Überschrift einen Text in die Mail einfügen lassen. Leider habe ich bislang keine Möglichkeit gefunden dies zu realisieren.
Hat jemand eine Idee?
Danke
Matthias

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: SendMail-Methode

MRR
AW: SendMail-Methode

02.08.2004 13:46:37

Matthias
AW: SendMail-Methode

MRR
AW: SendMail-Methode

hans

AW: SendMail-Methode

MRR

Probiere es mal so:


Sub SendeMail()
Dim olApp As Outlook.Application
Dim objNachricht As Outlook.MailItem
Dim objRecipient As Outlook.Recipient
Set olApp = CreateObject("Outlook.Application")
Set objNachricht = olApp.CreateItem(olMailItem)
With objNachricht
.Subject = "Text im Betreff"
.Body = "Hier könnte schon Text der eigentlichen Nachricht stehen..." & vbCr & _
"Dies ist die 2. Zeile des Textes"
Set objRecipient = .Recipients.Add("Heinz.Becker@web.de")
objRecipient.Type = 1
.Display
End With
'Bereinigung der Variablen
Set objRecipient = Nothing
Set objNachricht = Nothing
Set olApp = Nothing
End Sub

HTH, Matthias

AW: SendMail-Methode

02.08.2004 13:46:37

Matthias

Super, danke .... lassen sich da auch noch Dateien anfügen?
Gruß
Matthias

AW: SendMail-Methode

MRR

Dann hier ein bisschen mehr (bitte anpassen!)


Sub SendeMail()
Dim olApp As Object
Dim objNachricht As Object    'Variable für die Mail
Dim objRecipient As Object   'Variable für die Empfänger
Set olApp = CreateObject("Outlook.Application") 'Erzeuge Outlook-Sitzung
'Erstelle eine neue Nachricht, die 0 in CreateItem steht für olMailItem
Set objNachricht = olApp.CreateItem(0)
With objNachricht
.Subject = "Text im Betreff"
.Body = "Hier könnte schon Text der eigentlichen Nachricht stehen..." & vbCr & _
"Dies ist die 2. Zeile des Textes"
'Erzeuge 2 Adressaten: Der 1. wird als primärer, der 2. als Kopieempfänger angegeben
Set objRecipient = .Recipients.Add("Karl.Klammer@gmx.de")
objRecipient.Type = 1 'Adressiere: To
Set objRecipient = .Recipients.Add("Heinz.Becker@web.de")
objRecipient.Type = 2 'Adressiere: CC
'Hänge eine Datei an die Mail
.Attachments.Add "C:\Temp\Test.xls"
.ExpiryTime = Date + 8      'Nachricht verfällt beim Empfänger in 8 Tagen
.Importance = 2             'entspricht olImportanceHigh = Hohe Wichtigkeit
.ReminderTime = Date + 7    'Erinnerung in 7 Tagen
.Sensitivity = 3            'entspricht olConfidential = Vertraulich
.DeleteAfterSubmit = True   'Nach dem Senden direkt wieder löschen (nicht aufheben)
.Send                       'Sende die Nachricht
End With
'Bereinigung der Variablen
Set objRecipient = Nothing
Set objNachricht = Nothing
olApp.Quit
Set olApp = Nothing
End Sub

HTH, Matthias

AW: SendMail-Methode

hans

Hallo Matthias,
ist dir das eine Hilfe ?
Set olApp = CreateObject("Outlook.Application")
With olApp.CreateItem(0)
'Empfänger
.Recipients.Add "Empfaenger"
'Betreff
.Subject = "Überschrift"
'Nachricht
.Body = "Text ..... bla bla bla" & Chr(13) & _
"bla bla bla" & Chr(13) & Chr(13) & _
"bla bla" & Chr(13)
'Lesebestätigung aus
.ReadReceiptRequested = False
'Dateianhang
.Attachments.Add ("Datei")
.display
End With
Set olApp = Nothing

Beliebteste Forumthreads (12 Monate)

Forumthread: SendMail-Methode

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread