Matrix mit Makro erstellen

Forumthread: Matrix mit Makro erstellen

10.06.2006 18:27:18

Stefan

Hi,
wie kann man denn solch eine Matrix mit Makro erzeugen?
Userbild

Die soll eine beliebige Größe haben aber immer Zeilen = Spalten.
Danke für Hilfe.
mfg Stefan

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Matrix mit Makro erstellen

10.06.2006 22:21:37

Josef
AW: Matrix mit Makro erstellen

10.06.2006 22:25:48

Erich
AW: Matrix mit Makro erstellen

10.06.2006 22:28:10

Erich
Sensationell, ich danke euch! oT

10.06.2006 22:39:56

Stefan

AW: Matrix mit Makro erstellen

10.06.2006 22:21:37

Josef

Hallo Stefan!
Viel Spass.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub MakeWiredMatrix(ByVal Dimension As Integer, ByVal TargetCell As Range)
Dim intR As Integer, intC As Integer, intIndex As Integer, intDim As Integer
Dim rng As Range

If Dimension > 256 Then Dimension = 256

intDim = Dimension - 1

Set rng = TargetCell.Cells(1, 1)

If rng.Column + Dimension - 1 > Columns.Count Then GoTo ErrExit
If rng.Row + Dimension - 1 > Rows.Count Then GoTo ErrExit

Redim varm(intDim, intDim)
intIndex = 1
For intC = 0 To intDim
  intIndex = intIndex - 1
  For intR = 0 To intDim
    If intIndex = Dimension Then intIndex = 0
    intIndex = intIndex + 1
    varm(intR, intC) = intIndex
  Next
Next

With TargetCell.Parent
  .Range(.Cells(rng.Row, rng.Column), .Cells(rng.Row + intDim, rng.Column + intDim)) = varm
End With

ErrExit:
Set rng = Nothing
End Sub

Sub test()
MakeWiredMatrix 12, Range("A1")

''Oder
'MakeWiredMatrix 25, Sheets("Tabelle3").Range("D25")
End Sub

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

AW: Matrix mit Makro erstellen

10.06.2006 22:25:48

Erich

Hallo Stefan,
noch ein Vorschlag:

Sub Matrix_fuellen()
Const anz = 10
Range([A1], Cells(anz, anz)).FormulaR1C1 = "=ROW()-COLUMN()+1+" & anz & "*(ROW()<COLUMN())"
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Matrix mit Makro erstellen

10.06.2006 22:28:10

Erich

Hallo nochmal.
Wenn die Formel stören, dann so

Sub Matrix_fuellen2()
Const anz = 10
Range([A1], Cells(anz, anz)).FormulaR1C1 = "=ROW()-COLUMN()+1+" & anz & "*(ROW()<COLUMN())"
Range([A1], Cells(anz, anz)) = Range([A1], Cells(anz, anz)).Value
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Sensationell, ich danke euch! oT

10.06.2006 22:39:56

Stefan

Beliebteste Forumthreads (12 Monate)

Forumthread: Matrix mit Makro erstellen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread