Gültigkeitsprüfung

Forumthread: Gültigkeitsprüfung

Gültigkeitsprüfung

30.05.2007 09:49:02

Greta

Es gibt drei Produktgruppen A, B und C mit den jeweils dazugehörigen Produktnamen. An anderer Stelle sollen die Produktnamen, allerdings nur von B und C, über ein Listenfeld ausgewählt werden können. Ich habe an eine Gültigkeitsprüfung gedacht. Wie kann man die Produkte der Gruppe A ausschließen?
Grüße
Greta

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Gültigkeitsprüfung

30.05.2007 10:02:26

Frederic
AW: Gültigkeitsprüfung

30.05.2007 10:43:51

Greta
AW: Gültigkeitsprüfung

30.05.2007 13:51:00

HermannZ
AW: Gültigkeitsprüfung

30.05.2007 14:18:37

Christian
AW: Gültigkeitsprüfung

01.06.2007 10:56:29

Greta

AW: Gültigkeitsprüfung

30.05.2007 10:02:26

Frederic

Lad mal bitte ne Beispieldatei hoch.
Gruß.
Frederic

AW: Gültigkeitsprüfung

30.05.2007 13:51:00

HermannZ

Hallo Greta;
eine Möglichkeit du machst in einer Spalte eine neue Liste und zwar mit der Formel;
{=WENN(SUMME(--(A2:A100<>"")*(A2:A100<>"A"))<ZEILE(A1);""; INDIREKT("B"&KKLEINSTE(WENN($A$2:$A$100="A";"";ZEILE($2:$100));ZEILE(A1)))) }
und soweit wie nötig nach unten kopieren.
den bereich A1:A100 kannst du ja noch anpassen .
dann musst du dich nur noch auf diese Liste beziehen.
Gruss HermannZ

AW: Gültigkeitsprüfung

30.05.2007 14:18:37

Christian

Hallo Greta,
Bsp:
Tabelle1

	A	B	C	D	E	F	G	H
1	Produktgruppe	Name					Petersilie	Spalte G ist Hilfsspalte für Gültigkeit!!
2	A	Rosen					Schnittlauch
3	B	Petersilie					Hortensie
4	A	Nelken		Auswahl:	Schefflera		Ficus
5	B	Schnittlauch					Schefflera
6	C	Hortensie
7	C	Ficus
8	C	Schefflera
9	A	Tulpen

Formeln der Tabelle

Zelle	Formel
G1	{=WENN(ZEILE()>ZÄHLENWENN(INDIREKT("$A$2:A"&VERWEIS(2;1/($A$1:$A$1000<>""); ZEILE($A$1:$A$1000))); "<>A"); "";INDIREKT("B"&KKLEINSTE(WENN($A$2:$A$1000<>"A";ZEILE($2:$1000)); ZEILE(A1))))}
G2	{=WENN(ZEILE()>ZÄHLENWENN(INDIREKT("$A$2:A"&VERWEIS(2;1/($A$1:$A$1000<>""); ZEILE($A$1:$A$1000))); "<>A"); "";INDIREKT("B"&KKLEINSTE(WENN($A$2:$A$1000<>"A";ZEILE($2:$1000)); ZEILE(A2))))}
G3	{=WENN(ZEILE()>ZÄHLENWENN(INDIREKT("$A$2:A"&VERWEIS(2;1/($A$1:$A$1000<>""); ZEILE($A$1:$A$1000))); "<>A"); "";INDIREKT("B"&KKLEINSTE(WENN($A$2:$A$1000<>"A";ZEILE($2:$1000)); ZEILE(A3))))}
G4	{=WENN(ZEILE()>ZÄHLENWENN(INDIREKT("$A$2:A"&VERWEIS(2;1/($A$1:$A$1000<>""); ZEILE($A$1:$A$1000))); "<>A"); "";INDIREKT("B"&KKLEINSTE(WENN($A$2:$A$1000<>"A";ZEILE($2:$1000)); ZEILE(A4))))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Datengültigkeit der Tabelle

Zelle	Zulassen	Daten	Eingabe 1	Eingabe 2
E4	Liste		=Liste

Namen in Formeln

Zelle	Name	Bezieht sich auf
E4	Liste	=INDIREKT("Tabelle1!$G$1:$G$"&VERWEIS(2;1/(Tabelle1!$G$1:$G$1000<>"");ZEILE(Tabelle1!$G$1:$G$1000)))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian

AW: Gültigkeitsprüfung

01.06.2007 10:56:29

Greta

Danke an HemannZ und Christian. Ich werde mich für eine der Lösungen entscheiden.
Greta

Forumthread: Gültigkeitsprüfung

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread