Auto-Eintrag Datum+User

30.06.2006 09:09:22

Sven

Hallo,
es wäre schön wenn mir jemand bei folgendem Problem helfen könnte.
Ich möchte das sobald z.B. in der Zelle A1 etwas eingetragen wird sich die Zelle A2 mit dem jeweiligen Tagesdatum und A3 mit der UserID des Benutzers füllt.
Die Daten sollen dann dort verbleiben, damit ich immer erkennen kann wann und von wem dieser Eintrag gemacht wurde.
Ich hoffe auf Eure Hilfe
Gruß
Sven

AW: Auto-Eintrag Datum+User

30.06.2006 09:30:06

Mustafa

Hallo Sven,
Wenn du jede auf jede Änderung von Zelle A1 reagieren willst, dann füge folgenden Code in das Tabellenblatt Modul ein:


Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Cells(1, 1)) Is Nothing Then Exit Sub
Target.Offset(0, 1) = Date & " " & Environ("Username")
End Sub

Rückmeldung obs Hilft wäre nett.
Viele Grüße aus Köln.

AW: Auto-Eintrag Datum+User

30.06.2006 10:15:12

Harald

Moin Sven,
noch ne Alternative


Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo ende
If Target.Count = 1 And Target.Address(0, 0) = "A1" Then
Application.EnableEvents = False
'ActiveSheet.Unprotect "Passwort"
Range("A2") = Format(Date, "dd.mm.yy")
Range("A3") = Environ("username")
'ActiveSheet.Protect "Passwort"
End If
ende:
Application.EnableEvents = True
End Sub

Gruss Harald

AW: Lösungen Auto-Eintrag Datum+User

30.06.2006 14:25:39

Sven

Vielen Dank für eure schnellen Antworten.
Ich muss immer staunen was man mit Programmierkenntnissen so umsetzen kann.
Fehlt mir leider völlig. Hab jetzt auch ein wenig gebraucht um das erpoben zu können.
Das sieht beides sehr gut aus. Jetzt brauche diese Funktion nicht nur speziell für eine Zelle sondern für eine komplette Spalte oder Zeile. Also ich möchtedie Einträge in A1,B1,C1.... u.s.w. mit o.g. Angaben ergänzen.
Geht das auch ?
Gruß
Sven

AW: Lösungen Auto-Eintrag Datum+User

30.06.2006 14:47:57

Harald

Hi,
hier z.B. für Zeile und den Bereich A1:G1 (kannste anpassen)


Private Sub Worksheet_Change(ByVal Target As Range)
Dim bereich As Range
On Error GoTo ende
Set bereich = Range("a1:g1")
If Target.Count > 1 Then Exit Sub
If Not Intersect(Target, bereich) Is Nothing Then
Application.EnableEvents = False
'ActiveSheet.Unprotect "Passwort"
Target.Offset(1, 0) = Format(Date, "dd.mm.yy")
Target.Offset(2, 0) = Environ("username")
'ActiveSheet.Protect "Passwort"
End If
ende:
Application.EnableEvents = True
End Sub

für Spalte und Bereich A1:A15 (bereich und Offset angepaßt)


Private Sub Worksheet_Change(ByVal Target As Range)
Dim bereich As Range
On Error GoTo ende
Set bereich = Range("a1:a15")
If Target.Count > 1 Then Exit Sub
If Not Intersect(Target, bereich) Is Nothing Then
Application.EnableEvents = False
'ActiveSheet.Unprotect "Passwort"
Target.Offset(0, 1) = Format(Date, "dd.mm.yy")
Target.Offset(0, 2) = Environ("username")
'ActiveSheet.Protect "Passwort"
End If
ende:
Application.EnableEvents = True
End Sub

Gruss Harald

AW: Lösungen Auto-Eintrag Datum+User

30.06.2006 15:41:08

Sven

Suuuper !!!
Danke, genau was ich wollte.
Danke.

Danke für die Rückmeldung owT

30.06.2006 15:43:09

Harald

Gruss Harald

Auto-Eintrag Datum+User

Forumthread: Auto-Eintrag Datum+User

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Auto-Eintrag Datum+User

Forumthread: Auto-Eintrag Datum+User

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread