Makro gesucht für Inhalte mehrerer Zellen kopieren

Forumthread: Makro gesucht für Inhalte mehrerer Zellen kopieren

21.12.2005 08:28:02

Rico

Guten Morgen liebe Experten
ich steh wiedermal aufm Schlauch und hab nach einigen Versuchen mit dem Makrorecorder und meinem sehr beschränkten VBA-Wissen klein beigeben müssen.. :-(
Ich sollte ein Makro haben welches ich dann mit einem Befehls-Button verknüpfen kann. Die auszüführende Funktion sollte dann sein:
1. Der Inhalt mehrerer markierter Zellen zu kopieren
2. Wenn möglich sollte beim Einfügen der kopierten Inhalte in ein Textfeld eines anderen Programmes (manuell ausgelöst mit strgl-v) zwischen den Inhalten der verschiedenen Zellen eine Leerzeile eingefügt werden. Ich frage mich nun, ob diese formatierung bereits im Makro fürs Kopieren der Zellinhalte eingebaut werden kann....
Für Eure Tips bin ich wie immer äusserst dankbar.
Gruss Rico

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Makro gesucht für Inhalte mehrerer Zellen kopieren

21.12.2005 11:27:16

Harald
Übersicht würde fehlen

21.12.2005 13:09:57

Rico
AW: Übersicht würde fehlen

21.12.2005 23:46:54

Erich
DANKE !!!!!

27.12.2005 09:02:53

Rico

AW: Makro gesucht für Inhalte mehrerer Zellen kopieren

21.12.2005 11:27:16

Harald

Hi Rico,
vielleicht wäre ein Hilfsblatt (Sheets(2)) als Zwischenschritt angebracht
Sheets(2).range("a1") = Sheets(1).range("a1").value & " "
Somit hättest Du den Wert aus Blatt 1 A1 inclusive Leerzeichen am Ende ins Blatt 2 transferiert und dort kannst Du die benötigten Zellen kopieren.
Gruss Harald

Übersicht würde fehlen

21.12.2005 13:09:57

Rico

Hoi Harald
Danke für die Antwort.
Da ich aus mehreren Excel-Dokumenten insgesamt etwa 4500 Zellen zu bearbeiten habe ist dies ziemlich aufwendig und unübersichtlich.. :-(
Zum Leerzeichen:
Im Textfeld des "anderen Programmes" sollte schlussendlich der Inhalt der "ersten" Zelle aufgeführt sein und danach eine Leerzeile damit ein neuer Abschnitt entsteht. Es kann vorkommen, dass ca. 5 Abschnitte (Inhalt aus 5 verschiedenen Zellen) eingefügt werden muss.
Gibts sonst noch Tips die mir weiterhelfen könnten? Danke im Voraus und Gruss aus der Schweiz

AW: Übersicht würde fehlen

21.12.2005 23:46:54

Erich

Hallo Rico,
wenn alle selektierten Zellen im aktiven Tabellenblatt in die Zwischenablage kopiert werden und zwischen den Zellwerten Leerzeielen stehen sollen, müsste das mit der Prozedur "Auswahl_in_Zwischenablage" gehen:


Option Explicit
Private Declare Function OpenClipboard Lib "user32" ( _
ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32" () As Long
Private Declare Function EmptyClipboard Lib "user32" () As Long
Private Declare Function SetClipboardData Lib "user32" ( _
ByVal wFormat As Long, _
ByVal hMem As Long) As Long
Private Declare Function GlobalAlloc Lib "kernel32" ( _
ByVal wFlags As Long, _
ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32" ( _
ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32" ( _
ByVal hMem As Long) As Long
Private Declare Function GlobalFree Lib "kernel32" ( _
ByVal hMem As Long) As Long
Private Declare Function lstrcpy Lib "kernel32" ( _
ByVal lpStr1 As Any, _
ByVal lpStr2 As Any) As Long
Private Const GMEM_MOVEABLE As Long = 2&
Private Const CF_TEXT As Long = 1&
Sub Auswahl_in_Zwischenablage()
Const Leer As String = vbCrLf
Dim strCP As String, rg As Range
For Each rg In Selection
strCP = strCP & rg & Leer & Leer
Next rg
StringToClipboard Left(strCP, Len(strCP) - 2 * Len(Leer))
End Sub
Public Sub StringToClipboard(s As String)
'  von Risi Thomas Softwareentwicklung   www.rtsoftwaredevelopment.de
Dim hMem As Long, hPtr As Long
hMem = GlobalAlloc(GMEM_MOVEABLE, Len(s) + 1)
hPtr = GlobalLock(hMem)
lstrcpy hPtr, s
GlobalUnlock hMem
OpenClipboard 0&
EmptyClipboard
SetClipboardData CF_TEXT, hMem
CloseClipboard
GlobalFree hMem
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

DANKE !!!!!

27.12.2005 09:02:53

Rico

Das ist ja super ERICH!!!
Vielen herzlichen Dank.... genau so muss es funktionieren :-)
Gruss aus der Schweiz
Rico

Beliebteste Forumthreads (12 Monate)

Makro gesucht für Inhalte mehrerer Zellen kopieren

Forumthread: Makro gesucht für Inhalte mehrerer Zellen kopieren

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread