Zeilen ausblenden

Forumthread: Zeilen ausblenden
4 Beiträge zu diesem Forumthread
Anzeige
VBA Beispiele zu verwandten Themen

Forumthread: Zeilen ausblenden

Zeilen ausblenden

19.11.2006 12:06:14

Christian

Schönen guten Morgen,
für einen Profi sicherlich eine leichte Aufgabe. Ich habe eine Tabelle mit z.B. 50 Zeilen und 10 Spalten. In diesem Bereich gibt es Zeilen, die keine Werte erhalten.
Wie kann ich diese Leerzeilen mit einem Makro am schnellsten und effektivsten ausblenden?
Danke im Voraus für Eure Hilfe,
herzliche Grüße, Christian

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zeilen ausblenden

19.11.2006 12:27:58

Marko
AW: Zeilen ausblenden

19.11.2006 14:07:38

Erich
AW: Zeilen ausblenden

19.11.2006 15:25:48

Daniel
AW: Zeilen ausblenden

19.11.2006 19:22:33

Christian

AW: Zeilen ausblenden

19.11.2006 12:27:58

Marko

hallo
meintest du so?
hier werden alle ausgeblendet die keinen oder den wert null haben!


Sub HideColumns()
Dim iCol As Integer
Application.ScreenUpdating = False
For iCol = 1 To 256
If Cells(5, iCol).Value = 0 Then
Columns(iCol).Hidden = True
End If
Next iCol
Application.ScreenUpdating = True
End Sub


Sub UnHideColumns()
Columns.Hidden = False
End Sub

gruß marko

AW: Zeilen ausblenden

19.11.2006 14:07:38

Erich

Hallo Christian,
versuchs mal so:

Sub HideEmptyRows()
Dim lngR As Long, intC As Integer
Application.ScreenUpdating = False
For lngR = 50 To 1 Step -1
For intC = 1 To 10
If Not IsEmpty(Cells(lngR, intC)) Then Exit For
Next intC
If intC > 10 Then Rows(lngR).Hidden = True
Next lngR
Application.ScreenUpdating = True
End Sub

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Zeilen ausblenden

19.11.2006 15:25:48

Daniel

Hallo
am schnellsten gehts ohne Schleifen


Sub Leerezeilen_ausblenden()
Dim Bereich As Range
With Range("A1:J50")
On Error Resume Next
Set Bereich = .SpecialCells(xlCellTypeConstants, 23)
Set Bereich = Union(Bereich, .SpecialCells(xlCellTypeFormulas, 23))
.EntireRow.Hidden = True
Bereich.EntireRow.Hidden = False
On Error Goto 0
End With
End Sub

Gruß, Daniel

AW: Zeilen ausblenden

19.11.2006 19:22:33

Christian

Grüß Euch!
Danke für Eure Bemühungen, der Vorschlag von Daniel funktioniert perfekt und erscheint mir am effektivsten.
Grüße, Christian