Seitenumbruch

Forumthread: Seitenumbruch

Seitenumbruch

24.09.2007 18:17:42

egres

Hallo Leute
ich habe in der Spalte A den Seitenumbruch mit dem Wort "Umbruch" definiert!
Wie kann ich per VbA nun erreichen das dieser Umbruch auch da gesetzt wird.
da habe ich schon probiert, aber es klappt nicht.


Sub Seitenwechsel()
Dim iRow As Integer
For iRow = WorksheetFunction.CountA(Columns(1)) To 1 Step -1
If Cells(iRow, 1).Value = "Umbruch" Then
Tabelle1.HPageBreaks.Add Cells(iRow, 1)
End If
Next iRow
End Sub

Wer kann mir helfen
Gruss und Danke
Serge

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Seitenumbruch

24.09.2007 20:31:25

fcs
AW: Seitenumbruch

24.09.2007 20:51:03

egres
AW: Seitenumbruch

24.09.2007 23:30:29

Josef
AW: Seitenumbruch

25.09.2007 00:25:03

egres
AW: Seitenumbruch

25.09.2007 00:45:42

Josef
AW: Seitenumbruch

25.09.2007 14:52:41

fcs
Meine Datei!

25.09.2007 17:53:00

egres
AW: Meine Datei!

25.09.2007 19:19:00

fcs
Super, Danke!

25.09.2007 19:56:42

egres

AW: Seitenumbruch

24.09.2007 20:31:25

fcs

Hallo serge,
so sollte es funktionieren
MfG
Franz


Sub Seitenwechsel()
Dim iRow As Integer, wks As Worksheet
Set wks = Tabelle1
With wks
.Rows.PageBreak = xlPageBreakNone
For iRow = .Cells(.Rows.Count, 1).End(xlUp).Row To 1 Step -1
If .Cells(iRow, 1).Value = "Umbruch" Then
.Rows(iRow).PageBreak = xlPageBreakManual
End If
Next iRow
End With
End Sub

AW: Seitenumbruch

24.09.2007 20:51:03

egres

Hallo fcs!
Das Makro bleibt bei
.Rows.PageBreak = xlPageBreakNone stehen mikt der Fehlermeldung:
Laufzeitfehler
Die Pagebreak-Eigenschaft des Range-Objektes kann nicht festgelegt werden
Serge

AW: Seitenumbruch

24.09.2007 23:30:29

Josef

Hallo Serge,
probier mal.
Sub HPBreaks()
Dim rng As Range
Dim strFirst As String

With ActiveSheet

    .Columns.PageBreak = xlPageBreakNone

    Set rng = .Columns(1).Find(What:="Umbruch", LookAt:=xlWhole, MatchCase:=False)

    If Not rng Is Nothing Then
        strFirst = rng.Address

        Do
            .HPageBreaks.Add rng

            Set rng = .Columns(1).FindNext(rng)

        Loop While Not rng Is Nothing And rng.Address <> strFirst

    End If

End With

Set rng = Nothing
End Sub

Gruß Sepp

AW: Seitenumbruch

25.09.2007 00:25:03

egres

Hallo Sepp
Das Makro bleibt auch bei
.Columns.PageBreak = xlPageBreakNone
stehen mit der Fehlermeldung:
Laufzeitfehler 1004
Die Pagebreak-Eigenschaft des Range-Objektes kann nicht festgelegt werden.
Gruss Serge

AW: Seitenumbruch

25.09.2007 00:45:42

Josef

Hallo Serge,
probier statt


.Columns.PageBreak = xlPageBreakNone

mal


.Columns.PageBreak = -4142

ansonsten kann ich nicht sagen warum es bei dir nicht läuft.
Kannst du das Tabellenblatt hochladen?

Gruß Sepp

AW: Seitenumbruch

25.09.2007 14:52:41

fcs

Hallo egres,
bei mir Office 2003 hat das mit dem Seitenumbruch funktioniert. Evtl. gibt es in deiner Datei das Blatt Tabelle1 (Interne Bezeichnung von Excel; wird nur im VBA-Projektexplorer angezeigt) nicht.
Probiere mal die folgende Variante. Alternativ kannst du statt der Nr 1 auch den Namen des Blattes in Anführungszeichen angeben.
MfG
Franz


Sub Seitenwechsel()
Dim iRow As Integer, wks As Worksheet
Set wks = WorkSheets(1) ' oder Worksheets("Tabelle1")
With wks
.Rows.PageBreak = xlPageBreakNone
For iRow = .Cells(.Rows.Count, 1).End(xlUp).Row To 1 Step -1
If .Cells(iRow, 1).Value = "Umbruch" Then
.Rows(iRow).PageBreak = xlPageBreakManual
End If
Next iRow
End With
End Sub

Meine Datei!

25.09.2007 17:53:00

egres

Hallo Sepp oder Franz
Hier meine Datei: https://www.herber.de/bbs/user/46327.xls
vielleicht geht es besser wenn ihr probier, bei mir klapp und klappt es nicht!
Gruss Serge

AW: Meine Datei!

25.09.2007 19:19:00

fcs

Hallo egres,
das Makro funktioniert nicht in der Ansicht "Seitenumbruch". Da ich diese praktisch nie benutze war mir das Problem nicht bekannt.
Ich hab es jetzt so angepasst, dass ggf. die Seitenansicht umgeschaltet wird und am Ende des Makros ggf. wieder zurückgesetzt wird.
Gruß
Franz


Sub Seitenwechsel()
Dim iRow As Integer, wks As Worksheet, PBview As Long
Set wks = Worksheets(1) ' oder Worksheets("Tabelle1")
With wks
Application.ScreenUpdating = False
PBview = ActiveWindow.View ' Seitenansicht merken
If ActiveWindow.View = xlPageBreakPreview Then
ActiveWindow.View = xlNormalView
End If
.Rows.PageBreak = xlPageBreakNone
For iRow = .Cells(.Rows.Count, 1).End(xlUp).Row To 1 Step -1
If .Cells(iRow, 1).Value = "Umbruch" Then
.Rows(iRow).PageBreak = xlPageBreakManual
End If
Next iRow
If PBview  ActiveWindow.View Then
ActiveWindow.View = xlPageBreakPreview
End If
Application.ScreenUpdating = True
End With
End Sub

Super, Danke!

25.09.2007 19:56:42

egres

Hallo Franz
Super, es klappt wie geschmiert und so wie ich es mir vorgestellt habe!
Danke und salut
Serge
aus dem noch sonnigem Elsass.

Forumthread: Seitenumbruch

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread