DBSUMME Datenbankfeld

Forumthread: DBSUMME Datenbankfeld

16.08.2005 07:25:44

Doug

Hallo!
Weiss jemand, ob man das Datenbankfeld in DBSUMME variabel gestalten kann?
DBSUMME soll in einer Zelle sein, aber je nach dem was in einer anderen Zelle steht (variabel) eine andere Spalte aus der Datenbank auslesen und aufsummieren!
Danke!
Doug

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: DBSUMME Datenbankfeld

16.08.2005 12:15:26

Herbert
AW: DBSUMME Datenbankfeld

16.08.2005 14:20:20

Erich
AW: DBSUMME Datenbankfeld

17.08.2005 06:14:21

Doug

AW: DBSUMME Datenbankfeld

16.08.2005 12:15:26

Herbert

hallo Doug,
ich denke ja,
z.B.
=WENN(A1=1;DBSUMME(C3:E10;D3;H3:H4);WENN(A1=2;DBSUMME(C3:E10;E3;H3:H4);""))
wenn in A1 eine 1 steht wird Spalte D summiert,
wenn in A1 eine 2 steht wird Spalte E summiert,
sonst bleibt die Zelle leer
gruß Herbert

AW: DBSUMME Datenbankfeld

16.08.2005 14:20:20

Erich

Hallo Doug,
es geht auch ohne WENN, du kannst auch Ausdrücke als Parameter von DBSUMME verwenden. Ein paar Beispiele:

__|___A____|____B____|___C____|______D______|E|___F____|______G______|
 1|abra    |sonstwas |kadabra |abra_kadabra | |Spalte  |            1|
 2|       1|        2|       4|            8| |Summe:  |      1111111|
 3|      10|       20|      40|           80| |        |             |
 4|     100|      200|     400|          800| |Spalte  |abra_kadabra |
 5|    1000|     2000|    4000|         8000| |Summe:  |         8888|
 6|   10000|    20000|   40000|             | |        |             |
 7|  100000|   200000|        |             | |Summen: |      1111111|
 8| 1000000|         |        |             | |        |       222222|
 9|        |         |        |             | |        |        44444|
10|        |         |        |             | |        |         8888|

Benutzte Formeln:
   G1 : =AUFRUNDEN(ZUFALLSZAHL()*4;0)
   G2 : =DBSUMME(A1:D8;G1;$E$1:$E$2)
   G4 : =A1&"_"&C1
   G5 : =DBSUMME(A1:D11;G4;$E$1:$E$2)
   G7 : =DBSUMME(A:D;ZEILE()-6;$E$1:$E$2)
   G8 : =DBSUMME(A:D;ZEILE()-6;$E$1:$E$2)
   G9 : =DBSUMME(A:D;ZEILE()-6;$E$1:$E$2)
   G10: =DBSUMME(A:D;ZEILE()-6;$E$1:$E$2)

In G1 wird eine Zufallszahl zwischen 1 und 4 gerechnet, in G2 wird diese als Spaltennummer für die Summe verwendet.
In G4 steht eine Formel für den Feldnamen, der dann in G5 verwendet wird. In G5 könnte natürlich auch (ohne den Hilfswert G4)
=DBSUMME(A1:D11;A1&"_"&C1;H4:H5) stehen.
In G7 bis G10 werden die zu summierenden Spaltennummern aus den Zeilen, in denen die Formeln stehen, gerechnet.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: DBSUMME Datenbankfeld

17.08.2005 06:14:21

Doug

Hallo Erich!
Danke fuer die umfangreiche Loesung! Hat funktioniert, arbeite mit der Formel aus G5! Perfekt!
Danke!
Doug

Forumthread: DBSUMME Datenbankfeld

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread