Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

26.10.2024 18:16:11

Kuwari

Gibt es in excel eine Funktion, mit der man aus einer vierstelligen Zahl ( auch 0001) den höchsten und den niedrigsten wert darstellen kann (Beispiel: Zahl 1705; höchster Wert: 7510; niedrigster Wert: 0157)?

AW: Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

26.10.2024 18:29:08

Eifeljoi 5

Hallo
Das aller sinnvollste ist alles zusammen samt Beitrag ab in in die Mülltonne.
Oder wenn dir das reicht schreibe das Ganze als Text.

AW: Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

26.10.2024 18:38:20

Onur

https://www.herber.de/bbs/user/173173.xlsx

AW: --TEXTKETTE(SORTIEREN(TEIL(A1;{1;2;3;4};1);;-1))

26.10.2024 18:44:46

Rolf

Hallo Kuwari?

...für die größte Zahl.
Schau Dir SORTIEREN mal genau an, dann schaffst Du die kleinste alleine!

Gruß Rolf

AW: habe XL365 nicht, ...

26.10.2024 20:23:59

neopa C

Hallo Rolf,

... somit kann ich Formelvorschläge mit XL365 leider nur teilweise in etwa nachvollziehen. Deshalb hatte ich nur den für mich bis dahin letzten Beitrag im thread (von Case mit seiner Formel) gelesen und dabei gedacht, das müßte doch einfacher realisierbar sein. Die vorherigen Beiträge hatte ich deshalb nicht weiter beachtet, sorry. Und Edgars Vorschlag kam in der Zeit, als ich noch an meiner Formellösung für ältere XL-Versionen "gebastelt" habe. Dein Formelvorschlag erscheint mir momentan zumindest als die einfachste Lösung für das angefragte.

Gruß Werner
.. , - ...

AW: @Werner

26.10.2024 21:03:00

Rolf

Hallo Werner
ich hab auch 'nur' die 2021-er Version, aber da sind auch schon 'ne Menge an neuen Funktionen drin!

Gruß Rolf

AW: ja, manchmal reicht eben auch weniger als mehr ;-) owT

26.10.2024 21:33:08

neopa C

Gruß Werner
.. , - ...

Manchmal...

26.10.2024 22:07:13

Case

Moin Werner, :-)

... muss es aber auch ein klein wenig mehr sein. :-)

Ich befasse mich mit Formeln erst ab den neuen Funktionen (und ab Rente). ;-)
Versuche dann etwas mit den neuen Funktionen aufzubauen. Wenn ich es dann zum spillen bringen will, wird es oft eine lange Formel. Versuche dann z. B. sowas wie die tolle MAP-Funktion mit einzubauen: ;-)
https://support.microsoft.com/de-de/office/map-funktion-48006093-f97c-47c1-bfcc-749263bb1f01

Häufig wahrscheinlich überflüssig. Das ist mir aber egal. :-)

Das gute bei Herber ist, dass im Minutentakt, oder Stundentakt neue Versionen reinkommen. Ich stelle es dann - auch wenn es Tage später ist - einfach als Alternative ein. Eventuell schreibe ich besser dazu, dass es die Langversion ist. :-)

Das würde auch in Power Query gehen (wird wohl eher interessant, wenn es eine lange Liste ist):
https://www.herber.de/bbs/user/173178.xlsx

Bei großen Datenmengen würde ich das jeder Formel vorziehen.
Vorteil auch, es ist egal, ob das in Zeile 1, 2, 3 oder sonstwo steht. Bei Formeln muss dann häufig eingegriffen werden.

Den Einzeiler im M-Code generiert - wie schon öfter gesagt - mein NET-Programm (inklusive der Kommentare oben). Funktioniert im Moment aber nur bei einfachen Teilen. ;-)

Servus
Case

AW: Oft ... sehe ich das prinzipell ähnlich :-) owT

27.10.2024 09:27:00

neopa C

Gruß Werner
.. , - ...

Eventuell...

26.10.2024 18:56:57

Case

Moin, :-)

... so: ;-)
https://www.herber.de/bbs/user/173174.xlsx

Servus
Case

AW: Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

26.10.2024 19:47:15

BoskoBiati2

Hi,,
oder auch so:

=LET(xa;TEIL(A1;ZEILE($1:$4);1);--TEXTKETTE(SORTIERENNACH(xa;xa;-1)))

=LET(xa;TEIL(A1;ZEILE($1:$4);1);--TEXTKETTE(SORTIERENNACH(xa;xa;1)))

Gruß

Edgar

AW: in XL2010 reicht 1ne Formel mit nur 4 Funktionen ....

26.10.2024 19:54:05

neopa C

Hallo zusammen,

... und zwar auch ohne Matrixformelabschluss. Allerdings muß man in den XL-Versionen vor XL365 die Formel noch händisch ziehend (nach rechts und unten) kopieren, weil da noch nicht automatisch gespillt wird. Durch das benutzerdefinierte Zahlenformat ist das Ergebnis auch für die kleinste Zahl eine echte Zahl und kein Text.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Zahl		MAX	MIN
2	1705		7510	0157
3	2184		8421	1248
4	1023		3210	0123
5	9336		9633	3369

Zelle	Format	Wert
C2	0000	7510

Zelle	Formel
C2	=SUMMENPRODUKT(AGGREGAT(14+SPALTE(A2)-1;6;--TEIL($A2;{1;2;3;4};1);{1;2;3;4})*10^{3;2;1;0})

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Gruß Werner
.. , - ...

Und bezogen auf...

26.10.2024 19:06:33

Case

Moin, :-)

... meine Beispieldatei: ;-)

=LET(x;H1:H4;y;MAP(x;LAMBDA(zahl;TEXTVERKETTEN("";;SORTIEREN(WERT(TEXT(TEIL(zahl;ZEILE(1:4);1);"0"));1;-1))));z;MAP(x;LAMBDA(zahl;TEXTVERKETTEN("";;SORTIEREN(WERT(TEXT(TEIL(zahl;ZEILE(1:4);1);"0"));1;1))));HSTAPELN(y; z))

Servus
Case

AW: Und bezogen auf...

27.10.2024 17:46:05

Luschi

Hallo Case,

ich habe Deine 365-Formeln so geändert, daß auch 1 bis 3-stellige Zahlen korrekt behandelt werden (2 verschiedene Varianten).
Deine PQ-Lösung wurde ein bißchen aufgedröselt, denn mit dem komprimierten PQ-M-Code können wohl 99% der PQ-Hilfesuchenden nix anfangen. Da es z.Z. mehrere PQ-M-User gibt, die diese PQ-M-Verklumpung anbieten, habe ich ein C#-Tool geschrieben, der die Aufdröselung realisiert.

https://www.herber.de/bbs/user/173187.xlsx

Gruß von Luschi
aus klein-Paris

AW: zu Deinen Formeln im Blatt "Daten" ...

27.10.2024 18:42:57

neopa C

Hallo Luschi,

... meine von Dir verwendete Formel, war von mir für die durch den TE vorgegebene "vierstellige" Zahl definiert.
Wenn Du diese für eine flexible Länge verwenden willst, muß diese natürlich für dies auch angepaßt werden.
Das ist auch in und mit XL2010 möglich. Damit die Zellformellänge vergleichbar bleibt, hab ich nachfolgend dafür den wiederholenden Formelteil durch eine benannte Formel definiert.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Zahl		MAX	MIN
2	2105		5210	0125
3	1		0001	0001
4	4132075		7543210	123457
5	31		0031	0013
6	231		0321	0123

Zelle	Format	Wert
C2	0000	5210

Name	Bezug
_X	=ZEILE(!$A$1:INDEX(!$A:$A;LÄNGE(!$A1)))

Zelle	Formel
C2	=SUMMENPRODUKT(AGGREGAT(14+SPALTE(A2)-1;6;--TEIL($A2;_X;1);_X)*10^(LÄNGE($A2)-_X))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Und bitte meinen Usernamen neopa immer nur kleingeschrieben verwenden.

Gruß Werner
.. , - ...

Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

Forumthread: Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

Forumthread: Aus einer 4stelligen zahl deen höchsten/ niedigsten Wert erm

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread